IntelRealSense · maloel · Jul 20, 2023 · Mar 13, 2023 · Mar 13, 2023 · Mar 13, 2023
diff --git a/.github/workflows/buildsCI.yaml b/.github/workflows/buildsCI.yaml
@@ -351,7 +351,7 @@ jobs:
 
 
   #--------------------------------------------------------------------------------
-  U20_ST_Py_DDS_CI:  # Ubuntu 2020, Static, Python, DDS, LibCI without executables
+  U20_ST_Py_DDS_RSUSB_CI:  # Ubuntu 2020, Static, Python, DDS, RSUSB, LibCI without executables
     runs-on: ubuntu-20.04
     timeout-minutes: 60
     steps:
@@ -381,18 +381,21 @@ jobs:
         mkdir build
 
     - name: Build
+      # Note: we force RSUSB because, on Linux, the context creation will fail on GHA:
+      #     (backend-v4l2.cpp:555) Cannot access /sys/class/video4linux)
+      # And, well, we don't need any specific platform for DDS!
       shell: bash
       run: |
         cd build
-        cmake .. -DCMAKE_BUILD_TYPE=${{env.LRS_RUN_CONFIG}} -DBUILD_SHARED_LIBS=false -DBUILD_EXAMPLES=false -DBUILD_TOOLS=true -DBUILD_UNIT_TESTS=false -DCHECK_FOR_UPDATES=false -DBUILD_WITH_DDS=true -DBUILD_PYTHON_BINDINGS=true -DPYTHON_EXECUTABLE=$(which python3)
+        cmake .. -DCMAKE_BUILD_TYPE=${{env.LRS_RUN_CONFIG}} -DBUILD_SHARED_LIBS=false -DBUILD_EXAMPLES=false -DBUILD_TOOLS=false -DBUILD_UNIT_TESTS=false -DCHECK_FOR_UPDATES=false -DBUILD_WITH_DDS=true -DBUILD_PYTHON_BINDINGS=true -DPYTHON_EXECUTABLE=$(which python3) -DFORCE_RSUSB_BACKEND=true
         cmake --build . -- -j4  
 
     - name: LibCI
       # Note: we specifically disable BUILD_UNIT_TESTS so the executable C++ unit-tests won't run
       # This is to save time as DDS already lengthens the build...
       shell: bash
       run: |
-        python3 unit-tests/run-unit-tests.py --no-color --debug --stdout --not-live --context "dds linux"
+        python3 unit-tests/run-unit-tests.py --no-color --debug --stdout --not-live --context "dds linux" --tag dds
 
 
   #--------------------------------------------------------------------------------

diff --git a/.github/workflows/cppcheck-parse.py b/.github/workflows/cppcheck-parse.py
@@ -28,7 +28,7 @@ def __init__( self, message, line=None ):
         global line_number, logfile
         if line is None:
             line = line_number
-        super().__init__( f'{logile}+{line}: {message}' )
+        super().__init__( f'{logfile}+{line}: {message}' )
 
 
 handle = open( logfile, "r" )

