MoveInitializers and parser loops

[fruffy]

There seems to be a problem in the way the compiler moves initializers in the parser. I stripped issue281.p4 to the essentials (attached). After MoveInitializers

parser L3(packet_in b, inout h hdr) {
    bit<16> etherType_0 = hdr.ether.etherType;
    state start {
        transition select(etherType_0) {
            16w0x800: h;
            16w0x8100: i;
            default: accept;
        }
    }
    state h {
        b.extract<H>(hdr.h);
        transition accept;
    }
    state i {
        b.extract<I>(hdr.i);
        etherType_0 = hdr.i.etherType;
        transition start;
    }
}

parser MyParser(packet_in b, out h hdr, inout m meta, inout standard_metadata_t std) {
    @name("l3") L3() l3_0;
    state start {
        b.extract<ethernet_t>(hdr.ether);
        l3_0.apply(b, hdr);
        transition accept;
    }
}

turns into

parser L3(packet_in b, inout h hdr) {
    bit<16> etherType_0;
    state start {
        etherType_0 = hdr.ether.etherType;
        transition select(etherType_0) {
            16w0x800: h;
            16w0x8100: i;
            default: accept;
        }
    }
    state h {
        b.extract<H>(hdr.h);
        transition accept;
    }
    state i {
        b.extract<I>(hdr.i);
        etherType_0 = hdr.i.etherType;
        transition start;
    }
}

parser MyParser(packet_in b, out h hdr, inout m meta, inout standard_metadata_t std) {
    @name("l3") L3() l3_0;
    state start {
        b.extract<ethernet_t>(hdr.ether);
        l3_0.apply(b, hdr);
        transition accept;
    }
}

There is a problem with moving etherType_0 = hdr.ether.etherType; into start.
In state i etherType_0 is assigned the value hdr.i.etherType. This is essentially ignored once the parser transitions back to state start because etherType_0 = hdr.ether.etherType; has been moved there.

I unfortunately do not have a stf test for this yet.

issue281_stripped.p4.txt