Overhaul build and project systems and drop Mac/POSIX code

scripts/Build.bat

@@ -0,0 +1,98 @@
+@ECHO OFF
+CALL %~dp0\InitializeEnvironment.bat || EXIT /b 10
+SETLOCAL
+SETLOCAL EnableDelayedExpansion
+
+IF "%~1"=="" (
+    SET CONFIGURATION=Debug
+) ELSE (
+    SET CONFIGURATION=%1
+)
+
+IF "%~2"=="" (
+    SET GVFSVERSION=0.2.173.2
+) ELSE (
+    SET GVFSVERSION=%2
+)
+
+IF "%~3"=="" (
+    SET VERBOSITY=minimal
+) ELSE (
+    SET VERBOSITY=%3
+)
+
+REM If we have MSBuild on the PATH then go straight to the build phase
+FOR /F "tokens=* USEBACKQ" %%F IN (`where msbuild.exe`) DO (
+    SET MSBUILD_EXEC=%%F
+    ECHO INFO: Found msbuild.exe at '%%F'
+    GOTO :BUILD
+)
+
+:LOCATE_MSBUILD
+REM Locate MSBuild via the vswhere tool
+FOR /F "tokens=* USEBACKQ" %%F IN (`where nuget.exe`) DO (
+    SET NUGET_EXEC=%%F
+    ECHO INFO: Found nuget.exe at '%%F'
+)
+
+REM NuGet is required to be on the PATH to install vswhere
+IF NOT EXIST "%NUGET_EXEC%" (
+    ECHO ERROR: Could not find nuget.exe on the PATH
+    EXIT /B 10
+)
+
+REM Acquire vswhere to find VS installations reliably
+SET VSWHERE_VER=2.6.7
+"%NUGET_EXEC%" install vswhere -Version %VSWHERE_VER% || exit /b 1
+SET VSWHERE_EXEC=%VFS_PACKAGESDIR%\vswhere.%VSWHERE_VER%\tools\vswhere.exe
+
+REM Assumes default installation location for Windows 10 SDKs
+IF NOT EXIST "C:\Program Files (x86)\Windows Kits\10\Include\10.0.16299.0" (
+    ECHO ERROR: Could not find Windows 10 SDK Version 16299
+    EXIT /B 1
+)
+
+REM Use vswhere to find the latest VS installation with the MSBuild component
+REM See https://github.com/Microsoft/vswhere/wiki/Find-MSBuild
+FOR /F "tokens=* USEBACKQ" %%F IN (`%VSWHERE_EXEC% -all -prerelease -latest -products * -requires Microsoft.Component.MSBuild -find MSBuild\**\Bin\amd64\MSBuild.exe`) DO (
+    SET MSBUILD_EXEC=%%F
+    ECHO INFO: Found msbuild.exe at '%%F'
+)
+
+:BUILD
+IF NOT DEFINED MSBUILD_EXEC (
+  ECHO ERROR: Could not locate a Visual Studio installation with required components.
+  ECHO Refer to Readme.md for a list of the required Visual Studio components.
+  EXIT /B 10
+)
+
+ECHO ^**********************
+ECHO ^* Restoring Packages *
+ECHO ^**********************
+"%MSBUILD_EXEC%" %VFS_SRCDIR%\GVFS.sln ^
+        /t:Restore ^
+        /v:%VERBOSITY% ^
+        /p:Configuration=%CONFIGURATION% || GOTO ERROR
+
+ECHO ^*********************
+ECHO ^* Building Solution *
+ECHO ^*********************
+"%MSBUILD_EXEC%" %VFS_SRCDIR%\GVFS.sln ^
+        /t:Build ^
+        /v:%VERBOSITY% ^
+        /p:Configuration=%CONFIGURATION% || GOTO ERROR
+
+GOTO :EOF
+
+:USAGE
+ECHO usage: %~n0%~x0 [^<configuration^>] [^<version^>] [^<verbosity^>]
+ECHO.
+ECHO   configuration    Solution configuration (default: Debug).
+ECHO   version          GVFS version (default: 0.2.173.2).
+ECHO   verbosity        MSBuild verbosity (default: minimal).
+ECHO.
+EXIT 1
+
+:ERROR
+ECHO ERROR: Build failed with exit code %ERRORLEVEL%
+EXIT /B %ERRORLEVEL%