diff --git a/.github/workflows/cppcheck_run.log b/.github/workflows/cppcheck_run.log
diff --git a/CMake/external_fastdds.cmake b/CMake/external_fastdds.cmake
@@ -0,0 +1,65 @@
+cmake_minimum_required(VERSION 3.5) 
+include(FetchContent)
+
+# We use a function to enforce a scoped variables creation only for FastDDS build (i.e turn off BUILD_SHARED_LIBS which is used on LRS build as well)
+function(get_fastdds)
+
+    # Mark new options from FetchContent as advanced options
+    mark_as_advanced(FETCHCONTENT_QUIET)
+    mark_as_advanced(FETCHCONTENT_BASE_DIR)
+    mark_as_advanced(FETCHCONTENT_FULLY_DISCONNECTED)
+    mark_as_advanced(FETCHCONTENT_UPDATES_DISCONNECTED)
+
+    message(CHECK_START  "Fetching fastdds...")
+    list(APPEND CMAKE_MESSAGE_INDENT "  ")  # Indent outputs
+
+    FetchContent_Declare(
+      fastdds
+      GIT_REPOSITORY https://github.com/eProsima/Fast-DDS.git
+      GIT_TAG        v2.9.1
+      GIT_SUBMODULES ""     # Submodules will be cloned as part of the FastDDS cmake configure stage
+      GIT_SHALLOW ON        # No history needed
+      SOURCE_DIR ${CMAKE_BINARY_DIR}/third-party/fastdds
+    )
+
+    # Set FastDDS internal variables
+    # We use cached variables so the default parameter inside the sub directory will not override the required values
+    # We add "FORCE" so that is a previous cached value is set our assignment will override it.
+    set(THIRDPARTY_Asio FORCE CACHE INTERNAL "" FORCE)
+    set(THIRDPARTY_fastcdr FORCE CACHE INTERNAL "" FORCE)
+    set(THIRDPARTY_TinyXML2 FORCE CACHE INTERNAL "" FORCE)
+    set(COMPILE_TOOLS OFF CACHE INTERNAL "" FORCE)
+    set(BUILD_TESTING OFF CACHE INTERNAL "" FORCE)
+    set(SQLITE3_SUPPORT OFF CACHE INTERNAL "" FORCE)
+
+    # Set special values for FastDDS sub directory
+    set(BUILD_SHARED_LIBS OFF)
+    set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR}/fastdds/fastdds_install) 
+    set(CMAKE_PREFIX_PATH ${CMAKE_BINARY_DIR}/fastdds/fastdds_install)  
+
+    # Get fastdds
+    FetchContent_MakeAvailable(fastdds)
+
+    # Mark new options from FetchContent as advanced options
+    mark_as_advanced(FETCHCONTENT_SOURCE_DIR_FASTDDS)
+    mark_as_advanced(FETCHCONTENT_UPDATES_DISCONNECTED_FASTDDS)
+
+    # place FastDDS project with other 3rd-party projects
+    set_target_properties(fastcdr fastrtps PROPERTIES
+                          FOLDER "ExternalProjectTargets/fastdds")
+
+    list(POP_BACK CMAKE_MESSAGE_INDENT) # Unindent outputs
+
+    add_library(dds INTERFACE)
+    target_link_libraries(dds INTERFACE  fastcdr fastrtps)
+
+    add_definitions(-DBUILD_WITH_DDS)
+
+    install(TARGETS dds EXPORT realsense2Targets)
+    message(CHECK_PASS "Done")
+endfunction()
+
+# Trigger the FastDDS build
+get_fastdds()
+
+
diff --git a/CMake/external_foonathan_memory.cmake b/CMake/external_foonathan_memory.cmake
@@ -0,0 +1,83 @@
+cmake_minimum_required(VERSION 3.11) 
+include(FetchContent)
+
+# Mark new options from FetchContent as advanced options
+mark_as_advanced(FETCHCONTENT_QUIET)
+mark_as_advanced(FETCHCONTENT_BASE_DIR)
+mark_as_advanced(FETCHCONTENT_FULLY_DISCONNECTED)
+mark_as_advanced(FETCHCONTENT_UPDATES_DISCONNECTED)
+
+message(CHECK_START  "Fetching & Installing foonathan_memory...")
+list(APPEND CMAKE_MESSAGE_INDENT "  ")
+
+FetchContent_Declare(
+  foonathan_memory
+  GIT_REPOSITORY https://github.com/foonathan/memory.git
+  GIT_TAG        "v0.7-2"
+  GIT_SHALLOW ON    # No history needed
+  SOURCE_DIR ${CMAKE_CURRENT_BINARY_DIR}/third-party/foonathan_memory
+)
+
+# Remove unrequired targets
+set(FOONATHAN_MEMORY_BUILD_VARS -DBUILD_SHARED_LIBS=OFF             # explicit set static lib
+                                -DFOONATHAN_MEMORY_BUILD_EXAMPLES=OFF 
+                                -DFOONATHAN_MEMORY_BUILD_TESTS=OFF
+                                -DFOONATHAN_MEMORY_BUILD_TOOLS=ON)  # this tool is needed during configure time only, FastDDS recommend turning it ON.
+
+# Align STATIC CRT definitions with LRS   
+if(BUILD_WITH_STATIC_CRT)
+    set(FOONATHAN_MEMORY_BUILD_VARS ${FOONATHAN_MEMORY_BUILD_VARS}
+                                    -DCMAKE_POLICY_DEFAULT_CMP0091:STRING=NEW 
+                                    -DCMAKE_MSVC_RUNTIME_LIBRARY:STRING=MultiThreaded$<$<CONFIG:Debug>:Debug>)
+endif()  
+
+
+# Since `FastDDS` require foonathan_memory package installed during configure time,
+# We download it build it and install it both in Release & Debug configuration since we need both available.
+# We use `FetchContent_Populate` and not `FetchContent_MakeAvailable` for that reason, we want to manually configure and build it.
+FetchContent_GetProperties(foonathan_memory)
+if(NOT foonathan_memory_POPULATED)
+  FetchContent_Populate(foonathan_memory)
+endif()
+
+# Mark new options from FetchContent as advanced options
+mark_as_advanced(FETCHCONTENT_SOURCE_DIR_FOONATHAN_MEMORY)
+mark_as_advanced(FETCHCONTENT_UPDATES_DISCONNECTED_FOONATHAN_MEMORY)
+
+
+# Configure stage
+execute_process(COMMAND "${CMAKE_COMMAND}" -G "${CMAKE_GENERATOR}" -DCMAKE_INSTALL_PREFIX=${CMAKE_CURRENT_BINARY_DIR}/fastdds/fastdds_install
+                                                                   ${FOONATHAN_MEMORY_BUILD_VARS}
+                                                                   . 
+                                                                    WORKING_DIRECTORY "${CMAKE_BINARY_DIR}/third-party/foonathan_memory" 
+                                                                    OUTPUT_QUIET
+                                                                    RESULT_VARIABLE configure_ret
+)
+
+# Build and install Debug version
+execute_process(COMMAND "${CMAKE_COMMAND}" --build . --config Debug --target install
+    WORKING_DIRECTORY "${CMAKE_BINARY_DIR}/third-party/foonathan_memory" 
+    OUTPUT_QUIET
+    RESULT_VARIABLE debug_build_ret
+)
+
+# Build and install RelWithDeb version
+execute_process(COMMAND "${CMAKE_COMMAND}" --build . --config RelWithDebInfo --target install
+    WORKING_DIRECTORY "${CMAKE_BINARY_DIR}/third-party/foonathan_memory" 
+    OUTPUT_QUIET
+    RESULT_VARIABLE rel_with_deb_info_build_ret
+)
+
+# Build and install Release version
+execute_process(COMMAND "${CMAKE_COMMAND}" --build . --config Release --target install
+    WORKING_DIRECTORY "${CMAKE_BINARY_DIR}/third-party/foonathan_memory" 
+    OUTPUT_QUIET
+    RESULT_VARIABLE release_build_ret
+)
+
+ if(configure_ret OR debug_build_ret OR release_build_ret OR rel_with_deb_info_build_ret)
+        message( FATAL_ERROR "Failed to build foonathan_memory")
+ endif()
+
+list(POP_BACK CMAKE_MESSAGE_INDENT)
+message(CHECK_PASS "Done")
diff --git a/CMake/external_json.cmake b/CMake/external_json.cmake
@@ -0,0 +1,41 @@
+cmake_minimum_required(VERSION 3.6)
+include(ExternalProject)
+
+
+
+# We use a function to enforce a scoped variables creation only for the build
+# (i.e turn off BUILD_SHARED_LIBS which is used on LRS build as well)
+function(get_nlohmann_json)
+
+    message( STATUS #CHECK_START
+        "Fetching nlohmann/json..." )
+    #list( APPEND CMAKE_MESSAGE_INDENT "  " )  # Indent outputs
+
+    # We want to clone the pybind repo and build it here, during configuration, so we can use it.
+    # But ExternalProject_add is limited in that it only does its magic during build.
+    # This is possible in CMake 3.12+ with FetchContent and FetchContent_MakeAvailable in 3.14+ (meaning Ubuntu 20)
+    # but we need to adhere to CMake 3.10 (Ubuntu 18).
+    # So instead, we invoke a new CMake project just to download pybind:
+    configure_file( CMake/json-download.cmake.in
+                    ${CMAKE_BINARY_DIR}/external-projects/json-download/CMakeLists.txt )
+    execute_process( COMMAND "${CMAKE_COMMAND}" -G "${CMAKE_GENERATOR}" .
+                     WORKING_DIRECTORY "${CMAKE_BINARY_DIR}/external-projects/json-download"
+                     OUTPUT_QUIET
+                     RESULT_VARIABLE configure_ret )
+    execute_process( COMMAND "${CMAKE_COMMAND}" --build .
+                     WORKING_DIRECTORY "${CMAKE_BINARY_DIR}/external-projects/json-download"
+                     OUTPUT_QUIET
+                     RESULT_VARIABLE build_ret )
+
+    if( configure_ret OR build_ret )
+        message( FATAL_ERROR "Failed to download nlohmann/json" )
+    endif()
+
+    message( STATUS #CHECK_PASS
+        "Fetching nlohmann/json - Done" )
+    #list( POP_BACK CMAKE_MESSAGE_INDENT ) # Unindent outputs (requires cmake 3.15)
+
+endfunction()
+
+# Trigger the build
+get_nlohmann_json()
diff --git a/CMake/external_pybind11.cmake b/CMake/external_pybind11.cmake
@@ -20,10 +20,16 @@ function(get_pybind11)
                     ${CMAKE_BINARY_DIR}/external-projects/pybind11-download/CMakeLists.txt )
     execute_process( COMMAND "${CMAKE_COMMAND}" -G "${CMAKE_GENERATOR}" .
                      WORKING_DIRECTORY "${CMAKE_BINARY_DIR}/external-projects/pybind11-download"
-                     OUTPUT_QUIET )
+                     OUTPUT_QUIET
+                     RESULT_VARIABLE configure_ret )
     execute_process( COMMAND "${CMAKE_COMMAND}" --build .
                      WORKING_DIRECTORY "${CMAKE_BINARY_DIR}/external-projects/pybind11-download"
-                     OUTPUT_QUIET )
+                     OUTPUT_QUIET
+                     RESULT_VARIABLE build_ret )
+
+    if( configure_ret OR build_ret )
+        message( FATAL_ERROR "Failed to download pybind11" )
+    endif()
 
     # Now that it's available, we can refer to it with an actual ExternalProject_add (but notice we're not
     # downloading anything)
