Implement sum

src/BandedMatrices.jl

@@ -7,7 +7,7 @@ import Base: axes, axes1, getproperty, getindex, setindex!, *, +, -, ==, <, <=,
                >=, /, \, adjoint, transpose, showerror, convert, size, view,
                unsafe_indices, first, last, size, length, unsafe_length, step, to_indices,
                to_index, show, fill!, similar, copy, promote_rule, real, imag,
-               copyto!, Array
+               copyto!, Array, sum
 
 using Base.Broadcast: AbstractArrayStyle, DefaultArrayStyle, Broadcasted
 import Base.Broadcast: BroadcastStyle, broadcasted
@@ -99,4 +99,5 @@ end
 include("precompile.jl")
 
 
+
 end #module

src/banded/BandedMatrix.jl

@@ -1007,3 +1007,45 @@
     l,u = bandwidths(A)
     _BandedMatrix(reshape(resize!(vec(copy(bandeddata(A))), (l+u+1)*m), l+u+1, m), n, l,u)
 end
+
+function sum(A::BandedMatrix; dims=:)
+    if dims isa Colon
+        l, u = bandwidths(A)
+        ret = zero(eltype(A))
+        if l + u < 0
+            return ret
+        end
+        n, m = size(A)
+        for i = 1:n, j = rowrange(A, i)
+            ret += A[i, j]
+        end
+        ret
+    elseif dims > 2
+        A
+    elseif dims == 2
+        l, u = bandwidths(A)
+        n, m = size(A)
+        ret = zeros(eltype(A), n, 1)
+        if l + u < 0
+            return ret
+        end
+        for i = 1:n, j = rowrange(A, i)
+            ret[i, 1] += A[i, j]
+        end
+        ret
+    elseif dims == 1
+        l, u = bandwidths(A)
+        n, m = size(A)
+        ret = zeros(eltype(A), 1, m)
+        if l + u < 0
+            return ret
+        end
+        for i = 1:m, j = colrange(A, i)
+            ret[1, i] += A[j, i]
+        end
+        ret
+    else
+        throw(ArgumentError("dimension must be ≥ 1, got $dims"))
+    end
+end
+

test/runtests.jl

@@ -26,3 +26,4 @@ include("test_symbanded.jl")
 include("test_tribanded.jl")
 include("test_interface.jl")
 include("test_miscs.jl")
+include("test_sum.jl")

test/test_sum.jl

@@ -0,0 +1,20 @@
+module TestSum
+
+using Test, BandedMatrices, Random
+
+r = brand(Float64,rand(1:10_000),rand(1:10_000),rand(-20:100),rand(-20:100))
+empty_r = brand(Float64,rand(1:1_000),rand(1:1_000),rand(1:100),rand(-200:-101))
+n,m = size(empty_r)
+matr = Matrix(r)
+@testset "sum" begin
+    @test sum(empty_r) ≈ 0
+    @test sum(empty_r; dims = 2) ≈ zeros(n,1)
+    @test sum(empty_r; dims = 1) ≈ zeros(1,m)
+    @test sum(r) ≈ sum(matr) rtol = 1e-10
+    @test sum(r; dims=2) ≈ sum(matr; dims=2) rtol = 1e-10
+    @test sum(r; dims=1) ≈ sum(matr; dims=1) rtol = 1e-10
+    @test sum(r; dims=3) == r
+    @test_throws ArgumentError sum(r; dims=0)
+end
+
+end