Build system update (Minestom#527)

.gitignore

@@ -31,7 +31,7 @@
 hs_err_pid*
 
 ### Gradle template
-.gradle
+**/.gradle
 **/build/
 
 # Ignore Gradle GUI config
@@ -53,5 +53,6 @@ gradle-app.setting
 /src/main/java/com/mcecraft/
 
 # When running the demo we generate the extensions folder
-/extensions/
-/.mixin.out/
+# Incase people are using IntelliJ to run the server, this will exclude extensions from any folder.
+/demo/extensions
+/extensions

build-logic/build.gradle.kts

@@ -0,0 +1,16 @@
+plugins {
+    `kotlin-dsl`
+}
+
+repositories {
+    mavenCentral()
+    gradlePluginPortal()
+}
+
+dependencies {
+    val indraVersion = "2.0.6"
+    implementation("org.jetbrains.kotlin", "kotlin-gradle-plugin", "1.6.10")
+    implementation("net.kyori", "indra-common", indraVersion)
+    implementation("net.kyori", "indra-publishing-sonatype", indraVersion)
+    implementation("org.graalvm.buildtools", "native-gradle-plugin", "0.9.9")
+}

build-logic/src/main/kotlin/minestom.common-conventions.gradle.kts

@@ -0,0 +1,25 @@
+plugins {
+    java
+}
+
+// Always exclude checker-qual. This is the single most annoying thing that always reappears.
+configurations.all {
+    // We only use Jetbrains Annotations
+    exclude("org.checkerframework", "checker-qual")
+}
+
+java {
+    toolchain {
+        languageVersion.set(JavaLanguageVersion.of(17))
+    }
+}
+
+tasks {
+    withType<JavaCompile> {
+        // We are fully aware, that we should be suppressing these instead of ignoring them here, but man keep my terminal clean.
+        options.compilerArgs.addAll(listOf("-Xlint:none", "-Xlint:-deprecation", "-Xlint:-unchecked"))
+    }
+    withType<Test> {
+        useJUnitPlatform()
+    }
+}

build-logic/src/main/kotlin/minestom.native-conventions.gradle.kts

@@ -0,0 +1,14 @@
+plugins {
+    id("minestom.common-conventions")
+    id("org.graalvm.buildtools.native")
+}
+
+graalvmNative {
+    binaries {
+        named("main") {
+            buildArgs.add("--allow-incomplete-classpath")
+            // One day toolchains will support getting this automagically, but that day is not today.
+            toolchainDetection.set(false)
+        }
+    }
+}

build-logic/src/main/kotlin/minestom.publishing-conventions.gradle.kts

@@ -0,0 +1,32 @@
+plugins {
+    id("net.kyori.indra")
+    id("net.kyori.indra.publishing")
+    id("net.kyori.indra.publishing.sonatype")
+}
+
+indra {
+    javaVersions {
+        target(17)
+        testWith(17)
+    }
+
+    github("Minestom", "Minestom") {
+        ci(true)
+    }
+    apache2License()
+
+    configurePublications {
+        pom {
+            developers {
+                developer {
+                    id.set("TheMode")
+                    name.set("TheMode")
+                }
+                developer {
+                    id.set("jglrxavpok")
+                    name.set("jglrxavpok")
+                }
+            }
+        }
+    }
+}

build.gradle.kts

@@ -0,0 +1,84 @@
+plugins {
+    `java-library`
+    id("minestom.publishing-conventions")
+    id("minestom.native-conventions")
+}
+
+allprojects {
+    group = "net.minestom.server"
+    version = "1.0"
+    description = "Lightweight and multi-threaded Minecraft server implementation"
+}
+
+sourceSets {
+    main {
+        java {
+            srcDir(file("src/autogenerated/java"))
+        }
+    }
+}
+
+java {
+    withJavadocJar()
+    withSourcesJar()
+}
+
+tasks {
+    withType<Javadoc> {
+        (options as? StandardJavadocDocletOptions)?.apply {
+            encoding = "UTF-8"
+
+            // Custom options
+            addBooleanOption("html5", true)
+            addStringOption("-release", "17")
+            // Links to external javadocs
+            links("https://docs.oracle.com/en/java/javase/17/docs/api/")
+            links("https://jd.adventure.kyori.net/api/${libs.versions.adventure.get()}/")
+        }
+    }
+    withType<Zip> {
+        duplicatesStrategy = DuplicatesStrategy.EXCLUDE
+    }
+}
+
+dependencies {
+    // Junit Testing Framework
+    testImplementation(libs.junit.api)
+    testRuntimeOnly(libs.junit.engine)
+    // Only here to ensure J9 module support for extensions and our classloaders
+    testCompileOnly(libs.mockito.core)
+
+
+    // Logging
+    implementation(libs.bundles.logging)
+    // Libraries required for the terminal
+    implementation(libs.bundles.terminal)
+
+    // Performance improving libraries
+    implementation(libs.caffeine)
+    api(libs.fastutil)
+    implementation(libs.bundles.flare)
+
+    // Libraries
+    api(libs.guava)
+    api(libs.gson)
+    implementation(libs.jcTools)
+    // Path finding
+    api(libs.hydrazine)
+
+    // Adventure, for user-interface
+    api(libs.bundles.adventure)
+
+    // Kotlin Libraries
+    api(libs.bundles.kotlin)
+
+    // Extension Management System dependency handler.
+    api(libs.dependencyGetter)
+
+    // Minestom Data (From MinestomDataGenerator)
+    implementation(libs.minestomData)
+
+    // NBT parsing/manipulation/saving
+    api("io.github.jglrxavpok.hephaistos:common:${libs.versions.hephaistos.get()}")
+    api("io.github.jglrxavpok.hephaistos:gson:${libs.versions.hephaistos.get()}")
+}