@@ -75,8 +81,45 @@ function(get_pybind11)
 
 endfunction()
 
+
+# We also want a json-compatible pybind interface:
+function(get_pybind11_json)
+
+    message( STATUS #CHECK_START
+        "Fetching pybind11_json..." )
+    #list( APPEND CMAKE_MESSAGE_INDENT "  " )  # Indent outputs
+
+    # We want to clone the pybind repo and build it here, during configuration, so we can use it.
+    # But ExternalProject_add is limited in that it only does its magic during build.
+    # This is possible in CMake 3.12+ with FetchContent and FetchContent_MakeAvailable in 3.14+ (meaning Ubuntu 20)
+    # but we need to adhere to CMake 3.10 (Ubuntu 18).
+    # So instead, we invoke a new CMake project just to download pybind:
+    configure_file( CMake/pybind11-json-download.cmake.in
+                    ${CMAKE_BINARY_DIR}/external-projects/pybind11-json-download/CMakeLists.txt )
+    execute_process( COMMAND "${CMAKE_COMMAND}" -G "${CMAKE_GENERATOR}" .
+                     WORKING_DIRECTORY "${CMAKE_BINARY_DIR}/external-projects/pybind11-json-download"
+                     OUTPUT_QUIET
+                     RESULT_VARIABLE configure_ret )
+    execute_process( COMMAND "${CMAKE_COMMAND}" --build .
+                     WORKING_DIRECTORY "${CMAKE_BINARY_DIR}/external-projects/pybind11-json-download"
+                     OUTPUT_QUIET
+                     RESULT_VARIABLE build_ret )
+
+    if( configure_ret OR build_ret )
+        message( FATAL_ERROR "Failed to download pybind11_json" )
+    endif()
+
+    # pybind11_add_module will add the directory automatically (see below)
+
+    message( STATUS #CHECK_PASS
+        "Fetching pybind11_json - Done" )
+    #list( POP_BACK CMAKE_MESSAGE_INDENT ) # Unindent outputs (requires cmake 3.15)
+
+endfunction()
+
 # Trigger the build
 get_pybind11()
