CDB front and backend

.gitignore

@@ -40,3 +40,10 @@ lcov
 
 # python compiled files
 *.pyc
+
+cdb.rs
+*.cdb
+compile_commands.json
+
+*.cmd
+core

CMakeLists.txt

@@ -39,9 +39,11 @@ option(TARGET_REDIS "build redis binary" ON)
 option(TARGET_SLIMREDIS "build slimredis binary" ON)
 option(TARGET_SLIMCACHE "build slimcache binary" ON)
 option(TARGET_TWEMCACHE "build twemcache binary" ON)
-
+option(TARGET_CDB "build cdb binary" ON)
 option(TARGET_RESPCLI "build resp-cli binary" ON)
 
+option(RUST_USE_MUSL "build rust deps against musl" OFF)
+
 option(COVERAGE "code coverage" OFF)
 
 # Note: duplicate custom targets only works with Makefile generators, will break XCode & VS
@@ -99,6 +101,7 @@ add_subdirectory(${CCOMMON_SOURCE_DIR} ${PROJECT_BINARY_DIR}/ccommon)
 # other dependencies
 include(FindPackageHandleStandardArgs)
 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${PROJECT_SOURCE_DIR}/cmake")
+
 find_package(Check)
 if(NOT CHECK_FOUND)
     message(WARNING "Check is required to build and run tests")
@@ -112,6 +115,9 @@ endif(CHECK_FOUND)
 
 find_package(Threads)
 
