elastic · nik9000 · May 5, 2016 · Apr 29, 2016
diff --git a/buildSrc/src/main/groovy/org/elasticsearch/gradle/RestTestsFromSnippetsTask.groovy b/buildSrc/src/main/groovy/org/elasticsearch/gradle/RestTestsFromSnippetsTask.groovy
@@ -0,0 +1,214 @@
+/*
+ * Licensed to Elasticsearch under one or more contributor
+ * license agreements. See the NOTICE file distributed with
+ * this work for additional information regarding copyright
+ * ownership. Elasticsearch licenses this file to you under
+ * the Apache License, Version 2.0 (the "License"); you may
+ * not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *    http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing,
+ * software distributed under the License is distributed on an
+ * "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
+ * KIND, either express or implied.  See the License for the
+ * specific language governing permissions and limitations
+ * under the License.
+ */
+
+package org.elasticsearch.gradle
+
+import org.elasticsearch.gradle.SnippetsTask.Snippet
+import org.gradle.api.InvalidUserDataException
+import org.gradle.api.tasks.Input
+import org.gradle.api.tasks.OutputDirectory
+
+import java.nio.file.Files
+import java.nio.file.Path
+import java.util.regex.Matcher
+
+/**
+ * Generates REST tests for each snippet marked // TEST.
+ */
+public class RestTestsFromSnippetsTask extends SnippetsTask {
+    @Input
+    Map<String, String> setups = new HashMap()
+
+    /**
+     * Root directory of the tests being generated. To make rest tests happy
+     * we generate them in a testRoot() which is contained in this directory.
+     */
+    @OutputDirectory
+    File testRoot = project.file('build/rest')
+
+    public RestTestsFromSnippetsTask() {
+        project.afterEvaluate {
+            // Wait to set this so testRoot can be customized
+            project.sourceSets.test.output.dir(testRoot, builtBy: this)
+        }
+        TestBuilder builder = new TestBuilder()
+        doFirst { outputRoot().delete() }
+        perSnippet builder.&handleSnippet
+        doLast builder.&finishLastTest
+    }
+
+    /**
+     * Root directory containing all the files generated by this task. It is
+     * contained withing testRoot.
+     */
+    File outputRoot() {
+        return new File(testRoot, '/rest-api-spec/test')
+    }
+
+    private class TestBuilder {
+        private static final String SYNTAX = {
+            String method = /(?<method>GET|PUT|POST|HEAD|OPTIONS|DELETE)/
+            String pathAndQuery = /(?<pathAndQuery>[^\n]+)/
+            String badBody = /GET|PUT|POST|HEAD|OPTIONS|DELETE|#/
+            String body = /(?<body>(?:\n(?!$badBody)[^\n]+)+)/
+            String nonComment = /$method\s+$pathAndQuery$body?/
+            String comment = /(?<comment>#.+)/
+            /(?:$comment|$nonComment)\n+/
+        }()
+
+        /**
+         * The file in which we saw the last snippet that made a test.
+         */
+        Path lastDocsPath
+
+        /**
+         * The file we're building.
+         */
+        PrintWriter current
+
+        /**
+         * Called each time a snippet is encountered. Tracks the snippets and
+         * calls buildTest to actually build the test.
+         */
+        void handleSnippet(Snippet snippet) {
+            if (snippet.testSetup) {
+                setup(snippet)
+                return
+            }
+            if (snippet.testResponse) {
+                response(snippet)
+                return
+            }
+            if (snippet.test || snippet.autoSense) {
+                test(snippet)
+                return
+            }
+            // Must be an unmarked snippet....
+        }
+
+        private void test(Snippet test) {
+            setupCurrent(test)
+
+            if (false == test.continued) {
+                current.println('---')
+                current.println("\"$test.start\":")
+            }
+            if (test.skipTest) {
+                current.println("  - skip:")
+                current.println("      features: always_skip")
+                current.println("      reason: $test.skipTest")
+            }
+            if (test.setup != null) {
+                String setup = setups[test.setup]
+                if (setup == null) {
+                    throw new InvalidUserDataException("Couldn't find setup "
+                        + "for $test")
+                }
+                current.println(setup)
+            }
+
+            body(test)
+        }
+
+        private void response(Snippet response) {
+            current.println("  - response_body: |")
+            response.contents.eachLine { current.println("      $it") }
+        }
+
+        void emitDo(String method, String pathAndQuery,
+                String body, String catchPart) {
+            def (String path, String query) = pathAndQuery.tokenize('?')
+            current.println("  - do:")
+            if (catchPart != null) {
+                current.println("      catch: $catchPart")
+            }
+            current.println("      raw:")
+            current.println("        method: $method")
+            current.println("        path: \"$path\"")
+            if (query != null) {
+                for (String param: query.tokenize('&')) {
+                    def (String name, String value) = param.tokenize('=')
+                    current.println("        $name: \"$value\"")
+                }
+            }
+            if (body != null) {
+                // Throw out the leading newline we get from parsing the body
+                body = body.substring(1)
+                current.println("        body: |")
+                body.eachLine { current.println("          $it") }
+            }
+        }
+
+        private void setup(Snippet setup) {
+            if (lastDocsPath == setup.path) {
+                throw new InvalidUserDataException("$setup: wasn't first")
+            }
+            setupCurrent(setup)
+            current.println('---')
+            current.println("setup:")
+            body(setup)
+        }
+
+        private void body(Snippet snippet) {
+            parse("$snippet", snippet.contents, SYNTAX) { matcher, last ->
+                if (matcher.group("comment") != null) {
+                    // Comment
+                    return
+                }
+                String method = matcher.group("method")
+                String pathAndQuery = matcher.group("pathAndQuery")
+                String body = matcher.group("body")
+                String catchPart = last ? snippet.catchPart : null
+                if (pathAndQuery.startsWith('/')) {
+                    // Why not do some light linting while we're here?
+                    throw new InvalidUserDataException(
+                        "Path shouldn't start with a '/': $snippet\n"
+                        + snippet.contents)
+                }
+                emitDo(method, pathAndQuery, body, catchPart)
+            }
+        }
+
+        private PrintWriter setupCurrent(Snippet test) {
+            if (lastDocsPath == test.path) {
+                return
+            }
+            finishLastTest()
+            lastDocsPath = test.path
+
+            // Make the destination file:
+            // Shift the path into the destination directory tree
+            Path dest = outputRoot().toPath().resolve(test.path)
+            // Replace the extension
+            String fileName = dest.getName(dest.nameCount - 1)
+            dest = dest.parent.resolve(fileName.replace('.asciidoc', '.yaml'))
+
+            // Now setup the writer
+            Files.createDirectories(dest.parent)
+            current = dest.newPrintWriter()
+        }
+
+        void finishLastTest() {
+            if (current != null) {
+                current.close()
+                current = null
+            }
+        }
+    }
+}