Set sync or flush_on_newline for standard I/O on Windows.

src/crystal/system/unix/file_descriptor.cr

@@ -161,4 +161,24 @@ module Crystal::System::FileDescriptor
 
     bytes_read
   end
+
+  def self.from_stdio(fd)
+    # If we have a TTY for stdin/out/err, it is possibly a shared terminal.
+    # We need to reopen it to use O_NONBLOCK without causing other programs to break
+
+    # Figure out the terminal TTY name. If ttyname fails we have a non-tty, or something strange.
+    # For non-tty we set flush_on_newline to true for reasons described in STDOUT and STDERR docs.
+    path = uninitialized UInt8[256]
+    ret = LibC.ttyname_r(fd, path, 256)
+    return IO::FileDescriptor.new(fd).tap(&.flush_on_newline=(true)) unless ret == 0
+
+    clone_fd = LibC.open(path, LibC::O_RDWR)
+    return IO::FileDescriptor.new(fd).tap(&.flush_on_newline=(true)) if clone_fd == -1
+
+    # We don't buffer output for TTY devices to see their output right away
+    io = IO::FileDescriptor.new(clone_fd)
+    io.close_on_exec = true
+    io.sync = true
+    io
+  end
 end

src/crystal/system/win32/file_descriptor.cr

@@ -1,4 +1,5 @@
 require "c/io"
+require "c/consoleapi"
 
 module Crystal::System::FileDescriptor
   @volatile_fd : Atomic(LibC::Int)
@@ -162,4 +163,24 @@ module Crystal::System::FileDescriptor
 
     bytes_read
   end
+
+  def self.from_stdio(fd)
+    console_handle = false
+    handle = LibC._get_osfhandle(fd)
+    if handle != -1
+      if LibC.GetConsoleMode(LibC::HANDLE.new(handle), out _) != 0
+        console_handle = true
+      end
+    end
+
+    io = IO::FileDescriptor.new(fd)
+    # Set sync or flush_on_newline as described in STDOUT and STDERR docs.
+    # See https://crystal-lang.org/api/toplevel.html#STDERR
+    if console_handle
+      io.sync = true
+    else
+      io.flush_on_newline = true
+    end
+    io
+  end
 end

src/io/file_descriptor.cr

@@ -32,27 +32,7 @@ class IO::FileDescriptor < IO
 
   # :nodoc:
   def self.from_stdio(fd)
-    {% if flag?(:win32) %}
-      new(fd)
-    {% else %}
-      # If we have a TTY for stdin/out/err, it is possibly a shared terminal.
-      # We need to reopen it to use O_NONBLOCK without causing other programs to break
-
-      # Figure out the terminal TTY name. If ttyname fails we have a non-tty, or something strange.
-      # For non-tty we set flush_on_newline to true for reasons described in STDOUT and STDERR docs.
-      path = uninitialized UInt8[256]
-      ret = LibC.ttyname_r(fd, path, 256)
-      return new(fd).tap(&.flush_on_newline=(true)) unless ret == 0
-
-      clone_fd = LibC.open(path, LibC::O_RDWR)
-      return new(fd).tap(&.flush_on_newline=(true)) if clone_fd == -1
-
-      # We don't buffer output for TTY devices to see their output right away
-      io = new(clone_fd)
-      io.close_on_exec = true
-      io.sync = true
-      io
-    {% end %}
+    Crystal::System::FileDescriptor.from_stdio(fd)
   end
 
   def blocking

src/lib_c/x86_64-windows-msvc/c/consoleapi.cr

@@ -0,0 +1,5 @@
+require "c/winnt"
+
+lib LibC
+  fun GetConsoleMode(hConsoleHandle : HANDLE, lpMode : DWORD*) : BOOL
+end