scripts/CreateBuildArtifacts.bat

@@ -0,0 +1,88 @@
+@ECHO OFF
+CALL %~dp0\InitializeEnvironment.bat || EXIT /b 10
+SETLOCAL
+
+IF "%~1"=="" (
+    SET CONFIGURATION=Debug
+) ELSE (
+    SET CONFIGURATION=%1
+)
+
+IF "%~2"=="" (
+    SET OUTROOT=%VFS_PUBLISHDIR%
+) ELSE (
+    SET OUTROOT=%2
+)
+
+REM Check NuGet is on the PATH
+where /q nuget.exe
+IF ERRORLEVEL 1 (
+    ECHO ERROR: Could not find nuget.exe on the PATH
+    EXIT /B 1
+)
+
+IF EXIST %OUTROOT% (
+  rmdir /s /q %OUTROOT%
+)
+
+ECHO ^**********************
+ECHO ^* Collecting Symbols *
+ECHO ^**********************
+mkdir %OUTROOT%\Symbols
+SET COPY_SYM_CMD="&{Get-ChildItem -Recurse -Path '%VFS_OUTDIR%' -Include *.pdb | Where-Object FullName -Match '\\bin\\.*\\?%CONFIGURATION%\\' | Copy-Item -Destination '%OUTROOT%\Symbols'}"
+powershell ^
+    -NoProfile ^
+    -ExecutionPolicy Bypass ^
+    -Command %COPY_SYM_CMD% || GOTO ERROR
+
+ECHO ^******************************
+ECHO ^* Collecting GVFS.Installers *
+ECHO ^******************************
+mkdir %OUTROOT%\GVFS.Installers
+xcopy /S /Y ^
+    %VFS_OUTDIR%\GVFS.Installers\bin\%CONFIGURATION%\win-x64 ^
+    %OUTROOT%\GVFS.Installers\ || GOTO ERROR
+
+ECHO ^************************
+ECHO ^* Collecting FastFetch *
+ECHO ^************************
+ECHO Collecting FastFetch...
+mkdir %OUTROOT%\FastFetch
+xcopy /S /Y ^
+    %VFS_OUTDIR%\FastFetch\bin\%CONFIGURATION%\net461\win-x64 ^
+    %OUTROOT%\FastFetch\ || GOTO ERROR
+
+ECHO ^***********************************
+ECHO ^* Collecting GVFS.FunctionalTests *
+ECHO ^***********************************
+mkdir %OUTROOT%\GVFS.FunctionalTests
+xcopy /S /Y ^
+    %VFS_OUTDIR%\GVFS.FunctionalTests\bin\%CONFIGURATION%\net461\win-x64 ^
+    %OUTROOT%\GVFS.FunctionalTests\ || GOTO ERROR
+
+ECHO ^*************************************
+ECHO ^* Creating Installers NuGet Package *
+ECHO ^*************************************
+mkdir %OUTROOT%\NuGetPackages
+nuget.exe pack ^
+    %VFS_OUTDIR%\GVFS.Installers\bin\%CONFIGURATION%\win-x64\GVFS.Installers.nuspec ^
+    -BasePath %VFS_OUTDIR%\GVFS.Installers\bin\%CONFIGURATION%\win-x64 ^
+    -OutputDirectory %OUTROOT%\NuGetPackages || GOTO ERROR
+
+REM Move the nuspec file to the NuGetPackages artifact directory
+move %OUTROOT%\GVFS.Installers\GVFS.Installers.nuspec ^
+    %OUTROOT%\NuGetPackages
+
+GOTO :EOF
+
+:USAGE
+ECHO usage: %~n0%~x0 [^<configuration^>] [^<destination^>]
+ECHO.
+ECHO   configuration    Solution configuration (default: Debug).
+ECHO   destination      Destination directory to copy artifacts (default: %VFS_PUBLISHDIR%).
+ECHO.
+EXIT 1
+
+:ERROR
+ECHO ERROR: Create build artifacts failed with exit code %ERRORLEVEL%
+EXIT /B %ERRORLEVEL%