+enable_language(Rust)
+include(CMakeCargo)
+
 #set(CMAKE_INCLUDE_CURRENT_DIR)
 include_directories(${include_directories}
     "${PROJECT_BINARY_DIR}"
@@ -138,5 +144,14 @@ message(STATUS "HAVE_SIGNAME: " ${HAVE_SIGNAME})
 message(STATUS "HAVE_BACKTRACE: " ${HAVE_BACKTRACE})
 message(STATUS "HAVE_BIG_ENDIAN: " ${HAVE_BIG_ENDIAN})
 
+if(DUMP_ALL)
+    message(STATUS "<<++=====------------------\\/------------------=====++>>")
+    get_cmake_property(_variableNames VARIABLES)
+    foreach (_variableName ${_variableNames})
+        message(STATUS "${_variableName}=${${_variableName}}")
+    endforeach()
+    message(STATUS "<<++=====------------------/\\------------------=====++>>")
+endif()
+
 # Note: to uninstall targets, run:
 #  xargs rm < install_manifest.txt

cmake/CMakeCargo.cmake

@@ -0,0 +1,97 @@
+function(cargo_set_lib_target LIB_NAME)
+    if(WIN32)
+        if(CMAKE_SIZEOF_VOID_P EQUAL 8)
+            set(LIB_TARGET "x86_64-pc-windows-msvc" PARENT_SCOPE)
+        else()
+            set(LIB_TARGET "i686-pc-windows-msvc" PARENT_SCOPE)
+        endif()
+	elseif(ANDROID)
+        if(ANDROID_SYSROOT_ABI STREQUAL "x86")
+            set(LIB_TARGET "i686-linux-android" PARENT_SCOPE)
+        elseif(ANDROID_SYSROOT_ABI STREQUAL "x86_64")
+            set(LIB_TARGET "x86_64-linux-android" PARENT_SCOPE)
+        elseif(ANDROID_SYSROOT_ABI STREQUAL "arm")
+            set(LIB_TARGET "arm-linux-androideabi" PARENT_SCOPE)
+        elseif(ANDROID_SYSROOT_ABI STREQUAL "arm64")
+            set(LIB_TARGET "aarch64-linux-android" PARENT_SCOPE)
+        endif()
+    elseif(IOS)
+		set(LIB_TARGET "universal" PARENT_SCOPE)
+    elseif(CMAKE_SYSTEM_NAME STREQUAL Darwin)
+        set(LIB_TARGET "x86_64-apple-darwin" PARENT_SCOPE)
+	else()
+        if(RUST_USE_MUSL)
+            set(RUST_LIBC_NAME "musl")
+        else()
+            set(RUST_LIBC_NAME "gnu")
+        endif()
+
+        if(CMAKE_SIZEOF_VOID_P EQUAL 8)
+            set(LIB_TARGET "x86_64-unknown-linux-${RUST_LIBC_NAME}" PARENT_SCOPE)
+        else()
+            set(LIB_TARGET "i686-unknown-linux-${RUST_LIBC_NAME}" PARENT_SCOPE)
+        endif()
+    endif()
+endfunction()
+
+function(cargo_build)
+    cmake_parse_arguments(CARGO "" "NAME" "" ${ARGN})
+    string(REPLACE "-" "_" LIB_NAME ${CARGO_NAME})
+
+    get_filename_component(CARGO_TARGET_DIR "${CMAKE_CURRENT_BINARY_DIR}" ABSOLUTE)
+
+    cargo_set_lib_target(LIB_NAME)
+
+    if(NOT CMAKE_BUILD_TYPE)
+        set(LIB_BUILD_TYPE "debug")
+    elseif(${CMAKE_BUILD_TYPE} STREQUAL "Release")
+        set(LIB_BUILD_TYPE "release")
+    else()
+        set(LIB_BUILD_TYPE "debug")
+    endif()
+
+    set(SHARED_LIB_FNAME "${CMAKE_SHARED_LIBRARY_PREFIX}${LIB_NAME}${CMAKE_SHARED_LIBRARY_SUFFIX}")
+    set(STATIC_LIB_FNAME "${CMAKE_STATIC_LIBRARY_PREFIX}${LIB_NAME}${CMAKE_STATIC_LIBRARY_SUFFIX}")
+
+    set(LIB_BASE_DIR "${CARGO_TARGET_DIR}/${LIB_TARGET}/${LIB_BUILD_TYPE}")
+
+    get_filename_component(SHARED_LIB_FILE "${LIB_BASE_DIR}/${SHARED_LIB_FNAME}" ABSOLUTE)
+    get_filename_component(STATIC_LIB_FILE "${LIB_BASE_DIR}/${STATIC_LIB_FNAME}" ABSOLUTE)
+
+	if(IOS)
+		set(CARGO_ARGS "lipo")
+	else()
+    	set(CARGO_ARGS "build")
+		list(APPEND CARGO_ARGS "--target" ${LIB_TARGET})
+	endif()
+
+    if(${LIB_BUILD_TYPE} STREQUAL "release")
+        list(APPEND CARGO_ARGS "--release")
+    endif()
+
+    file(GLOB_RECURSE LIB_SOURCES "*.rs")
+
+    set(CARGO_ENV_COMMAND ${CMAKE_COMMAND} -E env "CARGO_TARGET_DIR=${CARGO_TARGET_DIR}")
+
+    add_custom_command(
+        OUTPUT ${STATIC_LIB_FILE}
+        COMMAND ${CARGO_ENV_COMMAND} ${CARGO_EXECUTABLE} ARGS ${CARGO_ARGS}
+        WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
+        DEPENDS ${LIB_SOURCES}
+        COMMENT "running cargo")
+    add_custom_target(${CARGO_NAME}_static_target ALL DEPENDS ${STATIC_LIB_FILE})
+    add_library(${CARGO_NAME}_static STATIC IMPORTED GLOBAL)
+    add_dependencies(${CARGO_NAME}_static ${CARGO_NAME}_static_target)
+    set_target_properties(${CARGO_NAME}_static PROPERTIES IMPORTED_LOCATION ${STATIC_LIB_FILE})
+
+    add_custom_command(
+        OUTPUT ${SHARED_LIB_FILE}
+        COMMAND ${CARGO_ENV_COMMAND} ${CARGO_EXECUTABLE} ARGS ${CARGO_ARGS}
+        WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
+        DEPENDS ${LIB_SOURCES}
+        COMMENT "running cargo")
+    add_custom_target(${CARGO_NAME}_shared_target ALL DEPENDS ${SHARED_LIB_FILE})
+    add_library(${CARGO_NAME}_shared SHARED IMPORTED GLOBAL)
+    add_dependencies(${CARGO_NAME}_shared ${CARGO_NAME}_shared_target)
+    set_target_properties(${CARGO_NAME}_shared PROPERTIES IMPORTED_LOCATION ${SHARED_LIB_FILE})
+endfunction()

cmake/CMakeDetermineRustCompiler.cmake

@@ -0,0 +1,25 @@
+
+if(NOT CMAKE_Rust_COMPILER)
+	find_package(Rust)
+	if(RUST_FOUND)
+		set(CMAKE_Rust_COMPILER "${RUSTC_EXECUTABLE}")
+		set(CMAKE_Rust_COMPILER_ID "Rust")
+		set(CMAKE_Rust_COMPILER_VERSION "${RUST_VERSION}")
+		set(CMAKE_Rust_PLATFORM_ID "Rust")
+	endif()
+endif()
+
+message(STATUS "Cargo Prefix: ${CARGO_PREFIX}")
+message(STATUS "Rust Compiler Version: ${RUSTC_VERSION}")
+
+mark_as_advanced(CMAKE_Rust_COMPILER)
+
+if(CMAKE_Rust_COMPILER)
+	set(CMAKE_Rust_COMPILER_LOADED 1)
+endif(CMAKE_Rust_COMPILER)
+
+configure_file(${CMAKE_SOURCE_DIR}/cmake/CMakeRustCompiler.cmake.in
+	${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/${CMAKE_VERSION}/CMakeRustCompiler.cmake IMMEDIATE @ONLY)
+
+set(CMAKE_Rust_COMPILER_ENV_VAR "RUSTC")
+

cmake/CMakeRustCompiler.cmake.in

@@ -0,0 +1,15 @@
+
+set(CMAKE_Rust_COMPILER "@CMAKE_Rust_COMPILER@")
+set(CMAKE_Rust_COMPILER_ID "@CMAKE_Rust_COMPILER_ID@")
+set(CMAKE_Rust_COMPILER_VERSION "@CMAKE_Rust_COMPILER_VERSION@")
+set(CMAKE_Rust_COMPILER_LOADED @CMAKE_Rust_COMPILER_LOADED@)
+set(CMAKE_Rust_PLATFORM_ID "@CMAKE_Rust_PLATFORM_ID@")
+
+SET(CMAKE_Rust_SOURCE_FILE_EXTENSIONS rs)
+SET(CMAKE_Rust_LINKER_PREFERENCE 40)
+#SET(CMAKE_Rust_OUTPUT_EXTENSION_REPLACE 1)
+SET(CMAKE_STATIC_LIBRARY_PREFIX_Rust "")
+SET(CMAKE_STATIC_LIBRARY_SUFFIX_Rust .a)
+
+set(CMAKE_Rust_COMPILER_ENV_VAR "RUSTC")
+

cmake/CMakeRustInformation.cmake

@@ -0,0 +1,106 @@
+
+# 
+# Usage: rustc [OPTIONS] INPUT
+# 
+# Options:
+#     -h --help           Display this message
+#     --cfg SPEC          Configure the compilation environment
+#     -L [KIND=]PATH      Add a directory to the library search path. The
+#                         optional KIND can be one of dependency, crate, native,
+#                         framework or all (the default).
+#     -l [KIND=]NAME      Link the generated crate(s) to the specified native
+#                         library NAME. The optional KIND can be one of static,
+#                         dylib, or framework. If omitted, dylib is assumed.
+#     --crate-type [bin|lib|rlib|dylib|cdylib|staticlib|metadata]
+#                         Comma separated list of types of crates for the
+#                         compiler to emit
+#     --crate-name NAME   Specify the name of the crate being built
+#     --emit [asm|llvm-bc|llvm-ir|obj|link|dep-info]
+#                         Comma separated list of types of output for the
+#                         compiler to emit
+#     --print [crate-name|file-names|sysroot|cfg|target-list|target-cpus|target-features|relocation-models|code-models]
+#                         Comma separated list of compiler information to print
+#                         on stdout
+#     -g                  Equivalent to -C debuginfo=2
+#     -O                  Equivalent to -C opt-level=2
+#     -o FILENAME         Write output to <filename>
+#     --out-dir DIR       Write output to compiler-chosen filename in <dir>
+#     --explain OPT       Provide a detailed explanation of an error message
+#     --test              Build a test harness
+#     --target TARGET     Target triple for which the code is compiled
+#     -W --warn OPT       Set lint warnings
+#     -A --allow OPT      Set lint allowed
+#     -D --deny OPT       Set lint denied
+#     -F --forbid OPT     Set lint forbidden
+#     --cap-lints LEVEL   Set the most restrictive lint level. More restrictive
+#                         lints are capped at this level
+#     -C --codegen OPT[=VALUE]
+#                         Set a codegen option
+#     -V --version        Print version info and exit
+#     -v --verbose        Use verbose output
+# 
+# Additional help:
+#     -C help             Print codegen options
+#     -W help             Print 'lint' options and default settings
+#     -Z help             Print internal options for debugging rustc
+#     --help -v           Print the full set of options rustc accepts
+# 
+
+# <TARGET> <TARGET_BASE> <OBJECT> <OBJECTS> <LINK_LIBRARIES> <FLAGS> <LINK_FLAGS> <SOURCE> <SOURCES>
+
+include(CMakeLanguageInformation)
+
+if(UNIX)
+	set(CMAKE_Rust_OUTPUT_EXTENSION .o)
+else()
+	set(CMAKE_Rust_OUTPUT_EXTENSION .obj)
+endif()
+
+set(CMAKE_Rust_ECHO_ALL "echo \"TARGET: <TARGET> TARGET_BASE: <TARGET_BASE> ")
+set(CMAKE_Rust_ECHO_ALL "${CMAKE_Rust_ECHO_ALL} OBJECT: <OBJECT> OBJECTS: <OBJECTS> OBJECT_DIR: <OBJECT_DIR> SOURCE: <SOURCE> SOURCES: <SOURCES> ")
+set(CMAKE_Rust_ECHO_ALL "${CMAKE_Rust_ECHO_ALL} LINK_LIBRARIES: <LINK_LIBRARIES> FLAGS: <FLAGS> LINK_FLAGS: <LINK_FLAGS> \"")
+
+if(NOT CMAKE_Rust_CREATE_SHARED_LIBRARY)
+	set(CMAKE_Rust_CREATE_SHARED_LIBRARY
+		"echo \"CMAKE_Rust_CREATE_SHARED_LIBRARY\""
+		"${CMAKE_Rust_ECHO_ALL}"
+		)
+endif()
+
+if(NOT CMAKE_Rust_CREATE_SHARED_MODULE)
+	set(CMAKE_Rust_CREATE_SHARED_MODULE
+		"echo \"CMAKE_Rust_CREATE_SHARED_MODULE\""
+		"${CMAKE_Rust_ECHO_ALL}"
+		)
+endif()
+
+if(NOT CMAKE_Rust_CREATE_STATIC_LIBRARY)
+	set(CMAKE_Rust_CREATE_STATIC_LIBRARY
+		"echo \"CMAKE_Rust_CREATE_STATIC_LIBRARY\""
+		"${CMAKE_Rust_ECHO_ALL}"
+		)
+endif()
+
+if(NOT CMAKE_Rust_COMPILE_OBJECT)
+	set(CMAKE_Rust_COMPILE_OBJECT
+		"echo \"CMAKE_Rust_COMPILE_OBJECT\""
+		"${CMAKE_Rust_ECHO_ALL}"
+		"${CMAKE_Rust_COMPILER} --emit obj <SOURCE> -o <OBJECT>")
+endif()
+
+if(NOT CMAKE_Rust_LINK_EXECUTABLE)
+	set(CMAKE_Rust_LINK_EXECUTABLE
+		"echo \"CMAKE_Rust_LINK_EXECUTABLE\""
+		"${CMAKE_Rust_ECHO_ALL}"
+		)
+endif()
+
+mark_as_advanced(
+	CMAKE_Rust_FLAGS
+	CMAKE_Rust_FLAGS_DEBUG
+	CMAKE_Rust_FLAGS_MINSIZEREL
+	CMAKE_Rust_FLAGS_RELEASE
+	CMAKE_Rust_FLAGS_RELWITHDEBINFO)
+
+set(CMAKE_Rust_INFORMATION_LOADED 1)
+

cmake/CMakeTestRustCompiler.cmake

@@ -0,0 +1,3 @@
+
+set(CMAKE_Rust_COMPILER_WORKS 1 CACHE INTERNAL "")
+

cmake/FindRust.cmake

@@ -0,0 +1,75 @@
+
+set(_CMAKE_FIND_ROOT_PATH_MODE_PROGRAM ${CMAKE_FIND_ROOT_PATH_MODE_PROGRAM})
+set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
+set(_CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ${CMAKE_FIND_ROOT_PATH_MODE_INCLUDE})
+set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE BOTH)
+
+if(WIN32)
+	set(USER_HOME "$ENV{USERPROFILE}")
+else()
+	set(USER_HOME "$ENV{HOME}")
+endif()
+
+# Find cargo prefix
+find_path(CARGO_PREFIX ".cargo"
+	PATHS "${USER_HOME}")
+
+if(CARGO_PREFIX MATCHES "NOTFOUND")
+	message(FATAL_ERROR "Could not find Rust!")
+else()
+	set(CARGO_PREFIX "${CARGO_PREFIX}/.cargo")
+endif()
+
+# Find cargo executable
+find_program(CARGO_EXECUTABLE cargo
+	HINTS "${CARGO_PREFIX}"
+	PATH_SUFFIXES "bin")
+mark_as_advanced(CARGO_EXECUTABLE)
+
+# Find rustc executable
+find_program(RUSTC_EXECUTABLE rustc
+	HINTS "${CARGO_PREFIX}"
+	PATH_SUFFIXES "bin")
+mark_as_advanced(RUSTC_EXECUTABLE)
+
+# Find rustdoc executable
+find_program(RUSTDOC_EXECUTABLE rustdoc
+	HINTS "${CARGO_PREFIX}"
+	PATH_SUFFIXES "bin")
+mark_as_advanced(RUSTDOC_EXECUTABLE)
+
+# Find rust-gdb executable
+find_program(RUST_GDB_EXECUTABLE rust-gdb
+	HINTS "${CARGO_PREFIX}"
+	PATH_SUFFIXES "bin")
+mark_as_advanced(RUST_GDB_EXECUTABLE)
+
+# Find rust-lldb executable
+find_program(RUST_LLDB_EXECUTABLE rust-lldb
+	HINTS "${CARGO_PREFIX}"
+	PATH_SUFFIXES "bin")
+mark_as_advanced(RUST_LLDB_EXECUTABLE)
+
+# Find rustup executable
+find_program(RUSTUP_EXECUTABLE rustup
+	HINTS "${CARGO_PREFIX}"
+	PATH_SUFFIXES "bin")
+mark_as_advanced(RUSTUP_EXECUTABLE)
+
+set(RUST_FOUND FALSE CACHE INTERNAL "")
+
+if(CARGO_EXECUTABLE AND RUSTC_EXECUTABLE AND RUSTDOC_EXECUTABLE)
+	set(RUST_FOUND TRUE CACHE INTERNAL "")
+
+	set(CARGO_PREFIX "${CARGO_PREFIX}" CACHE PATH "Rust Cargo prefix")
+
+	execute_process(COMMAND ${RUSTC_EXECUTABLE} --version OUTPUT_VARIABLE RUSTC_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
+	string(REGEX REPLACE "rustc ([^ ]+) .*" "\\1" RUSTC_VERSION "${RUSTC_VERSION}")
+endif()
+
+if(NOT RUST_FOUND)
+	message(FATAL_ERROR "Could not find Rust!")
+endif()
+
+set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM ${_CMAKE_FIND_ROOT_PATH_MODE_PROGRAM})
+set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ${_CMAKE_FIND_ROOT_PATH_MODE_INCLUDE})