Unable to get Netfox functions to fire

[jeremyhcho]

I have what I think should be a pretty basic setup of Netfox spawning a player and accepting some movement input but I can't seem to get the functions to fire. Here's what things look like on my end:

In player.tscn, I have these nodes added

With the main RollbackSynchronizer configured like

And the Player script implementing the _rollback_tick function

func _rollback_tick(delta: float, _tick: int, _is_fresh: bool) -> void:
    # Add the gravity.
    _force_update_is_on_floor()
    if not is_on_floor():
        velocity.y -= gravity * delta

    var direction = Vector3(input.input_dir.x, 0, input.input_dir.y).normalized()
    if direction:
        velocity.x = direction.x * speed
        velocity.z = direction.z * speed
    else:
        velocity.x = move_toward(velocity.x, 0, speed)
        velocity.z = move_toward(velocity.z, 0, speed)

    # Apply movement
    velocity *= NetworkTime.physics_factor
    move_and_slide()
    velocity /= NetworkTime.physics_factor

I have a Player scene being spawned by the server and the spawning of the player seems to get relayed to the clients as I see the spawned Player scene within the client's scene tree.

In here, I can see that the RollbackSynchronizer's Earliest Input field is continuously increasing which makes me think that something is working but when I add a print statement inside the Player scene's _rollback_tick method, it never fires.

I'm pretty sure I'm missing something super obvious but any help would be greatly appreciated!

Edit: Maybe relevant so I'll add what my player input script looks like. The _gather function here is also not being entered on the client.

class_name PlayerInput
extends BaseNetInput


var input_dir: Vector2 = Vector2.ZERO


func _gather():
    input_dir = Input.get_vector(
        "move_left",
        "move_right",
        "move_forward",
        "move_backward"
    ) 

[jeremyhcho]

After debugging this a bit it seems like

    var input = player.find_child("Input")
    if input != null:
        input.set_multiplayer_authority(id)
        print("Set input(%s) ownership to %s" % [input.name, id])

Doesn't seem to be setting the multiplayer authority correctly which prevents _gather from ever being called

[albertok]

Whats your _ready function look like in the CharacterController?

Make sure you are initialising the rollback synchronizer there and probably also the best place to set authority on the Input.

Something like:

@onready var inputs : PlayerInput = $Input
@onready var rollback_synchronizer: RollbackSynchronizer = $RollbackSynchronizer

func _ready():
        inputs.set_multiplayer_authority(id)

	#Give things a frame to apply, then tell rollback synchronizer to refresh
	await get_tree().process_frame
	rollback_synchronizer.process_settings()
	

[jeremyhcho]

Ah yeah, that seemed to be it. I was calling set_multiplayer_authority from the server which doesn't propagate. Thank you!