scripts/InitializeEnvironment.bat

@@ -0,0 +1,25 @@
+@IF "%_echo%"=="" (ECHO OFF) ELSE (ECHO ON)
+
+REM Set environment variables for interesting paths that scripts might need access to.
+PUSHD %~dp0
+SET VFS_SCRIPTSDIR=%CD%
+POPD
+
+CALL :RESOLVEPATH "%VFS_SCRIPTSDIR%\.."
+SET VFS_SRCDIR=%_PARSED_PATH_%
+
+CALL :RESOLVEPATH "%VFS_SRCDIR%\.."
+SET VFS_ENLISTMENTDIR=%_PARSED_PATH_%
+
+SET VFS_OUTDIR=%VFS_ENLISTMENTDIR%\out
+SET VFS_PACKAGESDIR=%VFS_ENLISTMENTDIR%\packages
+SET VFS_PUBLISHDIR=%VFS_ENLISTMENTDIR%\publish
+
+REM Clean up
+SET _PARSED_PATH_=
+
+GOTO :EOF
+
+:RESOLVEPATH
+SET "_PARSED_PATH_=%~f1"
+GOTO :EOF

scripts/RunFunctionalTests.bat

@@ -0,0 +1,37 @@
+@ECHO OFF
+CALL %~dp0\InitializeEnvironment.bat || EXIT /b 10
+
+IF "%1"=="" (SET "CONFIGURATION=Debug") ELSE (SET "CONFIGURATION=%1")
+
+REM Ensure GVFS installation is on the PATH for the Functional Tests to find
+SETLOCAL
+SET PATH=C:\Program Files\GVFS;C:\Program Files\Git\cmd;%PATH%
+
+ECHO PATH = %PATH%
+
+ECHO gvfs location:
+where gvfs
+IF NOT %ERRORLEVEL% == 0 (
+    ECHO error: unable to locate GVFS on the PATH (has it been installed?)
+    EXIT /b 1
+)
+
+ECHO GVFS.Service location:
+where GVFS.Service
+IF NOT %ERRORLEVEL% == 0 (
+    ECHO error: unable to locate GVFS.Service on the PATH (has it been installed?)
+    EXIT /b 1
+)
+
+ECHO git location:
+where git
+IF NOT %ERRORLEVEL% == 0 (
+    ECHO error: unable to locate Git on the PATH (has it been installed?)
+    EXIT /b 1
+)
+
+%VFS_OUTDIR%\GVFS.FunctionalTests\bin\%CONFIGURATION%\net461\win-x64\GVFS.FunctionalTests.exe /result:TestResult.xml %2 %3 %4 %5
+
+SET error=%ERRORLEVEL%
+CALL %VFS_SCRIPTSDIR%\StopAllServices.bat
+EXIT /b %error%

scripts/RunUnitTests.bat

@@ -0,0 +1,10 @@
+@ECHO OFF
+CALL %~dp0\InitializeEnvironment.bat || EXIT /b 10
+
+IF "%1"=="" (SET "CONFIGURATION=Debug") ELSE (SET "CONFIGURATION=%1")
+
+SET RESULT=0
+
+%VFS_OUTDIR%\GVFS.UnitTests\bin\%CONFIGURATION%\net461\win-x64\GVFS.UnitTests.exe || SET RESULT=1
+
+EXIT /b %RESULT%

scripts/StopAllServices.bat

@@ -0,0 +1,5 @@
+@ECHO OFF
+CALL %~dp0\InitializeEnvironment.bat || EXIT /b 10
+
+CALL %VFS_SCRIPTSDIR%\StopService.bat GVFS.Service
+CALL %VFS_SCRIPTSDIR%\StopService.bat Test.GVFS.Service

scripts/StopService.bat

@@ -0,0 +1,2 @@
+sc stop %1
+verify >nul