Better prefill and completion for :GoRename

autoload/go/rename.vim

@@ -2,17 +2,25 @@ if !exists("g:go_gorename_bin")
   let g:go_gorename_bin = "gorename"
 endif
 
-if !exists("g:go_gorename_prefill")
-  let g:go_gorename_prefill = 1
-endif
+" Set the default value. A value of "1" is a shortcut for this, for
+" compatibility reasons.
+function! s:default() abort
+  if !exists("g:go_gorename_prefill") || g:go_gorename_prefill == 1
+    let g:go_gorename_prefill = 'expand("<cword>") =~# "^[A-Z]"' .
+          \ '? go#util#pascalcase(expand("<cword>"))' .
+          \ ': go#util#camelcase(expand("<cword>"))'
+  endif
+endfunction
+call s:default()
 
 function! go#rename#Rename(bang, ...) abort
+  call s:default()
+
   let to_identifier = ""
   if a:0 == 0
-    let from = expand("<cword>")
-    let ask = printf("vim-go: rename '%s' to: ", from)
-    if g:go_gorename_prefill
-      let to_identifier = input(ask, from)
+    let ask = printf("vim-go: rename '%s' to: ", expand("<cword>"))
+    if g:go_gorename_prefill != ''
+      let to_identifier = input(ask, eval(g:go_gorename_prefill))
     else
       let to_identifier = input(ask)
     endif
@@ -24,7 +32,7 @@ function! go#rename#Rename(bang, ...) abort
     let to_identifier = a:1
   endif
 
-  "return with a warning if the bin doesn't exist
+  " return with a warning if the bin doesn't exist
   let bin_path = go#path#CheckBinPath(g:go_gorename_bin)
   if empty(bin_path)
     return
@@ -146,4 +154,13 @@ function s:parse_errors(exit_val, bang, out)
   silent execute ":e"
 endfunction
 
+" Commandline completion: original, unexported camelCase, and exported
+" CamelCase.
+function! go#rename#Complete(lead, cmdline, cursor)
+  let l:word = expand('<cword>')
+  return filter(uniq(sort(
+        \ [l:word, go#util#camelcase(l:word), go#util#pascalcase(l:word)])),
+        \ 'strpart(v:val, 0, len(a:lead)) == a:lead')
+endfunction
+
 " vim: sw=2 ts=2 et

autoload/go/util.vim

@@ -264,25 +264,33 @@ endfunction
 " snakecase converts a string to snake case. i.e: FooBar -> foo_bar
 " Copied from tpope/vim-abolish
 function! go#util#snakecase(word) abort
-  let word = substitute(a:word,'::','/','g')
-  let word = substitute(word,'\(\u\+\)\(\u\l\)','\1_\2','g')
-  let word = substitute(word,'\(\l\|\d\)\(\u\)','\1_\2','g')
-  let word = substitute(word,'[.-]','_','g')
+  let word = substitute(a:word, '::', '/', 'g')
+  let word = substitute(word, '\(\u\+\)\(\u\l\)', '\1_\2', 'g')
+  let word = substitute(word, '\(\l\|\d\)\(\u\)', '\1_\2', 'g')
+  let word = substitute(word, '[.-]', '_', 'g')
   let word = tolower(word)
   return word
 endfunction
 
-" camelcase converts a string to camel case. i.e: FooBar -> fooBar
-" Copied from tpope/vim-abolish
+" camelcase converts a string to camel case. e.g. FooBar or foo_bar will become
+" fooBar.
+" Copied from tpope/vim-abolish.
 function! go#util#camelcase(word) abort
   let word = substitute(a:word, '-', '_', 'g')
   if word !~# '_' && word =~# '\l'
-    return substitute(word,'^.','\l&','')
+    return substitute(word, '^.', '\l&', '')
   else
-    return substitute(word,'\C\(_\)\=\(.\)','\=submatch(1)==""?tolower(submatch(2)) : toupper(submatch(2))','g')
+    return substitute(word, '\C\(_\)\=\(.\)', '\=submatch(1)==""?tolower(submatch(2)) : toupper(submatch(2))','g')
   endif
 endfunction
 
+" pascalcase converts a string to 'PascalCase'. e.g. fooBar or foo_bar will
+" become FooBar.
+function! go#util#pascalcase(word) abort
+  let word = go#util#camelcase(a:word)
+  return toupper(word[0]) . word[1:]
+endfunction
+
 " Echo a message to the screen and highlight it with the group in a:hi.
 "
 " The message can be a list or string; every line with be :echomsg'd separately.

doc/vim-go.txt

@@ -1468,10 +1468,15 @@ By default it is set to edit.
 <
                                                      *'g:go_gorename_prefill'*
 
-Specifies whether |:GoRename| prefills the new identifier name with the
-word under the cursor. By default it is enabled.
->
-  let g:go_gorename_prefill = 1
+Expression to prefill the new identifier when using |:GoRename| without any
+arguments. Use an empty string if you don't want to prefill anything. By
+default it converts the identifier to camel case but preserves the
+capitalisation of the first letter to ensure that the exported state stays the
+same.
+>
+  let g:go_gorename_prefill = 'expand("<cword>") =~# "^[A-Z]"' .
+        \ '? go#util#pascalcase(expand("<cword>"))' .
+        \ ': go#util#camelcase(expand("<cword>"))'
 <
                                                      *'g:go_gocode_autobuild'*
 

ftplugin/go/commands.vim

@@ -1,5 +1,5 @@
 " -- gorename
-command! -nargs=? GoRename call go#rename#Rename(<bang>0,<f-args>)
+command! -nargs=? -complete=customlist,go#rename#Complete GoRename call go#rename#Rename(<bang>0, <f-args>)
 
 " -- guru
 command! -nargs=* -complete=customlist,go#package#Complete GoGuruScope call go#guru#Scope(<f-args>)