+get_pybind11_json()
 
 # This function overrides "pybind11_add_module" function,  arguments is same as "pybind11_add_module" arguments
 # pybind11_add_module(<name> SHARED [file, file2, ...] )
@@ -93,5 +136,7 @@ function( pybind11_add_module project_name library_type ...)
     # (workaround for RS5-10582; see also https://github.com/pybind/pybind11/issues/2898)
     # NOTE: this workaround seems to be needed for debug compilations only
     target_compile_definitions( ${project_name} PRIVATE -DPYBIND11_COMPILER_TYPE=\"_${project_name}_abi\" )
-
+
+    target_include_directories( ${project_name} PRIVATE "${CMAKE_BINARY_DIR}/third-party/pybind11-json/include" )
+
 endfunction()
diff --git a/CMake/global_config.cmake b/CMake/global_config.cmake
@@ -80,7 +80,7 @@ macro(global_set_flags)
             add_definitions(-DCHECK_FOR_UPDATES)
         endif()
     endif()
-
+        
     add_definitions(-D${BACKEND} -DUNICODE)
 endmacro()
 
@@ -103,6 +103,5 @@ macro(global_target_config)
     )
 
 
-
 endmacro()
 
diff --git a/CMake/json-download.cmake.in b/CMake/json-download.cmake.in
@@ -0,0 +1,19 @@
+cmake_minimum_required(VERSION 3.6)
+project(nlohmann-json-download NONE)
+
+include(ExternalProject)
+ExternalProject_Add(
+    nlohmann_json
+    PREFIX .
+    GIT_REPOSITORY "https://github.com/nlohmann/json.git"
+    #GIT_TAG        v3.11.2
+    GIT_CONFIG     advice.detachedHead=false  # otherwise we'll get "You are in 'detached HEAD' state..."
+    SOURCE_DIR     "${CMAKE_BINARY_DIR}/third-party/json"
+    GIT_SHALLOW    1        # No history needed (requires cmake 3.6)
+    # Override default steps with no action, we just want the clone step.
+    CONFIGURE_COMMAND ""
+    BUILD_COMMAND ""
+    INSTALL_COMMAND ""
+    )
+
+
diff --git a/CMake/lrs_options.cmake b/CMake/lrs_options.cmake
@@ -45,4 +45,5 @@ else()
     option(ENABLE_EASYLOGGINGPP_ASYNC "Switch Logger to Asynchronous Mode (set OFF for Synchronous Mode)" OFF)
 endif()
 option(BUILD_PC_STITCHING "Build pointcloud-stitching example" OFF)
+option(BUILD_WITH_DDS "Use FastDDS to access camera devices through DDS topics" OFF)
 
diff --git a/CMake/pybind11-json-download.cmake.in b/CMake/pybind11-json-download.cmake.in
@@ -0,0 +1,19 @@
+cmake_minimum_required(VERSION 3.6)
+project(pybind11-json-download NONE)
+
+include(ExternalProject)
+ExternalProject_Add(
+    pybind11_json
+    PREFIX .
+    GIT_REPOSITORY "https://github.com/pybind/pybind11_json.git"
+    GIT_TAG        0.2.13
+    GIT_CONFIG     advice.detachedHead=false  # otherwise we'll get "You are in 'detached HEAD' state..."
+    SOURCE_DIR     "${CMAKE_BINARY_DIR}/third-party/pybind11-json"
+    GIT_SHALLOW    ON        # No history needed (requires cmake 3.6)
+    # Override default steps with no action, we just want the clone step.
+    CONFIGURE_COMMAND ""
+    BUILD_COMMAND ""
+    INSTALL_COMMAND ""
+    )
+
+