-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathExtIniFile.pas
1401 lines (1317 loc) · 46.6 KB
/
ExtIniFile.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
unit ExtIniFile;
// ExtIniFile Version 1.5.1 copyright(c) みず, 2002-2008
interface
uses
SysUtils, Classes, IniFiles, Forms, ShlObj, ActiveX, Windows, Graphics,
Controls, System.UITypes;
type
TDefaultFolder = (dfAppData, dfApplication, dfUser, dfWindows);
TExtIniFile = class(TComponent)
private
{ Private 宣言 }
// ******************************************************* フィールド **
FAppName: string;
FAutoUpdate: Boolean;
FCaseSensitive: Boolean;
FDefaultFolder: TDefaultFolder;
FFileName: TFileName;
FFolderPath: string;
FIniFileName: TFileName;
FModified: Boolean;
FOnLoad: TNotifyEvent;
FOnUpdate: TNotifyEvent;
FSections: THashedStringList;
FUpdateAtOnce: Boolean;
// ************************************************ メソッド(private) **
function FindItem(SectionName, ItemName: string; out Value: string): Integer;
function FindSectionIndex(SectionName: string): Integer;
function GetPathString(const Folder: TDefaultFolder): string;
procedure SaveIniFile(const ARename: Boolean);
procedure WriteValue(const Section, Item, Value: string);
// =============================================== プロパティアクセス ==
function GetAbsoluteFileName: TFileName;
function GetFullIniFileName: string;
function GetItems(Section: string): TStrings;
function GetSectionCount: Integer;
function GetSections(Index: Integer): string;
procedure SetCaseSensitive(const Value: Boolean);
procedure SetDefaultFolder(const Value: TDefaultFolder);
procedure SetFileName(const Value: TFileName);
procedure SetUpdateAtOnce(const Value: Boolean);
protected
// -------------Protected--
// ............method..
// ..........property..
property FullIniFileName: string read GetFullIniFileName;
// .............event..
public
{ Public 宣言 }
// ************************************************* メソッド(public) **
constructor Create(AOwner: TComponent); override;
destructor Destroy; override;
procedure Clear;
procedure Copy(const Dest: string);
procedure DeleteItem(const Section, Item: string);
procedure Erase;
procedure EraseSection(const Section: string);
function ItemExists(const Section, Item: string): Boolean;
function ReadBool(const Section, Item: string;
const Default: Boolean): Boolean;
procedure ReadBounds(const Section, Item: string; AControl: TControl);
function ReadCardinal(const Section, Item: string;
const Default: Cardinal): Cardinal;
function ReadColor(const Section, Item: string;
const Default: TColor): TColor;
function ReadCurr(const Section, Item: string;
const Default: Currency): Currency;
function ReadDate(const Section, Item: string; const Default: TDate): TDate;
function ReadDateTime(const Section, Item: string;
const Default: TDateTime): TDateTime;
function ReadDirectory(const Section, Item, Default: string): string;
function ReadFloat(const Section, Item: string;
const Default: Extended): Extended;
procedure ReadFont(const Section, Item: string; Font: TFont);
procedure ReadForm(const Section, Item: string; Form: TCustomForm);
procedure ReadForm2(const Section: string; Form: TCustomForm);
procedure ReadFormEx(const Section, Item: string; Form: TCustomForm);
procedure ReadFormEx2(const Section: string; Form: TCustomForm);
function ReadInt(const Section, Item: string;
const Default: Integer): Integer;
function ReadInt64(const Section, Item: string; const Default: Int64): Int64;
procedure ReadList(const Section, Item: string; List: TStrings);
procedure ReadPos(const Section, Item: string; AControl: TControl);
procedure ReadSection(const Section: string; List: TStrings);
procedure ReadSectionName(List: TStrings);
procedure ReadSize(const Section, Item: string; AControl: TControl);
function ReadStr(const Section, Item, Default: string): string;
function ReadStrEx(const Section, Item, Default, Password: string): string;
function ReadTime(const Section, Item: string; const Default: TTime): TTime;
procedure ReadWinPos(const Section, Item: string; Form: TForm);
procedure ReadWinSize(const Section, Item: string; Form: TForm);
procedure ReadWinSizeEx(const Section, Item: string; Form: TForm);
procedure Reload;
function Rename(const NewFolder: TDefaultFolder;
const NewName: string): Boolean;
function RenameSection(const Section, NewSection: string): Boolean;
function SectionExists(const Section: string): Boolean;
procedure Update;
procedure WriteBool(const Section, Item: string; const Value: Boolean);
procedure WriteBounds(const Section, Item: string; AControl: TControl);
procedure WriteCardinal(const Section, Item: string; const Value: Cardinal);
procedure WriteColor(const Section, Item: string; const Value: TColor);
procedure WriteCurr(const Section, Item: string; const Value: Currency);
procedure WriteDate(const Section, Item: string; const Value: TDate);
procedure WriteDateTime(const Section, Item: string; const Value: TDateTime);
procedure WriteDirectory(const Section, Item, Path: string);
procedure WriteFloat(const Section, Item: string; const Value: Extended);
procedure WriteFont(const Section, Item: string; Font: TFont);
procedure WriteForm(const Section, Item: string; Form: TCustomForm);
procedure WriteForm2(const Section: string; Form: TCustomForm);
procedure WriteInt(const Section, Item: string; const Value: Integer);
procedure WriteInt64(const Section, Item: string; const Value: Int64);
procedure WriteList(const Section, Item: string; List: TStrings);
procedure WriteStr(const Section, Item, Value: string);
procedure WriteStrEx(const Section, Item, Value, Password: string);
procedure WriteTime(const Section, Item: string; const Value: TTime);
// *********************************************** プロパティ(public) **
property AbsoluteFileName: TFileName read GetAbsoluteFileName;
property Items[Section: string]: TStrings read GetItems;
property Modified: Boolean read FModified write FModified;
property SectionCount: Integer read GetSectionCount;
property Sections[Index: Integer]: string read GetSections;
published
{ Published 宣言 }
// ******************************************** プロパティ(published) **
property AutoUpdate: Boolean read FAutoUpdate write FAutoUpdate default True;
property CaseSensitive: Boolean read FCaseSensitive
write SetCaseSensitive default False;
property DefaultFolder: TDefaultFolder read FDefaultFolder
write SetDefaultFolder default dfApplication;
property FileName: TFileName read FFileName write SetFileName;
property UpdateAtOnce: Boolean read FUpdateAtOnce write SetUpdateAtOnce
default False;
// ********************************************************* イベント **
property OnLoad: TNotifyEvent read FOnLoad write FOnLoad;
property OnUpdate: TNotifyEvent read FOnUpdate write FOnUpdate;
end;
procedure Register;
implementation
procedure Register;
begin
RegisterComponents('Samples', [TExtIniFile]);
end;
const
LeftSecMark = '[';
RightSecMark = ']';
Key1 = './#%$';
Key2 = 'ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789';
{ TExtIniFile }
// ######################################## バッファをクリア<Clearメソッド> ####
procedure TExtIniFile.Clear;
var
Lp: Integer;
Sec: TStringList;
begin
for Lp := 0 to FSections.Count - 1 do
begin
Sec := TStringList(FSections.Objects[Lp]);
if Assigned(Sec) then Sec.Free;
end;
FSections.Clear;
FModified := True;
end;
// ######################################### ファイルのコピー<Copyメソッド> ####
procedure TExtIniFile.Copy(const Dest: string);
var
Fs, Fd: TFileStream;
begin
if FileExists(FullIniFileName) then
begin
Fs := TFileStream.Create(FullIniFileName, fmOpenRead or fmShareDenyNone);
try
Fd := TFileStream.Create(Dest, fmCreate or fmShareDenyWrite);
try
Fd.CopyFrom(Fs, 0);
finally
Fd.Free;
end;
finally
Fs.Free;
end;
end;
end;
// ######################################### コンストラクタ<Createメソッド> ####
constructor TExtIniFile.Create(AOwner: TComponent);
begin
inherited;
// *************************************************** オブジェクト生成 **
FSections := THashedStringList.Create;
// *********************************************************** 初期設定 **
FAppName := ChangeFileExt(ExtractFileName(Application.ExeName), '');
FDefaultFolder := dfApplication;
FFileName := '';
FFolderPath := GetPathString(dfApplication);
FIniFileName := FAppName + '.ini';
FAutoUpdate := True;
// *********************************************************** 読み取り **
if not (csDesigning in ComponentState) then Reload;
end;
// ##################################### アイテムの削除<DeleteItemメソッド> ####
procedure TExtIniFile.DeleteItem(const Section, Item: string);
var
Count: Integer;
Sec: TStringList;
SecIndex, ItemIndex: Integer;
S: string;
// +++++++++++++++++++++++++++++++++++++++++++++++++++++++ アイテムの削除 ++++
procedure DelName(const ItemName: string);
var
DelIndex: Integer;
begin
DelIndex := Sec.IndexOfName(ItemName);
if DelIndex >= 0 then Sec.Delete(DelIndex);
end;
// +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
begin
ItemIndex := FindItem(Section, Item, S);
if ItemIndex >= 0 then
begin
SecIndex := FindSectionIndex(Section);
Sec := TStringList(FSections.Objects[SecIndex]);
if Assigned(Sec) then
begin
Sec.Delete(ItemIndex);
Sec.CaseSensitive := FCaseSensitive;
if AnsiSameText(S, 'FONT') then
begin
DelName(Item + '.charset');
DelName(Item + '.color');
DelName(Item + '.height');
DelName(Item + '.name');
DelName(Item + '.pitch');
DelName(Item + '.b');
DelName(Item + '.i');
DelName(Item + '.u');
DelName(Item + '.s');
end;
if AnsiSameText(S, 'FORM') then
begin
DelName(Item + '.flags');
DelName(Item + '.show');
DelName(Item + '.state');
DelName(Item + '.mx');
DelName(Item + '.my');
DelName(Item + '.left');
DelName(Item + '.top');
DelName(Item + '.right');
DelName(Item + '.bottom');
DelName(Item + '.cwidth');
DelName(Item + '.cheight');
end;
if AnsiSameText(S, 'BOUNDS') then
begin
DelName(Item + '.left');
DelName(Item + '.top');
DelName(Item + '.width');
DelName(Item + '.height');
end;
if AnsiSameText(S, 'LIST') then
begin
S := Sec.Values[Item + '.count'];
Count := StrToIntDef(S, 0);
DelName(Item + '.count');
for ItemIndex := 0 to Count - 1 do
DelName(Item + '.' + IntToStr(ItemIndex));
end;
FModified := True;
if FUpdateAtOnce then Update;
end;
end;
end;
// ########################################## デストラクタ<Destroyメソッド> ####
destructor TExtIniFile.Destroy;
begin
if not (csDesigning in ComponentState) and FAutoUpdate and
not FUpdateAtOnce then Update;
// *************************************************** オブジェクト破棄 **
Clear;
FSections.Free;
inherited;
end;
// ###################################### ファイル内容の消去<Eraseメソッド> ####
procedure TExtIniFile.Erase;
begin
Clear;
if FUpdateAtOnce then Update;
end;
// ################################# セクションの消去<EraseSectionメソッド> ####
procedure TExtIniFile.EraseSection(const Section: string);
var
Sec: TStringList;
SecIndex: Integer;
begin
SecIndex := FindSectionIndex(Section);
if SecIndex >= 0 then
begin
Sec := TStringList(FSections.Objects[SecIndex]);
if Assigned(Sec) then Sec.Free;
FSections.Delete(SecIndex);
FModified := True;
if FUpdateAtOnce then Update;
end;
end;
// ####################################### アイテムの取得<FindItemメソッド> ####
function TExtIniFile.FindItem(SectionName, ItemName: string;
out Value: string): Integer;
var
Sec: TStringList; // セクション内のアイテムリスト
SecIndex: Integer; // セクションのインデックス
begin
Result := -1;
Value := '';
SecIndex := FindSectionIndex(SectionName);
if SecIndex >= 0 then
begin
Sec := TStringList(FSections.Objects[SecIndex]);
if Assigned(Sec) then
begin
Sec.CaseSensitive := FCaseSensitive;
Value := Sec.Values[ItemName];
Result := Sec.IndexOfName(ItemName);
end;
end;
end;
// ############# セクションのインデックスを求める<FindSectionIndexメソッド> ####
function TExtIniFile.FindSectionIndex(SectionName: string): Integer;
begin
if Length(SectionName) >= 1 then
begin
if SectionName[1] <> LeftSecMark then
SectionName := LeftSecMark + SectionName;
if SectionName[Length(SectionName)] <> RightSecMark then
SectionName := SectionName + RightSecMark;
end;
Result := FSections.IndexOf(SectionName);
end;
// #### AbsoluteFileNameプロパティ取得<GetAbsoluteFileNameアクセスメソッド> ####
function TExtIniFile.GetAbsoluteFileName: TFileName;
begin
Result := FullIniFileName;
end;
// =========================================================================
// get: FullIniFileName
function TExtIniFile.GetFullIniFileName: string;
begin
Result := FFolderPath + FIniFileName;
end;
// #############################################################################
// ##### Itemsプロパティ取得 : GetItemsアクセスメソッド
function TExtIniFile.GetItems(Section: string): TStrings;
var
SecIndex: Integer;
begin
SecIndex := FindSectionIndex(Section);
if SecIndex >= 0 then
Result := TStringList(FSections.Objects[SecIndex])
else
Result := nil;
end;
// ############################ 指定フォルダのパスを取得(GetPathString関数) ####
function TExtIniFile.GetPathString(const Folder: TDefaultFolder): string;
var
IMem: IMalloc;
PathStr: array[0..1023] of Char;
PBuf: PChar;
PItem: PItemIDList;
begin
case Folder of
dfAppData:
begin
SHGetMalloc(IMem);
PBuf := IMem.Alloc(MAX_PATH);
SHGetSpecialFolderLocation(Application.Handle, CSIDL_APPDATA, PItem);
SHGetPathFromIDList(PItem, PBuf);
Result := PBuf;
IMem.Free(PBuf);
IMem.Free(PItem);
Result := IncludeTrailingPathDelimiter(Result) + FAppName;
end;
dfApplication: Result := ExtractFilePath(Application.ExeName);
dfUser : Result := '';
else
begin
GetWindowsDirectory(PathStr, SizeOf(PathStr));
Result := PathStr;
end;
end;
if Result <> '' then
begin
Result := IncludeTrailingPathDelimiter(Result);
if not DirectoryExists(Result) then ForceDirectories(Result);
end;
end;
// ############ SectionCountプロパティ取得<GetSectionCountアクセスメソッド> ####
function TExtIniFile.GetSectionCount: Integer;
begin
Result := FSections.Count;
end;
// #################### Sectionsプロパティ取得<GetSectionsアクセスメソッド> ####
function TExtIniFile.GetSections(Index: Integer): string;
begin
if (Index >= 0) and (Index < FSections.Count) then
begin
Result := FSections.Strings[Index];
Result := System.Copy(Result, 2, Length(Result) - 2);
end
else
Result := '';
end;
// ################################# アイテムの存在確認<ItemExistsメソッド> ####
function TExtIniFile.ItemExists(const Section, Item: string): Boolean;
var
ItemValue: string;
begin
Result := (FindItem(Section, Item, ItemValue) >= 0);
end;
// ################################## Boolean型の読み取り<ReadBoolメソッド> ####
function TExtIniFile.ReadBool(const Section, Item: string;
const Default: Boolean): Boolean;
var
S: string;
begin
if FindItem(Section, Item, S) = -1 then
Result := Default
else
Result := (S = '1') or SameText(S, 'true');
end;
// ################### コントロールの位置とサイズを取得<ReadBoundsメソッド> ####
procedure TExtIniFile.ReadBounds(const Section, Item: string;
AControl: TControl);
var
ALeft, ATop, AWidth, AHeight: Integer;
begin
ALeft := ReadInt(Section, Item + '.left', AControl.Left);
ATop := ReadInt(Section, Item + '.top', AControl.Top);
AWidth := ReadInt(Section, Item + '.width', AControl.Width);
AHeight := ReadInt(Section, Item + '.height', AControl.Height);
AControl.SetBounds(ALeft, ATop, AWidth, AHeight);
end;
// ############################# Cardinal型の読み取り<ReadCardinalメソッド> ####
function TExtIniFile.ReadCardinal(const Section, Item: string;
const Default: Cardinal): Cardinal;
var
S: string;
begin
if FindItem(Section, Item, S) = -1 then
Result := Default
else
Result := Cardinal(StrToInt64Def(S, Default));
end;
// #################################### カラーの読み取り<ReadColorメソッド> ####
function TExtIniFile.ReadColor(const Section, Item: string;
const Default: TColor): TColor;
var
ColInt: LongInt;
begin
ColInt := Default;
ColInt := ReadInt(Section, Item, ColInt);
Result := ColInt;
end;
// ################################# Currency型の読み取り<ReadCurrメソッド> ####
function TExtIniFile.ReadCurr(const Section, Item: string;
const Default: Currency): Currency;
var
CurrFormat: TFormatSettings;
S: string;
begin
if FindItem(Section, Item, S) = -1 then
Result := Default
else
begin
GetLocaleFormatSettings(GetUserDefaultLCID, CurrFormat);
if not TryStrToCurr(S, Result, CurrFormat) then Result := Default;
end;
end;
// #################################### TDate型の読み取り<ReadDateメソッド> ####
function TExtIniFile.ReadDate(const Section, Item: string;
const Default: TDate): TDate;
var
ADate: TDateTime;
DateValue: Double;
Y, M, D: Word;
begin
DateValue := Default;
DateValue := ReadFloat(Section, Item, DateValue);
if not TryFloatToDateTime(DateValue, ADate) then
Result := Default
else
begin
DecodeDate(ADate, Y, M, D);
Result := EncodeDate(Y, M, D);
end;
end;
// ############################ TDateTime型の読み取り<ReadDateTimeメソッド> ####
function TExtIniFile.ReadDateTime(const Section, Item: string;
const Default: TDateTime): TDateTime;
var
DateValue: Double;
begin
DateValue := Default;
DateValue := ReadFloat(Section, Item, DateValue);
if not TryFloatToDateTime(DateValue, Result) then Result := Default;
end;
// ==========================================================================
// == method: フォルダパスの読み取り ====
// ==========================================================================
function TExtIniFile.ReadDirectory(const Section, Item,
Default: string): string;
begin
if FindItem(Section, Item, Result) = -1 then Result := Default;
if Result <> '' then Result := IncludeTrailingPathDelimiter(Result);
end;
// #################################### 実数型の読み取り<ReadFloatメソッド> ####
function TExtIniFile.ReadFloat(const Section, Item: string;
const Default: Extended): Extended;
var
Ft: TFormatSettings;
S: string;
begin
if FindItem(Section, Item, S) = -1 then
Result := Default
else
begin
GetLocaleFormatSettings(GetUserDefaultLCID, Ft);
if not TryStrToFloat(S, Result, Ft) then Result := Default;
end;
end;
// ################################### フォントの読み取り<ReadFontメソッド> ####
procedure TExtIniFile.ReadFont(const Section, Item: string; Font: TFont);
var
Pitch: Integer;
S: string;
begin
// ************************************************************ CharSet **
if FindItem(Section, Item + '.charset', S) >= 0 then
Font.Charset := Byte(StrToIntDef(S, Font.Charset));
// ******************************************************* Color/Height **
Font.Color := ReadColor(Section, Item + '.color', Font.Color);
Font.Height := ReadInt(Section, Item + '.height', Font.Height);
// *************************************************************** Name **
if FindItem(Section, Item + '.name', S) >= 0 then Font.Name := S;
// ************************************************************** Pitch **
Pitch := ReadInt(Section, Item + '.pitch', Ord(Font.Pitch));
case Pitch of
Ord(fpDefault): Font.Pitch := fpDefault;
Ord(fpFixed) : Font.Pitch := fpFixed;
else
Font.Pitch := fpVariable;
end;
// ************************************************************** Style **
if ReadBool(Section, Item + '.b', fsBold in Font.Style) then
Font.Style := Font.Style + [fsBold]
else
Font.Style := Font.Style - [fsBold];
if ReadBool(Section, Item + '.i', fsItalic in Font.Style) then
Font.Style := Font.Style + [fsItalic]
else
Font.Style := Font.Style - [fsItalic];
if ReadBool(Section, Item + '.u', fsUnderline in Font.Style) then
Font.Style := Font.Style + [fsUnderline]
else
Font.Style := Font.Style - [fsUnderline];
if ReadBool(Section, Item + '.s', fsStrikeOut in Font.Style) then
Font.Style := Font.Style + [fsStrikeOut]
else
Font.Style := Font.Style - [fsStrikeOut];
end;
// ####################### フォーム位置とサイズの読み取り<ReadFormメソッド> ####
procedure TExtIniFile.ReadForm(const Section, Item: string; Form: TCustomForm);
var
State: Integer;
Wp: TWindowPlacement;
begin
// ************************************************************* 初期化 **
Wp.length := SizeOf(TWindowPlacement);
GetWindowPlacement(Form.Handle, @Wp);
// *********************************************************** 読み取り **
with Wp do
begin
flags := ReadCardinal(Section, Item + '.flags', flags);
// ===================================================== 最大化の位置 ==
ptMaxPosition.X := ReadInt(Section, Item + '.mx', ptMaxPosition.X);
ptMaxPosition.Y := ReadInt(Section, Item + '.my', ptMaxPosition.Y);
// =================================================== フォームの座標 ==
with rcNormalPosition do
begin
Left := ReadInt(Section, Item + '.left', Left);
Top := ReadInt(Section, Item + '.top', Top);
Right := ReadInt(Section, Item + '.right', Right);
Bottom := ReadInt(Section, Item + '.bottom', Bottom);
end;
// ========================================================= 表示状態 ==
showCmd := ReadCardinal(Section, Item + '.show', showCmd);
if not Form.Showing then
begin
showCmd := SW_HIDE;
SetWindowPlacement(Form.Handle, @Wp);
State := ReadInt(Section, Item + '.state', Ord(wsNormal));
case State of
Ord(wsNormal) : Form.WindowState := wsNormal;
Ord(wsMaximized): Form.WindowState := wsMaximized;
else
Form.WindowState := wsNormal;
end;
end
else
SetWindowPlacement(Form.Handle, @Wp);
end;
end;
// #############################################################################
// ## Method: フォームの読み取り
procedure TExtIniFile.ReadForm2(const Section: string; Form: TCustomForm);
begin
ReadForm(Section, Form.Name, Form);
end;
// ##################### フォーム位置とサイズの読み取り<ReadFormExメソッド> ####
procedure TExtIniFile.ReadFormEx(const Section, Item: string; Form: TCustomForm);
begin
ReadForm(Section, Item, Form);
Form.ClientWidth := ReadInt(Section, Item + '.cwidth', Form.ClientWidth);
Form.ClientHeight := ReadInt(Section, Item + '.cheight', Form.ClientHeight);
end;
// #############################################################################
// ## Method: フォームの読み取り
procedure TExtIniFile.ReadFormEx2(const Section: string; Form: TCustomForm);
begin
ReadFormEx(Section, Form.Name, Form);
end;
// ################################### Integer型の読み取り<ReadIntメソッド> ####
function TExtIniFile.ReadInt(const Section, Item: string;
const Default: Integer): Integer;
var
S: string;
begin
if FindItem(Section, Item, S) = -1 then
Result := Default
else
begin
if Length(S) >= 2 then
if (S[1] = '0') and SameText(S[2], 'x') then
S := '$' + System.Copy(S, 3, Length(S) - 2);
Result := StrToIntDef(S, Default);
end;
end;
// ################################### Int64型の読み取り<ReadInt64メソッド> ####
function TExtIniFile.ReadInt64(const Section, Item: string;
const Default: Int64): Int64;
var
S: string;
begin
if FindItem(Section, Item, S) = -1 then
Result := Default
else
Result := StrToInt64Def(S, Default);
end;
// ############################### 文字列リストの読み取り<ReadListメソッド> ####
procedure TExtIniFile.ReadList(const Section, Item: string;
List: TStrings);
var
Count: Integer;
Lp: Integer;
S: string;
begin
List.Clear;
Count := ReadInt(Section, Item + '.count', 0);
for Lp := 0 to Count - 1 do
if FindItem(Section, Item + '.' + IntToStr(Lp), S) >= 0 then
List.Append(S);
end;
// ############################## コントロールの位置を取得<ReadPosメソッド> ####
procedure TExtIniFile.ReadPos(const Section, Item: string;
AControl: TControl);
var
ALeft, ATop: Integer;
begin
ALeft := ReadInt(Section, Item + '.left', AControl.Left);
ATop := ReadInt(Section, Item + '.top', AControl.Top);
AControl.SetBounds(ALeft, ATop, AControl.Width, AControl.Height);
end;
// ################## セクションのアイテムリストを取得<ReadSectionメソッド> ####
procedure TExtIniFile.ReadSection(const Section: string; List: TStrings);
var
Sec: TStringList;
SecIndex: Integer;
begin
SecIndex := FindSectionIndex(Section);
List.Clear;
if SecIndex >= 0 then
begin
Sec := TStringList(FSections.Objects[SecIndex]);
if Assigned(Sec) then List.AddStrings(Sec);
end;
end;
// ###################### セクションのリストを取得<ReadSectionNameメソッド> ####
procedure TExtIniFile.ReadSectionName(List: TStrings);
var
Lp: Integer;
S: string;
begin
List.Clear;
if FSections.Count >= 1 then
for Lp := 0 to FSections.Count - 1 do
begin
S := FSections.Strings[Lp];
if Length(S) >= 2 then
if (S[1] = LeftSecMark) and (S[Length(S)] = RightSecMark) then
S := System.Copy(S, 2, Length(S) - 2);
List.Append(S);
end;
end;
// ########################### コントロールのサイズを取得<ReadSizeメソッド> ####
procedure TExtIniFile.ReadSize(const Section, Item: string;
AControl: TControl);
var
AWidth, AHeight: Integer;
begin
AWidth := ReadInt(Section, Item + '.width', AControl.Width);
AHeight := ReadInt(Section, Item + '.height', AControl.Height);
AControl.SetBounds(AControl.Left, AControl.Top, AWidth, AHeight);
end;
// ###################################### 文字列の読み取り<ReadStrメソッド> ####
function TExtIniFile.ReadStr(const Section, Item, Default: string): string;
begin
if FindItem(Section, Item, Result) = -1 then Result := Default;
end;
// #################################### デコード読み取り<ReadStrExメソッド> ####
function TExtIniFile.ReadStrEx(const Section, Item, Default,
Password: string): string;
var
APos, BPos: Integer;
Len, LenPass: Integer;
Lp, LPass: Integer;
Pass: string;
St, S1, S2: string;
begin
if FindItem(Section, Item, St) = -1 then
Result := Default
else
begin
// ********************************************************* デコード **
Pass := '';
for Lp := 1 to Length(Password) do
begin
APos := Ord(Password[Lp]);
Pass := Pass + IntToHex(APos, 2);
end;
Len := Length(Key2);
LenPass := Length(Pass);
LPass := 1;
Result := '';
for Lp := 1 to Length(St) div 2 do
begin
S1 := St[(Lp - 1) * 2 + 1];
S2 := St[Lp * 2];
APos := Pos(S1, Key1) - 1;
BPos := Pos(S2, Key2) - 1;
if LPass <= LenPass then
begin
BPos := BPos - StrToInt('$' + Pass[LPass]);
if BPos < 0 then Inc(BPos, Len);
end;
APos := Len * APos + BPos;
Result := Result + Chr(Byte(APos));
Inc(LPass);
if LPass > LenPass then LPass := 1;
end;
end;
end;
// #################################### TTime型の読み取り<ReadTimeメソッド> ####
function TExtIniFile.ReadTime(const Section, Item: string;
const Default: TTime): TTime;
var
ATime: TDateTime;
DateValue: Double;
H, M, S, Ms: Word;
begin
DateValue := Default;
DateValue := ReadFloat(Section, Item, DateValue);
if TryFloatToDateTime(DateValue, ATime) then
begin
DecodeTime(ATime, H, M, S, Ms);
Result := EncodeTime(H, M, S, Ms);
end
else
Result := Default;
end;
// ############################# フォーム位置の読み取り<ReadWinPosメソッド> ####
procedure TExtIniFile.ReadWinPos(const Section, Item: string; Form: TForm);
begin
Form.Left := ReadInt(Section, Item + '.left', Form.Left);
Form.Top := ReadInt(Section, Item + '.top', Form.Top);
end;
// ########################## フォームサイズの読み取り<ReadWinSizeメソッド> ####
procedure TExtIniFile.ReadWinSize(const Section, Item: string;
Form: TForm);
var
ARect: TRect;
State: Integer;
Wp: TWindowPlacement;
begin
// *************************************************************** 準備 **
Wp.length := SizeOf(TWindowPlacement);
GetWindowPlacement(Form.Handle, @Wp);
// *********************************************************** 読み取り **
with Wp do
begin
flags := ReadCardinal(Section, Item + '.flags', flags);
ptMaxPosition.X := ReadInt(Section, Item + '.mx', ptMaxPosition.X);
ptMaxPosition.Y := ReadInt(Section, Item + '.mx', ptMaxPosition.Y);
with ARect do
begin
Left := ReadInt(Section, Item + '.left', rcNormalPosition.Left);
Top := ReadInt(Section, Item + '.top', rcNormalPosition.Top);
Right := ReadInt(Section, Item + '.right', rcNormalPosition.Right);
Bottom := ReadInt(Section, Item + '.bottom', rcNormalPosition.Bottom);
end;
with rcNormalPosition do
begin
Right := Left + (ARect.Right - ARect.Left);
Bottom := Top + (ARect.Bottom - ARect.Top);
end;
showCmd := ReadCardinal(Section, Item + '.show', showCmd);
if not Form.Showing then
begin
showCmd := SW_HIDE;
SetWindowPlacement(Form.Handle, @Wp);
State := ReadInt(Section, Item + '.state', Ord(wsNormal));
case State of
Ord(wsNormal) : Form.WindowState := wsNormal;
Ord(wsMaximized): Form.WindowState := wsMaximized;
else
Form.WindowState := wsNormal;
end;
end
else
SetWindowPlacement(Form.Handle, @Wp);
end;
end;
// ############ フォームクライアントサイズの読み取り<ReadWinSizeExメソッド> ####
procedure TExtIniFile.ReadWinSizeEx(const Section, Item: string;
Form: TForm);
begin
ReadWinSize(Section, Item, Form);
Form.ClientWidth := ReadInt(Section, Item + '.cwidth', Form.ClientWidth);
Form.ClientHeight := ReadInt(Section, Item + '.cheight', Form.ClientHeight);
end;
// ############################### ファイルの内容を読み込む<Reloadメソッド> ####
procedure TExtIniFile.Reload;
var
Flag: Boolean;
Fs: TFileStream;
Index: Integer; // 追加位置
Ini, Sec: TStringList;
Lp: Integer;
S: string;
begin
// *************************************************** 現在の内容を破棄 **
Clear;
FModified := False;
// *********************************************************** 読み込み **
if FileExists(FullIniFileName) then
try
Ini := TStringList.Create;
try
Fs := TFileStream.Create(FullIniFileName, fmOpenRead or fmShareDenyNone);
try
Ini.LoadFromStream(Fs);
finally
Fs.Free;
end;
// ************************************************* バッファの構築 **
Sec := nil;
Flag := False;
for Lp := 0 to Ini.Count - 1 do
begin
S := Ini.Strings[Lp];
if Length(S) >= 2 then
begin
if (S[1] = LeftSecMark) and (S[Length(S)] = RightSecMark) then
begin
Index := FSections.Add(S);
FSections.Objects[Index] := TStringList.Create;
Sec := TStringList(FSections.Objects[Index]);
Flag := True;
end
else if Flag and Assigned(Sec) then
Sec.Append(S);
end;
end;
finally
Ini.Free;
end;
if Assigned(FOnLoad) then FOnLoad(Self);
except
//
end;
end;
// ####################################### ファイル名の変更<Renameメソッド> ####
function TExtIniFile.Rename(const NewFolder: TDefaultFolder;
const NewName: string): Boolean;
var
NewFileName: string;
begin
// *********************************************** 新しいフォルダを取得 **
NewFileName := GetPathString(NewFolder);
if NewFolder = dfUser then NewFileName := ExtractFilePath(NewName);
// ******************************************* フォルダの存在確認と作成 **
if not DirectoryExists(NewFileName) then ForceDirectories(NewFileName);
Result := DirectoryExists(NewFileName);
// *********************************************** ファイル名の変更処理 **
if Result then
begin
if NewFolder = dfUser then
NewFileName := NewName
else
NewFileName := NewFileName + NewName;
// ================================================= ファイルのコピー ==
Copy(NewFileName);
// =============================================== 元のファイルを削除 ==
SysUtils.DeleteFile(FullIniFileName);
// ================================================= プロパティの変更 ==
FDefaultFolder := NewFolder;
FFileName := NewName;
FIniFileName := ExtractFileName(NewFileName);
FFolderPath := ExtractFilePath(NewFileName);
end;
end;
// #############################################################################
// ##### RenameSectionメソッド
function TExtIniFile.RenameSection(const Section,
NewSection: string): Boolean;
var
SecIndex: Integer;
begin
if SectionExists(Section) and not SectionExists(NewSection) then
begin
SecIndex := FindSectionIndex(Section);
FSections.Strings[SecIndex] := NewSection;
FModified := True;
Result := True;
end
else
Result := False;
end;