Trac #33247: Restore quiet in ./configure -q

In Sage 9.5.rc4, two of the configure checks
do not respect the quiet mode:
{{{
$ ./configure -q
Traceback (most recent call last):
  File "<string>", line 1, in <module>
ImportError: No module named lzma
./configure: line 42336: ,: command not found
}}}

URL: https://trac.sagemath.org/33247
Reported by: slelievre
Ticket author(s): Matthias Koeppe
Reviewer(s): John Palmieri

build/pkgs/qhull/spkg-configure.m4

@@ -5,25 +5,21 @@ SAGE_SPKG_CONFIGURE([qhull], [
            AC_MSG_NOTICE([qhull not found. Installing qhull])
            sage_spkg_install_qhull=yes
     ], [
-           AC_MSG_CHECKING([is qhull's version good enough? ])
-           qhull_ver=`$QHULL -V | cut -d' ' -f2 2>> config.log`
+           AC_MSG_CHECKING([whether qhull's version is good enough])
+           qhull_ver=$($QHULL -V | cut -d' ' -f2 2>& AS_MESSAGE_LOG_FD)
            AX_COMPARE_VERSION([$qhull_ver], [ge], [$SAGE_QHULL_MINVER], [
-               AC_MSG_RESULT([yes.])
-               AC_MSG_CHECKING([is qhull_r library and headers installed? ])
+               AC_MSG_RESULT([yes])
                AC_CHECK_HEADER([libqhull_r/libqhull_r.h], [
                   AC_SEARCH_LIBS([qh_distplane], [qhull_r], [
-                     AC_MSG_RESULT([yes. Use system's qhull])
                   ], [
-                  AC_MSG_RESULT([no. Install qhull])
-                  sage_spkg_install_qhull=yes]) dnl SEARCH_LIBS
+                    sage_spkg_install_qhull=yes
+                  ])dnl AC_SEARCH_LIBS
                ], [
-                  AC_MSG_RESULT([no. Install qhull])
                   sage_spkg_install_qhull=yes
-               ]), dnl CHECK_HEADER
+               ])dnl AC_CHECK_HEADER
            ], [
-               AC_MSG_RESULT([no. Install qhull])
                sage_spkg_install_qhull=yes
-           ]) dnl AX_COMPARE_VERSION
-    ]) dnl IF
+           ])dnl AX_COMPARE_VERSION
+    ])dnl IF
     m4_popdef([SAGE_QHULL_MINVER])
 ])

build/pkgs/xz/spkg-configure.m4

@@ -16,7 +16,7 @@ SAGE_SPKG_CONFIGURE([xz], [
         dnl on the xz binary (for unpacking the tarball in sage_bootstrap.uncompress.tar_file
         dnl - when sage-bootstrap-python is so old that it cannot do that by itself).
         dnl Packages that depend on actual xz or liblzma should depend on the liblzma spkg.
-        AS_IF(["$SAGE_BOOTSTRAP_PYTHON" -c "import lzma"], [
+        AS_IF(["$SAGE_BOOTSTRAP_PYTHON" -c "import lzma" 2>& AS_MESSAGE_LOG_FD], [
              sage_require_xz=no
         ])
 ])