-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathcpm22ccp.s
1274 lines (1257 loc) · 29.8 KB
/
cpm22ccp.s
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
; .title ccpb03.s derived from ccpb03.asm
; .sbttl by Douglas Goodall 5/16/2011 dwg
.module cpm22ccp
.globl CBASE
.area _CPMCCP
USRDSP = 1 ;SHOW THE USER NUMBER
ENDFIL = 1 ;FILE FULL CCP SIZE
; optionally enable at most one of these to search user 0 and drive b0 when searching for executables:
CHKU0 = 1 ;Check for transients on user 0 too (restores user if not found)
CHKU0B = 0 ;Check for transients on user 0 and drive B (leaves user as 0 when not found)
;
;**************************************************************
;*
;* C C P - C O N S O L E C O M M A N D P R O C E S S O R
;*
;**************************************************************
;*
IOBYTE = 3 ; I/O DEFINITION BYTE.
TDRIVE = 4 ; CURRENT DRIVE NAME AND USER NUMBER.
ENTRY = 5 ; ENTRY POINT FOR THE CP/M BDOS.
TFCB = 0x5C ; DEFAULT FILE CONTROL BLOCK.
TBUFF = 0x80 ; I/O BUFFER AND COMMAND LINE STORAGE.
TBASE = 0x0100 ; TRANSIANT PROGRAM STORAGE AREA.
MONADR = 0x0FC00 ;MONITOR PROGRAM
;
; SET CONTROL CHARACTER .EQUATES.
;
CNTRLC = 0x03 ; CONTROL-C
CNTRLE = 0x05 ; CONTROL-E
BS = 0x08 ; BACKSPACE
TAB = 0x09 ; TAB
LF = 0x0A ; LINE FEED
FF = 0x0C ; FORM FEED
CR = 0x0D ; CARRIAGE RETURN
CNTRLP = 0x10 ; CONTROL-P
CNTRLR = 0x12 ; CONTROL-R
CNTRLS = 0x13 ; CONTROL-S
CNTRLU = 0x15 ; CONTROL-U
CNTRLX = 0x18 ; CONTROL-X
CNTRLZ = 0x1A ; CONTROL-Z (END-OF-FILE MARK)
ASTERICK = 0x2A
COLON = 0x3A
LESSTHAN = 0x3C
ASCSPACE = 0x20 ; SPACE
PERIOD = 0x2e ; PERIOD
EQUAL = 0x3D
GREATERTHAN = 0x3E
QUESTION = 0x3F ;QUESTION MARK
UNDERSCORE = 0x5F
LCURLY = 0x7B ; {
DEL = 0x7F ; RUBOUT
;
; SET ORIGIN FOR CP/M
;
NK = 59 ;SYSTEM SIZE
BASE = (NK*1024)-0x5000
CCPO = BASE+0x3400 ;CCP ORIGIN
BDOSO = BASE+0x3C00 ;BDOS ORIGIN
BIOSO = BASE+0x4A00 ;BIOS ORIGIN
CBASE: JP COMMAND ; EXECUTE COMMAND PROCESSOR (CCP).
JP CLEARBUF ; ENTRY TO EMPTY INPUT BUFFER BEFORE STARTING CCP.
;
; STANDARD CP/M CCP INPUT BUFFER. FORMAT IS (MAX LENGTH),
; (ACTUAL LENGTH), (CHAR #1), (CHAR #2), (CHAR #3), ETC.
;
INBUFF: .DB 127 ;length of input buffer.
.DB 0 ;current length of contents.
.ASCII "Copyright"
.ASCII " 1979 (c) by Digital Research "
.DB 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
.DB 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
.DB 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
.DB 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
;; s/b d086 here
INPOINT:.DW INBUFF+2 ; INPUT LINE POINTER
NAMEPNT:.DW 0 ; INPUT LINE POINTER USED FOR ERROR MESSAGE. POINTS TO
; ;START OF NAME IN ERROR.
;
; ROUTINE TO PRINT (A) ON THE CONSOLE. ALL REGISTERS USED.
;
PRINT: LD E,A ; SETUP BDOS CALL.
LD C,#2
JP ENTRY
;
; ROUTINE TO PRINT (A) ON THE CONSOLE AND TO SAVE (BC).
;
PRINTB: PUSH BC
CALL PRINT
POP BC
RET
;
; ROUTINE TO SEND A CARRIAGE RETURN, LINE FEED COMBINATION
; TO THE CONSOLE.
;
CRLF: LD A,#CR
CALL PRINTB
LD A,#LF
JP PRINTB
;
; ROUTINE TO SEND ONE SPACE TO THE CONSOLE AND SAVE (BC).
;
SPACE: LD A,#ASCSPACE
JP PRINTB
;
; ROUTINE TO PRINT CHARACTER STRING POINTED TO BE (BC) ON THE
; CONSOLE. IT MUST TERMINATE WITH A NULL BYTE.
;
PLINE: PUSH BC
CALL #CRLF
POP HL
PLINE2: LD A,(HL)
OR A
RET Z
INC HL
PUSH HL
CALL PRINT
POP HL
JP PLINE2
;
; ROUTINE TO RESET THE DISK SYSTEM.
;
RESDSK: LD C,#13
JP ENTRY
;
; ROUTINE TO SELECT DISK (A).
;
DSKSEL: LD E,A
LD C,#14
JP ENTRY
;
; ROUTINE TO CALL BDOS AND SAVE THE RETURN CODE. THE ZERO
; FLAG IS SET ON A RETURN OF 0FFH.
;
ENTRY1: CALL ENTRY
LD (RTNCODE),A ; SAVE RETURN CODE.
INC A ; SET ZERO IF 0FFH RETURNED.
RET
;
; ROUTINE TO OPEN A FILE. (DE) MUST POINT TO THE FCB.
;
OPEN: LD C,#15
JP ENTRY1
;
; ROUTINE TO OPEN FILE AT (FCB).
;
OPENFCB:XOR A ; CLEAR THE RECORD NUMBER BYTE AT FCB+32
LD (FCB+32),A
LD DE,#FCB
JP OPEN
;
; ROUTINE TO CLOSE A FILE. (DE) POINTS TO FCB.
;
CLOSE: LD C,#16
JP ENTRY1
;
; ROUTINE TO SEARCH FOR THE FIRST FILE WITH AMBIGUEOUS NAME
; (DE).
;
SRCHFST:LD C,#17
JP ENTRY1
;
; SEARCH FOR THE NEXT AMBIGEOUS FILE NAME.
;
SRCHNXT:LD C,#18
JP ENTRY1
;
; SEARCH FOR FILE AT (FCB).
;
SRCHFCB:LD DE,#FCB
JP SRCHFST
;
; ROUTINE TO DELETE A FILE POINTED TO BY (DE).
;
DELETE: LD C,#19
JP ENTRY
;
; ROUTINE TO CALL THE BDOS AND SET THE ZERO FLAG IF A ZERO
; STATUS IS RETURNED.
;
ENTRY2: CALL ENTRY
OR A ; SET ZERO FLAG IF APPROPRIATE.
RET
;
; ROUTINE TO READ THE NEXT RECORD FROM A S.EQUENTIAL FILE.
; (DE) POINTS TO THE FCB.
;
RDREC: LD C,#20
JP ENTRY2
;
; ROUTINE TO READ FILE AT (FCB).
;
READFCB:LD DE,#FCB
JP RDREC
;
; ROUTINE TO WRITE THE NEXT RECORD OF A S.EQUENTIAL FILE.
; (DE) POINTS TO THE FCB.
;
WRTREC: LD C,#21
JP ENTRY2
;
; ROUTINE TO CREATE THE FILE POINTED TO BY (DE).
;
CREATE: LD C,#22
JP ENTRY1
;
; ROUTINE TO RENAME THE FILE POINTED TO BY (DE). NOTE THAT
; THE NEW NAME STARTS AT (DE+16).
;
RENAM: LD C,#23
JP ENTRY
;
; GET THE CURRENT USER CODE.
;
GETUSR: LD E,#0x0FF
;
; ROUTNE TO GET OR SET THE CURRENT USER CODE.
; IF (E) IS FF THEN THIS IS A GET, ELSE IT IS A SET.
;
GETSETUC:
LD C,#32
JP ENTRY
;
; ROUTINE TO SET THE CURRENT DRIVE BYTE AT (TDRIVE).
;
SETCDRV:CALL GETUSR ; GET USER NUMBER
ADD A,A ; AND SHIFT INTO THE UPPER 4 BITS.
ADD A,A
ADD A,A
ADD A,A
LD HL,#CDRIVE ; NOW ADD IN THE CURRENT DRIVE NUMBER.
OR (HL)
LD (TDRIVE),A ; AND SAVE.
RET
;
; MOVE CURRENTLY ACTIVE DRIVE DOWN TO (TDRIVE).
;
MOVECD: LD A,(CDRIVE)
LD (TDRIVE),A
RET
;
; ROUTINE TO CONVERT (A) INTO UPPER CASE ASCII. ONLY LETTERS
; ARE AFFECTED.
;
UPPER: CP #0x41 ; CHECK FOR LETTERS IN THE RANGE OF 'A' TO 'Z'.
RET C
CP #LCURLY
RET NC
AND #0x5F ; CONVERT IT IF FOUND.
RET
;
; ROUTINE TO GET A LINE OF INPUT. WE MUST CHECK TO SEE IF THE
; USER IS IN (BATCH) MODE. IF SO, THEN READ THE INPUT FROM FILE
; ($$$.SUB). AT THE END, RESET TO CONSOLE INPUT.
;
GETINP: LD A,(BATCH) ; IF =0, THEN USE CONSOLE INPUT.
OR A
JP Z,GETINP1
;
; USE THE SUBMIT FILE ($$$.SUB) WHICH IS PREPARED BY A
; SUBMIT RUN. IT MUST BE ON DRIVE (A) AND IT WILL BE DELETED
; IF AND ERROR OCCURES (LIKE EOF).
;
LD A,(CDRIVE) ; SELECT DRIVE 0 IF NEED BE.
OR A
LD A,#0 ; ALWAYS USE DRIVE A FOR SUBMIT.
CALL NZ,DSKSEL ; SELECT IT IF R.EQUIRED.
LD DE,#BATCHFCB
CALL OPEN ; LOOK FOR IT.
JP Z,GETINP1 ; IF NOT THERE, USE NORMAL INPUT.
LD A,(BATCHFCB+15) ; GET LAST RECORD NUMBER+1.
DEC A
LD (BATCHFCB+32),A
LD DE,#BATCHFCB
CALL RDREC ; READ LAST RECORD.
JP NZ,GETINP1 ; QUIT ON END OF FILE.
;
; MOVE THIS RECORD INTO INPUT BUFFER.
;
LD DE,#INBUFF+1
LD HL,#TBUFF ; DATA WAS READ INTO BUFFER HERE.
LD B,#128 ; ALL 128 CHARACTERS MAY BE USED.
CALL HL2DE ; (HL) TO (DE), (B) BYTES.
LD HL,#BATCHFCB+14
LD (HL),#0 ; ZERO OUT THE 'S2' BYTE.
INC HL ; AND DECREMENT THE RECORD COUNT.
DEC (HL)
LD DE,#BATCHFCB ; CLOSE THE BATCH FILE NOW.
CALL CLOSE
JP Z,GETINP1 ; QUIT ON AN ERROR.
LD A,(CDRIVE) ; RE-SELECT PREVIOUS DRIVE IF NEED BE.
OR A
CALL NZ,DSKSEL ; DON'T DO NEEDLESS SELECTS.
;
; PRINT LINE JUST READ ON CONSOLE.
;
LD HL,#INBUFF+2
CALL PLINE2
CALL CHKCON ; CHECK CONSOLE, QUIT ON A KEY.
JP Z,GETINP2 ; JUMP IF NO KEY IS PRESSED.
;
; TERMINATE THE SUBMIT JOB ON ANY KEYBOARD INPUT. DELETE THIS
; FILE SUCH THAT IT IS NOT RE-STARTED AND JUMP TO NORMAL KEYBOARD
; INPUT SECTION.
;
CALL DELBATCH ; DELETE THE BATCH FILE.
JP CMMND1 ; AND RESTART COMMAND INPUT.
;
; GET HERE FOR NORMAL KEYBOARD INPUT. DELETE THE SUBMIT FILE
; INCASE THERE WAS ONE.
;
GETINP1:CALL DELBATCH ; DELETE FILE ($$$.SUB).
CALL SETCDRV ; RESET ACTIVE DISK.
LD C,#10 ; GET LINE FROM CONSOLE DEVICE.
LD DE,#INBUFF
CALL ENTRY
CALL MOVECD ; RESET CURRENT DRIVE (AGAIN).
;
; CONVERT INPUT LINE TO UPPER CASE.
;
GETINP2:LD HL,#INBUFF+1
LD B,(HL) ; (B)=CHARACTER COUNTER.
GETINP3:INC HL
LD A,B ; END OF THE LINE?
OR A
JP Z,GETINP4
LD A,(HL) ; CONVERT TO UPPER CASE.
CALL UPPER
LD (HL),A
DEC B ; ADJUST CHARACTER COUNT.
JP GETINP3
GETINP4:LD (HL),A ; ADD TRAILING NULL.
LD HL,#INBUFF+2
LD (INPOINT),HL ; RESET INPUT LINE POINTER.
RET
;
; ROUTINE TO CHECK THE CONSOLE FOR A KEY PRESSED. THE ZERO
; FLAG IS SET IS NONE, ELSE THE CHARACTER IS RETURNED IN (A).
;
CHKCON: LD C,#11 ; CHECK CONSOLE.
CALL ENTRY
OR A
RET Z ; RETURN IF NOTHING.
LD C,#1 ; ELSE GET CHARACTER.
CALL ENTRY
OR A ; CLEAR ZERO FLAG AND RETURN.
RET
;
; ROUTINE TO GET THE CURRENTLY ACTIVE DRIVE NUMBER.
;
GETDSK: LD C,#25
JP ENTRY
;
; SET THE STABDARD DMA ADDRESS.
;
STDDMA: LD DE,#TBUFF
;
; ROUTINE TO SET THE DMA ADDRESS TO (DE).
;
DMASET: LD C,#26
JP ENTRY
;
; DELETE THE BATCH FILE CREATED BY SUBMIT.
;
DELBATCH:
LD HL,#BATCH ; IS BATCH ACTIVE?
LD A,(HL)
OR A
RET Z
LD (HL),#0 ; YES, DE-ACTIVATE IT.
XOR A
CALL DSKSEL ; SELECT DRIVE 0 FOR SURE.
LD DE,#BATCHFCB ; AND DELETE THIS FILE.
CALL DELETE
LD A,(CDRIVE) ; RESET CURRENT DRIVE.
JP DSKSEL
;
; PRINT BACK FILE NAME WITH A '?' TO INDICATE A SYNTAX ERROR.
;
SYNERR: CALL CRLF ; END CURRENT LINE.
LD HL,(NAMEPNT) ; THIS POINTS TO NAME IN ERROR.
SYNERR1:LD A,(HL) ; PRINT IT UNTIL A SPACE OR NULL IS FOUND.
CP #ASCSPACE
JP Z,SYNERR2
OR A
JP Z,SYNERR2
PUSH HL
CALL PRINT
POP HL
INC HL
JP SYNERR1
SYNERR2:LD A,#QUESTION ; ADD TRAILING '?'.
CALL PRINT
CALL CRLF
CALL DELBATCH ; DELETE ANY BATCH FILE.
JP CMMND1 ; AND RESTART FROM CONSOLE INPUT.
;
; CHECK CHARACTER AT (DE) FOR LEGAL COMMAND INPUT. NOTE THAT THE
; ZERO FLAG IS SET IF THE CHARACTER IS A DELIMITER.
;
CHECK: LD A,(DE)
OR A
RET Z
CP #ASCSPACE ; CONTROL CHARACTERS ARE NOT LEGAL HERE.
JP C,SYNERR
RET Z ; CHECK FOR VALID DELIMITER.
CP #EQUAL
RET Z
CP #UNDERSCORE
RET Z
CP #PERIOD
RET Z
CP #COLON
RET Z
CP #0x3b
RET Z
CP #LESSTHAN
RET Z
CP #GREATERTHAN
RET Z
RET
;
; GET THE NEXT NON-BLANK CHARACTER FROM (DE).
;
NONBLANK:
LD A,(DE)
OR A ; STRING ENDS WITH A NULL.
RET Z
CP #ASCSPACE
RET NZ
INC DE
JP NONBLANK
;
; ADD (HL)=(HL)+(A)
;
ADDHL: ADD A,L
LD L,A
RET NC ; TAKE CARE OF ANY CARRY.
INC H
RET
;
; CONVERT THE FIRST NAME IN (FCB).
;
CONVFST:LD A,#0
;
; FORMAT A FILE NAME (CONVERT * TO '?', ETC.). ON RETURN,
; (A)=0 IS AN UNAMBIGEOUS NAME WAS SPECIFIED. ENTER WITH (A) .EQUAL TO
; THE POSITION WITHIN THE FCB FOR THE NAME (EITHER 0 OR 16).
;
CONVERT:LD HL,#FCB
CALL ADDHL
PUSH HL
PUSH HL
XOR A
LD (CHGDRV),A ; INITIALIZE DRIVE CHANGE FLAG.
LD HL,(INPOINT) ; SET (HL) AS POINTER INTO INPUT LINE.
EX DE,HL
CALL NONBLANK ; GET NEXT NON-BLANK CHARACTER.
EX DE,HL
LD (NAMEPNT),HL ; SAVE POINTER HERE FOR ANY ERROR MESSAGE.
EX DE,HL
POP HL
LD A,(DE) ; GET FIRST CHARACTER.
OR A
JP Z,CONVRT1
SBC A,#0x41-1 ; MIGHT BE A DRIVE NAME, CONVERT TO BINARY.
LD B,A ; AND SAVE.
INC DE ; CHECK NEXT CHARACTER FOR A ':'.
LD A,(DE)
CP #COLON
JP Z,CONVRT2
DEC DE ; NOPE, MOVE POINTER BACK TO THE START OF THE LINE.
CONVRT1:LD A,(CDRIVE)
LD (HL),A
JP CONVRT3
CONVRT2:LD A,B
LD (CHGDRV),A ; SET CHANGE IN DRIVES FLAG.
LD (HL),B
INC DE
;
; CONVERT THE BASIC FILE NAME.
;
CONVRT3:LD B,#8
CONVRT4:CALL CHECK
JP Z,CONVRT8
INC HL
CP #ASTERICK ; NOTE THAT AN '*' WILL FILL THE REMAINING
JP NZ,CONVRT5 ; FIELD WITH '?'.
LD (HL),#QUESTION
JP CONVRT6
CONVRT5:LD (HL),A
INC DE
CONVRT6:DEC B
JP NZ,CONVRT4
CONVRT7:CALL CHECK ; GET NEXT DELIMITER.
JP Z,GETEXT
INC DE
JP CONVRT7
CONVRT8:INC HL ; BLANK FILL THE FILE NAME.
LD (HL),#ASCSPACE
DEC B
JP NZ,CONVRT8
;
; GET THE EXTENSION AND CONVERT IT.
;
GETEXT: LD B,#3
CP #PERIOD
JP NZ,GETEXT5
INC DE
GETEXT1:CALL CHECK
JP Z,GETEXT5
INC HL
CP #ASTERICK
JP NZ,GETEXT2
LD (HL),#QUESTION
JP GETEXT3
GETEXT2:LD (HL),A
INC DE
GETEXT3:DEC B
JP NZ,GETEXT1
GETEXT4:CALL CHECK
JP Z,GETEXT6
INC DE
JP GETEXT4
GETEXT5:INC HL
LD (HL),#ASCSPACE
DEC B
JP NZ,GETEXT5
GETEXT6:LD B,#3
GETEXT7:INC HL
LD (HL),#0
DEC B
JP NZ,GETEXT7
EX DE,HL
LD (INPOINT),HL ; SAVE INPUT LINE POINTER.
POP HL
;
; CHECK TO SEE IF THIS IS AN AMBIGEOUS FILE NAME SPECIFICATION.
; SET THE (A) REGISTER TO NON ZERO IF IT IS.
;
LD BC,#11 ; SET NAME LENGTH.
GETEXT8:INC HL
LD A,(HL)
CP #QUESTION ; ANY QUESTION MARKS?
JP NZ,GETEXT9
INC B ; COUNT THEM.
GETEXT9:DEC C
JP NZ,GETEXT8
LD A,B
OR A
RET
;
; CP/M COMMAND TABLE. NOTE COMMANDS CAN BE EITHER 3 OR 4 CHARACTERS LONG.
;
NUMCMDS = 6 ; NUMBER OF COMMANDS
CMDTBL: .ascii "DIR "
.ascii "ERA "
.ascii "TYPE"
.ascii "SAVE"
.ascii "REN "
.ascii "USER"
CMDADR: .DW DIRECT
.DW ERASE
.DW TYPE
.DW SAVE
.DW RENAME
.DW USER
.DW UNKNOWN
;
; SEARCH THE COMMAND TABLE FOR A MATCH WITH WHAT HAS JUST
; BEEN ENTERED. IF A MATCH IS FOUND, THEN WE JUMP TO THE
; PROPER SECTION. ELSE JUMP TO (UNKNOWN).
; ON RETURN, THE (C) REGISTER IS SET TO THE COMMAND NUMBER
; THAT MATCHED (OR NUMCMDS+1 IF NO MATCH).
;
SEARCH: LD HL,#CMDTBL
LD C,#0
SEARCH1:LD A,C
CP #NUMCMDS ; THIS COMMANDS EXISTS.
RET NC
LD DE,#FCB+1 ; CHECK THIS ONE.
LD B,#4 ; MAX COMMAND LENGTH.
SEARCH2:LD A,(DE)
CP (HL)
JP NZ,SEARCH3 ; NOT A MATCH.
INC DE
INC HL
DEC B
JP NZ,SEARCH2
LD A,(DE) ; ALLOW A 3 CHARACTER COMMAND TO MATCH.
CP #ASCSPACE
JP NZ,SEARCH4
LD A,C ; SET RETURN REGISTER FOR THIS COMMAND.
RET
SEARCH3:INC HL
DEC B
JP NZ,SEARCH3
SEARCH4:INC C
JP SEARCH1
;
; SET THE INPUT BUFFER TO EMPTY AND THEN START THE COMMAND
; PROCESSOR (CCP).
;
CLEARBUF:
XOR A
LD (INBUFF+1),A ; SECOND BYTE IS ACTUAL LENGTH.
COMMAND:LD SP,#CCPSTACK ; SETUP STACK AREA.
PUSH BC ; NOTE THAT (C) SHOULD BE .EQUAL TO:
LD A,C ; (UUUUDDDD) WHERE 'UUUU' IS THE USER NUMBER
RRA ; AND 'DDDD' IS THE DRIVE NUMBER.
RRA
RRA
RRA
AND #0x0F ; ISOLATE THE USER NUMBER.
LD E,A
CALL GETSETUC ; AND SET IT.
CALL RESDSK ; RESET THE DISK SYSTEM.
LD (BATCH),A ; CLEAR BATCH MODE FLAG.
POP BC
LD A,C
AND #0x0F ; ISOLATE THE DRIVE NUMBER.
LD (CDRIVE),A ; AND SAVE.
CALL DSKSEL ; ...AND SELECT.
LD A,(INBUFF+1)
OR A ; ANYTHING IN INPUT BUFFER ALREADY?
JP NZ,CMMND2 ; YES, WE JUST PROCESS IT.
;
; ENTRY POINT TO GET A COMMAND LINE FROM THE CONSOLE.
;
CMMND1: LD SP,#CCPSTACK ; SET STACK STRAIGHT.
CALL CRLF ; START A NEW LINE ON THE SCREEN.
CALL GETDSK ; GET CURRENT DRIVE.
ADD A,#0x41
CALL PRINT ; PRINT CURRENT DRIVE.
.IF USRDSP
CALL GETUSR ;GET CURRENT USER NUMBER
CP #10 ;TWO DIGITS?
JR C,CMMND3 ;NO
LD A,#0x31 ;PRINT LEADING '1'
CALL PRINT
CALL GETUSR ;GET CURRENT USER NUMBER
SUB #10 ;SUBTRACT 10
CMMND3: ADD A,#0x30
CALL PRINT
.ENDIF
LD A,#GREATERTHAN
CALL PRINT ; AND ADD PROMPT.
CALL GETINP ; GET LINE FROM USER.
;
; PROCESS COMMAND LINE HERE.
;
CMMND2: LD DE,#TBUFF
CALL DMASET ; SET STANDARD DMA ADDRESS.
CALL GETDSK
LD (CDRIVE),A ; SET CURRENT DRIVE.
CALL CONVFST ; CONVERT NAME TYPED IN.
CALL NZ,SYNERR ; WILD CARDS ARE NOT ALLOWED.
LD A,(CHGDRV) ; IF A CHANGE IN DRIVES WAS INDICATED,
OR A ; THEN TREAT THIS AS AN UNKNOWN COMMAND
JP NZ,UNKNOWN ; WHICH GETS EXECUTED.
CALL SEARCH ; ELSE SEARCH COMMAND TABLE FOR A MATCH.
;
; NOTE THAT AN UNKNOWN COMMAND RETURNS
; WITH (A) POINTING TO THE LAST ADDRESS
; IN OUR TABLE WHICH IS (UNKNOWN).
;
LD HL,#CMDADR ; NOW, LOOK THRU OUR ADDRESS TABLE FOR COMMAND (A).
LD E,A ; SET (DE) TO COMMAND NUMBER.
LD D,#0
ADD HL,DE
ADD HL,DE ; (HL)=(CMDADR)+2*(COMMAND NUMBER).
LD A,(HL) ; NOW PICK OUT THIS ADDRESS.
INC HL
LD H,(HL)
LD L,A
JP (HL) ; NOW EXECUTE IT.
;
; READ ERROR WHILE TYPEING A FILE.
;
RDERROR:LD BC,#RDERR
JP PLINE
RDERR: .asciz "Read Error"
;
; R.EQUIRED FILE WAS NOT LOCATED.
;
NONE: LD BC,#NOFILE
JP PLINE
NOFILE: .asciz "No File"
;
; DECODE A COMMAND OF THE FORM 'A>FILENAME NUMBER{ FILENAME}.
; NOTE THAT A DRIVE SPECIFIER IS NOT ALLOWED ON THE FIRST FILE
; NAME. ON RETURN, THE NUMBER IS IN REGISTER (A). ANY ERROR
; CAUSES 'FILENAME?' TO BE PRINTED AND THE COMMAND IS ABORTED.
;
DECODE: CALL CONVFST ; CONVERT FILENAME.
LD A,(CHGDRV) ; DO NOT ALLOW A DRIVE TO BE SPECIFIED.
OR A
JP NZ,SYNERR
LD HL,#FCB+1 ; CONVERT NUMBER NOW.
LD BC,#11 ; (B)=SUM REGISTER, (C)=MAX DIGIT COUNT.
DECODE1:LD A,(HL)
CP #ASCSPACE ; A SPACE TERMINATES THE NUMERAL.
JP Z,DECODE3
INC HL
SUB #0x30 ; MAKE BINARY FROM ASCII.
CP #10 ; LEGAL DIGIT?
JP NC,SYNERR
LD D,A ; YES, SAVE IT IN (D).
LD A,B ; COMPUTE (B)=(B)*10 AND CHECK FOR OVERFLOW.
AND #0x0E0
JP NZ,SYNERR
LD A,B
RLCA
RLCA
RLCA ; (A)=(B)*8
ADD A,B ; .......*9
JP C,SYNERR
ADD A,B ; .......*10
JP C,SYNERR
ADD A,D ; ADD IN NEW DIGIT NOW.
DECODE2:JP C,SYNERR
LD B,A ; AND SAVE RESULT.
DEC C ; ONLY LOOK AT 11 DIGITS.
JP NZ,DECODE1
RET
DECODE3:LD A,(HL) ; SPACES MUST FOLLOW (WHY?).
CP #ASCSPACE
JP NZ,SYNERR
INC HL
DECODE4:DEC C
JP NZ,DECODE3
LD A,B ; SET (A)=THE NUMERIC VALUE ENTERED.
RET
;
; MOVE 3 BYTES FROM (HL) TO (DE). NOTE THAT THERE IS ONLY
; ONE REFERENCE TO THIS AT (A2D5H).
;
MOVE3: LD B,#3
;
; MOVE (B) BYTES FROM (HL) TO (DE).
;
HL2DE: LD A,(HL)
LD (DE),A
INC HL
INC DE
DEC B
JP NZ,HL2DE
RET
;
; COMPUTE (HL)=(TBUFF)+(A)+(C) AND GET THE BYTE THAT'S HERE.
;
EXTRACT:LD HL,#TBUFF
ADD A,C
CALL ADDHL
LD A,(HL)
RET
;
; CHECK DRIVE SPECIFIED. IF IT MEANS A CHANGE, THEN THE NEW
; DRIVE WILL BE SELECTED. IN ANY CASE, THE DRIVE BYTE OF THE
; FCB WILL BE SET TO NULL (MEANS USE CURRENT DRIVE).
;
DSELECT:XOR A ; NULL OUT FIRST BYTE OF FCB.
LD (FCB),A
LD A,(CHGDRV) ; A DRIVE CHANGE INDICATED?
OR A
RET Z
DEC A ; YES, IS IT THE SAME AS THE CURRENT DRIVE?
LD HL,#CDRIVE
CP (HL)
RET Z
JP DSKSEL ; NO. SELECT IT THEN.
;
; CHECK THE DRIVE SELECTION AND RESET IT TO THE PREVIOUS
; DRIVE IF IT WAS CHANGED FOR THE PRECEEDING COMMAND.
;
RESETDR:LD A,(CHGDRV) ; DRIVE CHANGE INDICATED?
OR A
RET Z
DEC A ; YES, WAS IT A DIFFERENT DRIVE?
LD HL,#CDRIVE
CP (HL)
RET Z
LD A,(CDRIVE) ; YES, RE-SELECT OUR OLD DRIVE.
JP DSKSEL
;
;**************************************************************
;*
;* D I R E C T O R Y C O M M A N D
;*
;**************************************************************
;
DIRECT: CALL CONVFST ; CONVERT FILE NAME.
CALL DSELECT ; SELECT INDICATED DRIVE.
LD HL,#FCB+1 ; WAS ANY FILE INDICATED?
LD A,(HL)
CP #ASCSPACE
JP NZ,DIRECT2
LD B,#11 ; NO. FILL FIELD WITH '?' - SAME AS *.*.
DIRECT1:LD (HL),#QUESTION
INC HL
DEC B
JP NZ,DIRECT1
DIRECT2:LD E,#0 ; SET INITIAL CURSOR POSITION.
PUSH DE
CALL SRCHFCB ; GET FIRST FILE NAME.
CALL Z,NONE ; NONE FOUND AT ALL?
DIRECT3:JP Z,DIRECT9 ; TERMINATE IF NO MORE NAMES.
LD A,(RTNCODE) ; GET FILE'S POSITION IN SEGMENT (0-3).
RRCA
RRCA
RRCA
AND #0x60 ; (A)=POSITION*32
LD C,A
LD A,#10
CALL EXTRACT ; EXTRACT THE TENTH ENTRY IN FCB.
RLA ; CHECK SYSTEM FILE STATUS BIT.
JP C,DIRECT8 ; WE DON'T LIST THEM.
POP DE
LD A,E ; BUMP NAME COUNT.
INC E
PUSH DE
AND #3 ; AT END OF LINE?
PUSH AF
JP NZ,DIRECT4
CALL CRLF ; YES, END THIS LINE AND START ANOTHER.
PUSH BC
CALL GETDSK ; START LINE WITH ('A:').
POP BC
ADD A,#0x41
CALL PRINTB
LD A,#COLON
CALL PRINTB
JP DIRECT5
DIRECT4:CALL SPACE ; ADD SEPERATOR BETWEEN FILE NAMES.
LD A,#COLON
CALL PRINTB
DIRECT5:CALL SPACE
LD B,#1 ; 'EXTRACT' EACH FILE NAME CHARACTER AT A TIME.
DIRECT6:LD A,B
CALL EXTRACT
AND #0x7F ; STRIP BIT 7 (STATUS BIT).
CP #ASCSPACE ; ARE WE AT THE END OF THE NAME?
JP NZ,DRECT65
POP AF ; YES, DON'T PRINT SPACES AT THE END OF A LINE.
PUSH AF
CP #3
JP NZ,DRECT63
LD A,#9 ; FIRST CHECK FOR NO EXTENSION.
CALL EXTRACT
AND #0x7F
CP #ASCSPACE
JP Z,DIRECT7 ; DON'T PRINT SPACES.
DRECT63:LD A,#ASCSPACE ; ELSE PRINT THEM.
DRECT65:CALL PRINTB
INC B ; BUMP TO NEXT CHARACTER PSOITION.
LD A,B
CP #12 ; END OF THE NAME?
JP NC,DIRECT7
CP #9 ; NOPE, STARTING EXTENSION?
JP NZ,DIRECT6
CALL SPACE ; YES, ADD SEPERATING SPACE.
JP DIRECT6
DIRECT7:POP AF ; GET THE NEXT FILE NAME.
DIRECT8:CALL CHKCON ; FIRST CHECK CONSOLE, QUIT ON ANYTHING.
JP NZ,DIRECT9
CALL SRCHNXT ; GET NEXT NAME.
JP DIRECT3 ; AND CONTINUE WITH OUR LIST.
DIRECT9:POP DE ; RESTORE THE STACK AND RETURN TO COMMAND LEVEL.
JP GETBACK
;
;**************************************************************
;*
;* E R A S E C O M M A N D
;*
;**************************************************************
;
ERASE: CALL CONVFST ; CONVERT FILE NAME.
CP #11 ; WAS '*.*' ENTERED?
JP NZ,ERASE1
LD BC,#YESNO ; YES, ASK FOR CONFIRMATION.
CALL PLINE
CALL GETINP
LD HL,#INBUFF+1
DEC (HL) ; MUST BE EXACTLY 'Y'.
JP NZ,CMMND1
INC HL
LD A,(HL)
CP #0x59
JP NZ,CMMND1
INC HL
LD (INPOINT),HL ; SAVE INPUT LINE POINTER.
ERASE1: CALL DSELECT ; SELECT DESIRED DISK.
LD DE,#FCB
CALL DELETE ; DELETE THE FILE.
INC A
CALL Z,NONE ; NOT THERE?
JP GETBACK ; RETURN TO COMMAND LEVEL NOW.
YESNO: .asciz "All (Y/N)?"
;
;**************************************************************
;*
;* T Y P E C O M M A N D
;*
;**************************************************************
;
TYPE: CALL CONVFST ; CONVERT FILE NAME.
JP NZ,SYNERR ; WILD CARDS NOT ALLOWED.
CALL DSELECT ; SELECT INDICATED DRIVE.
CALL OPENFCB ; OPEN THE FILE.
JP Z,TYPE5 ; NOT THERE?
CALL CRLF ; OK, START A NEW LINE ON THE SCREEN.
LD HL,#NBYTES ; INITIALIZE BYTE COUNTER.
LD (HL),#0x0FF ; SET TO READ FIRST SECTOR.
TYPE1: LD HL,#NBYTES
TYPE2: LD A,(HL) ; HAVE WE WRITTEN THE ENTIRE SECTOR?
CP #128
JP C,TYPE3
PUSH HL ; YES, READ IN THE NEXT ONE.
CALL READFCB
POP HL
JP NZ,TYPE4 ; END OR ERROR?
XOR A ; OK, CLEAR BYTE COUNTER.
LD (HL),A
TYPE3: INC (HL) ; COUNT THIS BYTE.
LD HL,#TBUFF ; AND GET THE (A)TH ONE FROM THE BUFFER (TBUFF).
CALL ADDHL
LD A,(HL)
CP #CNTRLZ ; END OF FILE MARK?
JP Z,GETBACK
CALL PRINT ; NO, PRINT IT.
CALL CHKCON ; CHECK CONSOLE, QUIT IF ANYTHING READY.
JP NZ,GETBACK
JP TYPE1
;
; GET HERE ON AN END OF FILE OR READ ERROR.
;
TYPE4: DEC A ; READ ERROR?
JP Z,GETBACK
CALL RDERROR ; YES, PRINT MESSAGE.
TYPE5: CALL RESETDR ; AND RESET PROPER DRIVE
JP SYNERR ; NOW PRINT FILE NAME WITH PROBLEM.
;
;**************************************************************
;*
;* S A V E C O M M A N D
;*
;**************************************************************
;
SAVE: CALL DECODE ; GET NUMERIC NUMBER THAT FOLLOWS SAVE.
PUSH AF ; SAVE NUMBER OF PAGES TO WRITE.
CALL CONVFST ; CONVERT FILE NAME.
JP NZ,SYNERR ; WILD CARDS NOT ALLOWED.
CALL DSELECT ; SELECT SPECIFIED DRIVE.
LD DE,#FCB ; NOW DELETE THIS FILE.
PUSH DE
CALL DELETE
POP DE
CALL CREATE ; AND CREATE IT AGAIN.
JP Z,SAVE3 ; CAN'T CREATE?
XOR A ; CLEAR RECORD NUMBER BYTE.
LD (FCB+32),A
POP AF ; CONVERT PAGES TO SECTORS.
LD L,A
LD H,#0
ADD HL,HL ; (HL)=NUMBER OF SECTORS TO WRITE.
LD DE,#TBASE ; AND WE START FROM HERE.
SAVE1: LD A,H ; DONE YET?
OR L
JP Z,SAVE2
DEC HL ; NOPE, COUNT THIS AND COMPUTE THE START
PUSH HL ; OF THE NEXT 128 BYTE SECTOR.
LD HL,#128
ADD HL,DE
PUSH HL ; SAVE IT AND SET THE TRANSFER ADDRESS.
CALL DMASET
LD DE,#FCB ; WRITE OUT THIS SECTOR NOW.
CALL WRTREC
POP DE ; RESET (DE) TO THE START OF THE LAST SECTOR.
POP HL ; RESTORE SECTOR COUNT.
JP NZ,SAVE3 ; WRITE ERROR?
JP SAVE1
;
; GET HERE AFTER WRITING ALL OF THE FILE.
;
SAVE2: LD DE,#FCB ; NOW CLOSE THE FILE.
CALL CLOSE
INC A ; DID IT CLOSE OK?
JP NZ,SAVE4