-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathLynx_96k_Rom.ASM
2623 lines (2600 loc) · 106 KB
/
Lynx_96k_Rom.ASM
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
;***********************************************************************
;*
;* Camputers Lynx 96k ROM disassembly (version L014)
;* -------------------------------------------------
;*
;* Reconstructed from Camputers Lynx "Mark II" source code (Version 505, 31 July 87)
;*
;* Disassembly, collation and formatting by: Mike Panter 25/06/2022.
;*
;* Additional credit to: Russell Davis (online archive of materials)
;* Pete Todd (knowledge, insight and Pale)
;*
;* WARNING: May contain inaccuracies - use at own risk.
;*
;* Free to distribute. Please include attribution.
;*
;* ---------------------------------------------------------------------
;* DECOMPILED USING: z88dk-dis -o 0x4000 -x "Lynx_48k_Rom.sym" "lynx96-3.rom"
;* COMPILE/ASSEMBLE: z88dk-z80asm -split-bin -b -mz80 -o"Lynx" "Lynx_48k_Rom.ASM" "Lynx_96k_Rom.ASM"
;* ---------------------------------------------------------------------
;*
;
EXTERN INTFP, ERR_TYPE_MISMATCH, ERR_OUT_OF_DATA, ERR_NOT_YET_IMP, ERR_SYNTAX, SPACE
EXTERN LNUM1, PN, TEST_IS_LOOP_END, SUB_INDENT, SKIP_LNUM, SUB_PRINT_KEYWORD, PRINT_BAS_LINE
EXTERN PRINT_STRING, DISPLAY_SPACE, PNE1, DO_INDENT, IEND, _BEEP, D6845, ERR_BAD_TAPE
EXTERN ERR_NUM_OUT_RANGE, ERR_OUT_OF_MEM, ERR_OVERFLOW, ERR_SOMETHG_MISSG, ERROR_PRINT
EXTERN EXEC2, FLOAT_ZERO, FPINT, GET_VAR_ADDR, IDPOKE, IE4CR, IE6CR, IINK, ILOAD, IVRY
EXTERN IREM, MOTOFF, RBYTE, READ_STRING_EXPR, READ_STRING_VAR, RP, RSYNC, STRING_EXEC
EXTERN SUB_PLOT3, TAPE_READ, TEST_FOR_STR_EXP, TEST_FOR_STRING, TEST_IS_COMMA
EXTERN VPTR_IS_STR, WRITE_FNAME, WSYNC, VROM, DFTW
;
include "Lynx.def"
include "Tokens.def"
SECTION _96k_3
PHASE $4000
;
NOP ;[4000]
JP EXINIT ;[4001]
; Copy to RAM from here.
;
LWRAM:
ROMOFF:
PUSH BC ;[4004]
LD BC,$FF7F ;[4005] Bank switching
LD A,$10 ;[4008]
OUT (C),A ;[400A]
POP BC ;[400C]
RET ;[400D]
ROMON:
PUSH BC ;[400E]
LD BC,$FF7F ;[400F] Bank switching
XOR A ;[4012]
OUT (C),A ;[4013]
POP BC ;[4015]
RET ;[4016]
;
; Execute LD A,(HL) for HL in low RAM
;
LAHL:
PUSH BC ;[4017]
PUSH DE ;[4018] Rom off
LD BC,$FF7F ;[4019] Bank switching
LD DE,$1000 ;[401C]
OUT (C),D ;[401F]
LD A,(HL) ;[4021]
OUT (C),E ;[4022]
POP DE ;[4024]
POP BC ;[4025]
RET ;[4026]
;
; Execute LDIR for HL in low RAM
;
ELDIR:
PUSH BC ;[4027] ROMOFF
LD BC,$FF7F ;[4028] Bank switching
LD A,$10 ;[402B]
OUT (C),A ;[402D]
POP BC ;[402F]
LDIR ;[4030] LDIR
LD BC,$FF7F ;[4032] ROMON
XOR A ;[4035]
OUT (C),A ;[4036]
RET ;[4038]
;
; Read variables from pad into
; BASIC area. In both,
; IX = pointer to BASIC
; HL = read pointer
; BC = write pointer
; Set C for EOF.
;
RNUM:
CALL ROMOFF ;[4039]
PUSH DE ;[403C]
CALL PRDBYT ;[403D] control byte
BIT 7,A ;[4040]
JP NZ,PRDTM ;[4042] 1 = string (type mismatch)
BIT 6,A ;[4045]
JR NZ,PRDN5 ;[4047] 1 = f.p.
BIT 5,A ;[4049]
JR NZ,PRDN1 ;[404B]
LD D,0 ;[404D]
BIT 4,A ;[404F]
JR Z,PRDN3 ;[4051]
AND $0F ;[4053]
JR PRDN2 ;[4055]
PRDN1:
CALL PRDBYT ;[4057]
PRDN2:
LD D,A ;[405A]
CALL PRDBYT ;[405B]
PRDN3:
LD E,A ;[405E] now DE = number
PUSH BC ;[405F]
PUSH HL ;[4060]
EX DE,HL ;[4061]
CALL ROMON ;[4062]
CALL INTFP ;[4065] number to WRA1
LD B,5 ;[4068]
LD HL,SYSVAR_WRA1 ;[406A]
PRDN4:
LD A,(HL) ;[406D] floating point
INC HL ;[406E]
LD (IX+0),A ;[406F]
INC IX ;[4072]
DJNZ PRDN4 ;[4074]
POP HL ;[4076]
POP BC ;[4077]
POP DE ;[4078]
RET ;[4079]
PRDN5:
LD E,$05 ;[407A]
PRDN6:
CALL PRDBYT ;[407C]
LD (IX+0),A ;[407F]
INC IX ;[4082]
DEC E ;[4084]
JR NZ,PRDN6 ;[4085]
PRDN7:
POP DE ;[4087]
JP ROMON ;[4088]
;
; Read string
;
RSTR:
CALL ROMOFF ;[408B]
PUSH DE ;[408E]
LD E,(IX-1) ;[408F] max size for string
CALL PRDBYT ;[4092] control byte
BIT 7,A ;[4095]
JP Z,PRDTM ;[4097]
RES 7,A ;[409A]
LD D,A ;[409C] length in file
INC D ;[409D]
PRDS1:
DEC D ;[409E]
JR Z,PRDS2 ;[409F]
CALL PRDBYT ;[40A1] get char
INC E ;[40A4]
DEC E ;[40A5]
JR Z,PRDS1 ;[40A6] ignore if no room
LD (IX+0),A ;[40A8]
INC IX ;[40AB]
DEC E ;[40AD]
JR PRDS1 ;[40AE]
PRDS2:
LD (IX+0),SZ ;[40B0]
POP DE ;[40B4]
JP ROMON ;[40B5]
;
; Read byte from software file
; NB Assumes interrupts already disabled *******
;
PRDBYT:
LD A,H ;[40B8]
CP B ;[40B9]
JR NZ,PRDB2 ;[40BA]
LD A,L ;[40BC]
CP C ;[40BD]
JP Z,PRDEOF ;[40BE]
PRDB2:
INC L ;[40C1]
JR NZ,PRDB3 ;[40C2]
LD H,(HL) ;[40C4]
INC L ;[40C5]
PRDB3:
LD A,(HL) ;[40C6]
RET ;[40C7]
PRDTM:
CALL ROMON ;[40C8]
CALL ERR_TYPE_MISMATCH ;[40CB]
PRDEOF:
CALL ROMON ;[40CE]
CALL ERR_OUT_OF_DATA ;[40D1]
;
; Get byte to save to tape.
;
EGETB:
EXX ;[40D4]
OUT (C),D ;[40D5]
INC L ;[40D7]
JR NZ,GTBYT1 ;[40D8]
LD H,(HL) ;[40DA]
INC L ;[40DB]
GTBYT1:
LD A,(HL) ;[40DC]
OUT (C),E ;[40DD]
EXX ;[40DF]
RET ;[40E0]
;
; Length of the "Low Ram" section above - to be copied to RAM (in EXINIT)
; (the PHASE command messes up the calculation by $4000, so deduct $4000)
;
LWLEN equ $-LWRAM-$4000
;
; Padding
;
DEFS 31,0
;
; Extra initialization.
; Copy ROM (LWRAM) to LOW RAM
;
EXINIT:
LD HL,LWRAM ;[4100] copy from HL (rom) to HL (ram)!
LD D,H ;[4103] (rom/ram reflection)
LD E,L ;[4104]
LD BC,LWLEN ;[4105]
LDIR ;[4108] Copy the "Low Ram" rom section to RAM
LD HL,UPROM ;[410A]
LD DE,UPRAM ;[410D]
LD BC,UPLEN ;[4110]
LDIR ;[4113]
LD HL,JUMPS ;[4115]
LD DE,SYSVAR_FLIGHT ;[4118]
LD BC,$15 ;[411B]
LDIR ;[411E]
;
; Change some 48K values.
;
LD A,(SYSVAR_EEXT+2) ;[4120] EXT done already?
CP $40 ;[4123]
JR NC,CHG2 ;[4125]
LD HL,EXTRAM ;[4127] no, clear RAM
LD B,8 ;[412A]
CHG1:
LD (HL),0 ;[412C]
INC HL ;[412E]
DJNZ CHG1 ;[412F]
;
LD HL,IEXTS ;[4131]
LD (SYSVAR_IEXT+1),HL ;[4134]
LD HL,EEXTS ;[4137]
LD (SYSVAR_EEXT+1),HL ;[413A]
LD HL,DBL96K ;[413D]
LD (SYSVAR_DBASLN+1),HL ;[4140]
CHG2:
LD HL,EXTTAB ;[4143]
LD (EXTRAM+2),HL ;[4146] 2 for int. ROM
LD A,EXT ;[4149] make <O$ESC>E = EXT
LD (SYSVAR_KTBL+4),A ;[414B]
LD A,FN1 ;[414E]
LD HL,EXSR ;[4150]
LD (SYSVAR_EXECSUB),A ;[4153]
LD (SYSVAR_EXECSUB+1),HL ;[4156]
;
CALL EPPR ;[4159] init parallel printer
CALL PAD ;[415C] init pad (low RAM)
RET ;[415F]
;
; Initial values of RAM.
;
UPROM:
DB 2 ;[4160] next free page
DB 0 ;[4161] current file
DB 0,PZ,0,PZ,0,PZ,0,0 ;[4162] file info
DW 0 ;[416A] error variable
DW 0 ;[416C] EXEC stack pointer
DB $88 ;[416E] lightpen offset
UPLEN equ ASMPC-UPROM-$4000
;
; Jumps
;
JUMPS:
JP FPEN ;[416F] Lightpen function
JP FJOY ;[4171] Joystick function
JP ERR_NOT_YET_IMP ;[4175] User0
JP ERR_NOT_YET_IMP ;[4178] User1
JP ERR_NOT_YET_IMP ;[417B] User2
JP ERR_NOT_YET_IMP ;[417E] User3
JP ERRORHANDLER ;[4181] Called during error.
;
EXTTAB:
EXT_ASCII: DW XT96KS ;[4184] ASCII for EXT commands
EXT_INPUT: DW XI96KS ;[4186] addr's for EXT input
EXT_EXEC: DW XE96KS ;[4188] addr's for EXT exec
;
; Search for tokenable word.
; HL points to start of table,
; DE points to input.
; Exit with A = position of word,
; set C if no match.
; BC is changed!
;
EXTK:
PUSH HL ;[418A]
LD B,(HL) ;[418B] word count
INC B ;[418C]
PUSH DE ;[418D]
EXTK1: ; Start new word
POP DE ;[418E] Restart input
DJNZ EXTK2 ;[418F]
POP HL ;[4191] Failed
SCF ;[4192]
RET ;[4193]
EXTK2:
INC HL ;[4194]
LD A,(HL) ;[4195]
SUB $80 ;[4196]
JR C,EXTK2 ;[4198] Loop till start of wo
LD C,A ;[419A]
PUSH DE ;[419B]
JR EXTK5 ;[419C]
EXTK4: ; next char in word
INC HL ;[419E]
LD C,(HL) ;[419F]
BIT 7,C ;[41A0] Start of next word?
JR NZ,EXTK8 ;[41A2]
EXTK5: ; compare with input
RST $10 ;[41A4]
INC DE ;[41A5]
CP 'a' ;[41A6] l/c to u/c
JR C,EXTK6 ;[41A8]
CP 'z'+1 ;[41AA]
JR NC,EXTK6 ;[41AC]
SUB $20 ;[41AE]
EXTK6:
CP C ;[41B0]
JR Z,EXTK4 ;[41B1]
EXTK7: ; check for '.' abbrev.
CP '.' ;[41B3]
JR NZ,EXTK1 ;[41B5]
BIT 7,(HL) ;[41B7] must be >1 char
JR NZ,EXTK1 ;[41B9]
EXTK8: ; match found
POP HL ;[41BB] leave DE now
POP HL ;[41BC] start of table
LD A,(HL) ;[41BD]
SUB B ;[41BE]
OR A ;[41BF] clear carry
RET ;[41C0]
;
; Get address from list.
; Entry: HL points to list, A = position
; Exit : HL holds addresss
;
HL2A:
PUSH DE ;[41C1]
RLCA ;[41C2]
LD E,A ;[41C3]
LD D,0 ;[41C4]
ADD HL,DE ;[41C6]
LD A,(HL) ;[41C7]
INC HL ;[41C8]
LD H,(HL) ;[41C9]
LD L,A ;[41CA]
POP DE ;[41CB]
RET ;[41CC]
;
; Set up rest of line after EXT.
;
IEXTS:
PUSH HL ;[41CD] Polish pointer
LD HL,EXTRAM-1 ;[41CE]
LD B,4 ;[41D1] 4 types of EXT
IEXTS1:
PUSH BC ;[41D3]
INC HL ;[41D4]
LD C,(HL) ;[41D5]
INC HL ;[41D6]
LD B,(HL) ;[41D7]
LD A,C ;[41D8]
OR B ;[41D9]
JR Z,IEXTS2 ;[41DA] JR if not set up
PUSH BC ;[41DC]
POP IX ;[41DD] IX points to 3-word table
PUSH HL ;[41DF]
LD L,(IX+0) ;[41E0]
LD H,(IX+1) ;[41E3] point HL at commands
CALL EXTK ;[41E6] get token if match
POP HL ;[41E9]
JR NC,IEXTS3 ;[41EA] JR if match
IEXTS2:
POP BC ;[41EC]
DJNZ IEXTS1 ;[41ED]
CALL ERR_SYNTAX ;[41EF] not in any table
IEXTS3:
POP BC ;[41F2]
LD C,A ;[41F3] position in table
LD A,$04 ;[41F4]
SUB B ;[41F6] type (0 to 3)
RRCA ;[41F7]
RRCA ;[41F8] times $40
ADD C ;[41F9] make token
POP HL ;[41FA] Polish pointer
LD (HL),A ;[41FB]
INC HL ;[41FC]
LD A,C ;[41FD] position in table
PUSH HL ;[41FE]
LD L,(IX+2) ;[41FF]
LD H,(IX+3) ;[4202] point HL at dispatch
CALL HL2A ;[4205] HL = disp. addr.
EX (SP),HL ;[4208]
JP SPACE ;[4209] get char, then dispatch (skip spaces)
;
; New "Display Basic Line".
; Allow for EXT, correct REM bug.
;
DBL96K:
PUSH IX ;[420C]
POP HL ;[420E]
PUSH HL ;[420F]
CALL LNUM1 ;[4210]
CALL PN ;[4213]
CALL TEST_IS_LOOP_END ;[4216]
CALL SUB_INDENT ;[4219]
CALL SKIP_LNUM ;[421C]
NDBL1:
LD A,(DE) ;[421F]
PUSH AF ;[4220]
CALL SUB_PRINT_KEYWORD ;[4221]
POP AF ;[4224]
CP REM ;[4225] ------ start insert
JR Z,KOPY ;[4227] just copy rest if REM
CP EXT ;[4229]
JR NZ,NDBL6 ;[422B]
LD A,(DE) ;[422D] token after EXT
AND %11000000 ;[422E]
RLCA ;[4230]
RLCA ;[4231] A = type of EXT
LD HL,EXTRAM ;[4232]
CALL HL2A ;[4235] point to 3-word table
LD A,(HL) ;[4238]
INC HL ;[4239]
LD H,(HL) ;[423A]
LD L,A ;[423B] point to ASCII
LD A,(DE) ;[423C] token again
AND %00111111 ;[423D] posn in list
CALL SUB_PRINT_KEYWORD+6 ;[423F] token back to ASCII
JR NDBL15 ;[4242] ------ end insert
NDBL6:
CP ELSE ;[4244]
JR Z,NDBL1 ;[4246]
CP CODE ;[4248]
JP Z,PRINT_BAS_LINE ;[424A]
NDBL15:
DEC DE ;[424D]
NDBL:
INC DE ;[424E]
NDBL11:
LD A,(DE) ;[424F]
CP EOS ;[4250]
RET Z ;[4252]
CP CR ;[4253]
JR Z,NDBL4 ;[4255]
CP SOP ;[4257] Start of polish
JR Z,NDBL2 ;[4259]
CP $80 ;[425B]
JR NC,NDBL3 ;[425D] Token
RST 8 ;[425F]
CP $22 ;[4260] Quote char
JR NZ,NDBL ;[4262]
CALL PRINT_STRING ;[4264]
RST 8 ;[4267]
JR NDBL ;[4268]
NDBL2:
INC DE ;[426A]
CALL SYSVAR_PP ;[426B]
JR NDBL ;[426E]
NDBL3:
CP CHR ;[4270]
PUSH AF ;[4272]
CALL C,DISPLAY_SPACE ;[4273]
CALL PNE1 ;[4276]
POP AF ;[4279]
PUSH AF ;[427A]
CALL C,DISPLAY_SPACE ;[427B]
POP AF ;[427E]
INC DE ;[427F]
CP THEN ;[4280]
JR Z,NDBL1 ;[4282]
JR NDBL11 ;[4284]
NDBL4:
POP IX ;[4286]
JP DO_INDENT+2 ;[4288]
;
; Here to copy ASCII from Polish
;
KOPY1:
INC DE ;[428B]
KOPY:
LD A,(DE) ;[428C]
CP $0D ;[428D]
JP Z,DO_INDENT ;[428F]
RST 8 ;[4292]
JR $428B ;[4293]
;
; Execute EXT command.
; DE points to token after EXT,
; A holds (DE).
;
EEXTS:
PUSH IX ;[4295]
AND %11000000 ;[4297]
RLCA ;[4299]
RLCA ;[429A] A = type of EXT
LD HL,EXTRAM ;[429B]
CALL HL2A ;[429E] point to 3-word table
LD A,H ;[42A1]
OR L ;[42A2]
CALL Z,ERR_NOT_YET_IMP ;[42A3] error if not set up
PUSH HL ;[42A6]
POP IX ;[42A7]
LD L,(IX+4) ;[42A9]
LD H,(IX+5) ;[42AC] point HL at dispatch
LD A,(DE) ;[42AF]
AND %00111111 ;[42B0]
CALL HL2A ;[42B2] get address
INC DE ;[42B5]
LD A,(DE) ;[42B6] next byte
POP IX ;[42B7]
JP (HL) ;[42B9]
;
; ASCII for EXT commands
;
XT96KS:
DB $1B ;[42BA] 27 (1b) = say how many
DB $80+'E',"XPLODE" ;[42BB]
DB $80+'K',"LAXON" ;[42C2]
DB $80+'L',"ASER" ;[42C7]
DB $80+'Z',"AP" ;[42CD]
DB $80+'S',"TORE" ;[42D0]
DB $80+'I',"STORE" ;[42D5]
DB $80+'F',"ETCH" ;[42DB]
DB $80+'W',"IPE" ;[42E0]
DB $80+'B',"ACK" ;[42E4]
DB $80+'S',"SAVE" ;[42E8]
DB $80+'S',"LOAD" ;[42ED]
DB $80+'C',"SAVE" ;[42F2]
DB $80+'C',"HAIN" ;[42F7]
DB $80+'T',"RAP" ;[42FC]
DB $80+'N',"OTRAP" ;[4300]
DB $80+'P',"PRINT" ;[4306]
DB $80+'S',"PRINT" ;[430C]
DB $80+'V',"RESET" ;[4312]
DB $80+'C',"IRCLE" ;[4318]
DB $80+'T',"RIANGLE" ;[431E]
DB $80+'C',"LW" ;[4326]
DB $80+'@',"@@@@@" ;[4329]
DB $80+'@',"@@@@@" ;[432F]
DB $80+'@',"@@@@@" ;[4335]
DB $80+'@',"@@@@@" ;[433B]
DB $80+'@',"@@@@@" ;[4341]
DB $80+'@',"@@@@@" ;[4347]
DB $80 ;[434D]
;
; Dispatch table for EXT input
;
XI96KS:
DW IEND ;[434E] EXPLODE
DW IEND ;[4350] KLAXON
DW IEND ;[4352] LASER
DW IEND ;[4354] ZAP
DW IPWR ;[4356] STORE
DW IIST ;[4358] ISTORE
DW IPRD ;[435A] FETCH
DW IINK ;[435C] WIPE
DW IINK ;[435E] BACK
DW ISSV ;[4360] SSAVE
DW ISSV ;[4362] SLOAD
DW ISSV ;[4364] CSAVE
DW IDPOKE ;[4366] CHAIN
DW ITRP ;[4368] TRAP
DW IEND ;[436A] NOTRAP
DW IEND ;[436C] PPRINT
DW IEND ;[436E] SPRINT
DW IEND ;[4370] VRESET
DW IE4CR ;[4372] CIRCLE
DW IE6CR ;[4374] TRIANGLE
DW IEND ;[4376] CLW
DW IREM ;[4378] @@@@@@
DW IREM ;[437A] @@@@@@
DW IREM ;[437C] @@@@@@
DW IREM ;[437E] @@@@@@
DW IREM ;[4380] @@@@@@
DW IREM ;[4382] @@@@@@
;
; Dispatch table for EXT execution
;
XE96KS:
DW EXPL ;[4384] EXPLODE
DW EKLX ;[4386] KLAXON
DW ELSR ;[4388] LASER
DW EZAP ;[438A] ZAP
DW EPWR ;[438C] STORE
DW EIST ;[438E] ISTORE
DW EPRD ;[4390] FETCH
DW EWIP ;[4392] WIPE
DW EBAK ;[4394] BACK
DW ESSV ;[4396] SSAVE
DW ESLD ;[4398] SLOAD
DW ECSV ;[439A] CSAVE
DW ECHN ;[439C] CHAIN
DW ETRP ;[439E] TRAP
DW ENTR ;[43A0] NOTRAP
DW EPPR ;[43A2] PPRINT
DW ESPR ;[43A4] SPRINT
DW EVRS ;[43A6] VRESET
DW ECIR ;[43A8] CIRCLE
DW ETRI ;[43AA] TRIANGLE
DW ECLW ;[43AC] CLW
DW ERR_NOT_YET_IMP ;[43AE] @@@@@@
DW ERR_NOT_YET_IMP ;[43B0] @@@@@@
DW ERR_NOT_YET_IMP ;[43B2] @@@@@@
DW ERR_NOT_YET_IMP ;[43B4] @@@@@@
DW ERR_NOT_YET_IMP ;[43B6] @@@@@@
DW ERR_NOT_YET_IMP ;[43B8] @@@@@@
;
;----------------------------------------------------------
; Routines for store, i.e. low RAM used to store software files.
; Organized into pages of 256 bytes, with byte 0 of each page
; used to point to the next page.
;
; Initialize. The file information
; has already been copied from ROM
;
PAD:
LD HL,$9FFF ;[43BA] test for 96K
LD DE,$BFFF ;[43BD]
LD A,(DE) ;[43C0]
CPL ;[43C1]
LD (DE),A ;[43C2]
LD C,(HL) ;[43C3]
CPL ;[43C4]
LD (DE),A ;[43C5]
LD A,(HL) ;[43C6]
CP C ;[43C7] if 48K, HL & DE are different
JR Z,PAD1 ;[43C8]
LD A,$80 ;[43CA] set flag if 48K
LD (KFILE),A ;[43CC]
RET ;[43CF]
PAD1:
LD A,(NXFRPG) ;[43D0] next free page
LD H,A ;[43D3] point to byte 0 of that
LD L,0 ;[43D4]
PAD2:
INC A ;[43D6]
LD (HL),A ;[43D7]
INC H ;[43D8]
CP $5F ;[43D9]
JR NZ,PAD2 ;[43DB]
LD (HL),PZ ;[43DD] terminator
LD H,$3F ;[43DF] skip over page 40H
LD (HL),$41 ;[43E1]
LD HL,KNXFIL ;[43E3] file info, upper RAM
LD DE,FILINF ;[43E6] lower RAM
LD B,MXNFIL ;[43E9] copy for each file
PAD3:
PUSH BC ;[43EB]
LD BC,RANDOM ;[43EC]
PUSH HL ;[43EF]
LDIR ;[43F0]
POP HL ;[43F2]
POP BC ;[43F3]
DJNZ PAD3 ;[43F4]
RET ;[43F6]
;
; Read file number from program,
; then get info about file & put
; info into upper RAM.
;
GETINF:
LD HL,KFILE ;[43F7] current datastore
BIT 7,(HL) ;[43FA] 48K Lynx?
CALL NZ,ERR_NOT_YET_IMP ;[43FC] yes, "not yet implemented"
PUSH HL ;[43FF]
RST $18 ;[4400] file no. to HL and A
INC DE ;[4401] start of next arg.
DEC H ;[4402] test high byte
INC H ;[4403]
CALL NZ,ERR_NUM_OUT_RANGE ;[4404] must be 0
DEC A ;[4407] nos. start at 1
CP MXNFIL ;[4408] max no of files (48)
CALL NC,ERR_NUM_OUT_RANGE ;[440A]
INC A ;[440D]
POP HL ;[440E]
BIT 6,(HL) ;[440F] valid info?
JR Z,GTINF0 ;[4411]
RES 6,(HL) ;[4413]
CP (HL) ;[4415] about this file?
RET Z ;[4416] then do no more
GTINF0:
LD (HL),A ;[4417]
GTINF1:
DEC A ;[4418]
LD H,0 ;[4419]
LD L,A ;[441B]
ADD HL,HL ;[441C] 8*(file number)
ADD HL,HL ;[441D]
ADD HL,HL ;[441E]
PUSH DE ;[441F] save program pointer
LD DE,S ;[4420] info in low RAM
ADD HL,DE ;[4423] point to this file
LD DE,KNXFIL ;[4424] info in high RAM
LD BC,8 ;[4427]
CALL ELDIR ;[442A] copy info
POP DE ;[442D]
RET ;[442E]
;
; Put updated info about file
; from high RAM into low RAM.
;
PUTINF:
LD HL,KFILE ;[442F]
LD A,(HL) ;[4432] file no.
SET 6,(HL) ;[4433] flag for GETINF
DEC A ;[4435]
LD H,0 ;[4436]
LD L,A ;[4438]
ADD HL,HL ;[4439] times 8
ADD HL,HL ;[443A]
ADD HL,HL ;[443B]
LD DE,FILINF ;[443C] info in low RAM
ADD HL,DE ;[443F]
EX DE,HL ;[4440]
LD HL,KNXFIL ;[4441]
LD BC,RANDOM ;[4444]
LDIR ;[4447]
RET ;[4449]
;
; Attach unused pages to current file
; Set Z if file not started and no
; free page is available.
;
ATTACH:
LD HL,(KWRPTR) ;[444A] write pointer
LD L,0 ;[444D] byte 0 of last page used
LD A,H ;[444F] or nothing there?
CP PZ ;[4450]
LD A,(NXFRPG) ;[4452] next free page
JR Z,ATTCH1 ;[4455] JR if file not started
LD (HL),A ;[4457] chain it on
RET ;[4458] with Z reset
ATTCH1:
LD H,A ;[4459] HL = byte 0 of free page
LD (KFSTPG),A ;[445A]
LD (KWRPTR),HL ;[445D]
LD (KRDPTR),HL ;[4460]
LD H,0 ;[4463]
LD (KFILEN),HL ;[4465] length = 0
CP PZ ;[4468] set Z if no space
RET ;[446A]
;
; Detach unused pages from current file.
;
DETACH:
LD HL,(KWRPTR) ;[446B] write pointer
LD A,H ;[446E] last page used
CP PZ ;[446F] file started?
RET Z ;[4471] if not, nothing to do
LD L,0 ;[4472] byte 0 of page
CALL LAHL ;[4474] A = next page
LD (HL),PZ ;[4477] terminate file
LD (NXFRPG),A ;[4479] unused becomes free
RET ;[447C]
;
; Input syntax for STORE
;
IPWR:
CALL TEST_IS_COMMA ;[447D] expression + ','
RST $10 ;[4480] char after ','
CP CR ;[4481] end of line?
CALL Z,ERR_SOMETHG_MISSG ;[4483]
CALL TEST_FOR_STR_EXP ;[4486] test for string expr.
JR NZ,IPWR2 ;[4489]
CALL READ_STRING_EXPR ;[448B] read string expr.
INC DE ;[448E]
JR IPWR3 ;[448F]
IPWR2:
CALL RP ;[4491] Reverse polish
IPWR3:
CP ',' ;[4494]
JP NZ,IEND ;[4496]
LD (HL),A ;[4499]
INC HL ;[449A]
JR $4480 ;[449B]
;
; Input syntax for ISTORE
;
IIST:
CALL TEST_IS_COMMA ;[449D]
IIST1:
RST $10 ;[44A0]
CP CR ;[44A1]
CALL Z,ERR_SOMETHG_MISSG ;[44A3]
CALL RP ;[44A6] must be numeric
CP ',' ;[44A9]
JP NZ,IEND ;[44AB]
LD (HL),A ;[44AE]
INC HL ;[44AF]
JR IIST1 ;[44B0]
;
; Input syntax for FETCH
;
IPRD:
CALL TEST_IS_COMMA ;[44B2] expression + ','
IPRD1:
CALL TEST_FOR_STRING ;[44B5] test for string
JR NZ,IPRD2 ;[44B8]
CALL READ_STRING_VAR ;[44BA] string syntax
RST $10 ;[44BD]
JR IPRD3 ;[44BE]
IPRD2:
CALL IVRY ;[44C0] numeric syntax
IPRD3:
LD (HL),A ;[44C3] term'r to Polish
CP CR ;[44C4]
RET Z ;[44C6]
RST $20 ;[44C7]
DB ',' ;[44C8]
INC HL ;[44C9]
INC DE ;[44CA]
RST $10 ;[44CB]
JR IPRD1 ;[44CC]
;
; Input syntax for SSAVE, SLOAD
;
ISSV:
CALL TEST_IS_COMMA ;[44CE] expression + ','
RST $10 ;[44D1] get char after ','
JP ILOAD ;[44D2] rest like LOAD
;
; Write into software file. (EXT STORE)
;
EPWR:
CALL WROPEN ;[44D5]
EPWR1:
PUSH BC ;[44D8]
PUSH HL ;[44D9]
LD A,(DE) ;[44DA] byte after ','
CP SOP ;[44DB] start of Polish?
JR NZ,EPWR4 ;[44DD]
RST 40 ;[44DF] number into WRA1
POP HL ;[44E0]
POP BC ;[44E1]
PUSH DE ;[44E2]
CALL WRADV ;[44E3]
LD (HL),$40 ;[44E6] means f.p.
LD IX,SYSVAR_WRA1 ;[44E8]
LD E,$05 ;[44EC]
EPWR2:
CALL WRADV ;[44EE]
LD A,(IX+0) ;[44F1] byte of number
INC IX ;[44F4]
LD (HL),A ;[44F6] into file
DEC E ;[44F7]
JR NZ,EPWR2 ;[44F8]
POP DE ;[44FA]
JR EPWR7 ;[44FB]
EPWR4:
CALL STRING_EXEC ;[44FD] String expr.
POP HL ;[4500]
POP BC ;[4501]
PUSH DE ;[4502]
CALL WRADV ;[4503]
PUSH HL ;[4506] addr for control byte
LD E,$80 ;[4507] init byte
LD IX,SYSVAR_STRBUF ;[4509] point to answer
EPWR5:
LD A,(IX+0) ;[450D]
CP SZ ;[4510]
JR Z,EPWR6 ;[4512]
INC IX ;[4514]
CALL WRADV ;[4516]
LD (HL),A ;[4519]
INC E ;[451A] incr control count
JR EPWR5 ;[451B]
EPWR6:
POP IX ;[451D] was HL
LD (IX+0),E ;[451F] control byte first
POP DE ;[4522]
EPWR7:
LD A,(DE) ;[4523]
INC DE ;[4524]
CP ',' ;[4525] another arg?
JR Z,EPWR1 ;[4527]
JP EIST9 ;[4529]
;
; Execute ISTORE
;
EIST:
CALL WROPEN ;[452C]
EIST1:
PUSH BC ;[452F]
PUSH HL ;[4530]
LD A,(DE) ;[4531]
CP SOP ;[4532] Start of polish
CALL NZ,ERR_TYPE_MISMATCH ;[4534] numeric only
RST 40 ;[4537] no. to WRA1
POP HL ;[4538]
POP BC ;[4539]
;
PUSH DE ;[453A]
PUSH BC ;[453B]
PUSH HL ;[453C]
CALL FPINT ;[453D] Float to int
EX DE,HL ;[4540] no. to DE
POP HL ;[4541]
POP BC ;[4542]
LD A,$0F ;[4543] fits half byte?
CP D ;[4545]
JR NC,EIST2 ;[4546]
CALL WRADV ;[4548]
LD (HL),$20 ;[454B]
JR EIST4 ;[454D]
EIST2:
INC D ;[454F]
DEC D ;[4550]
JR NZ,EIST3 ;[4551]
CP E ;[4553]
JR NC,EIST5 ;[4554]
EIST3:
SET 4,D ;[4556]
EIST4:
CALL WRADV ;[4558]
LD (HL),D ;[455B]
EIST5:
CALL WRADV ;[455C]
LD (HL),E ;[455F]
POP DE ;[4560]
LD A,(DE) ;[4561]
INC DE ;[4562]
CP ',' ;[4563] another arg?
JR Z,EIST1 ;[4565]
EIST9:
LD (KWRPTR),HL ;[4567] update file info
LD (KFILEN),BC ;[456A]
CALL DETACH ;[456E]
CALL PUTINF ;[4571]
RET ;[4574]
;
; Open software file.
;
WROPEN:
CALL GETINF ;[4575]
CALL ATTACH ;[4578]
CALL Z,ERR_OUT_OF_MEM ;[457B]
LD HL,(KWRPTR) ;[457E]
LD BC,(KFILEN) ;[4581]
RET ;[4585]
;
; Advance write pointer, inc count
;
WRADV:
INC BC ;[4586]
INC L ;[4587]
RET NZ ;[4588]
PUSH AF ;[4589]
CALL LAHL ;[458A]
CP PZ ;[458D]
CALL Z,ERR_OUT_OF_MEM ;[458F]
LD H,A ;[4592]
INC L ;[4593]
POP AF ;[4594]
RET ;[4595]
;
EPRD:
CALL GETINF ;[4596] get file info
LD HL,(KRDPTR) ;[4599] read-pointer
LD BC,(KWRPTR) ;[459C] last byte written
EPRD1:
PUSH BC ;[45A0]
PUSH HL ;[45A1]
CALL VPTR_IS_STR ;[45A2] addr of var into HL
PUSH HL ;[45A5]
POP IX ;[45A6]
POP HL ;[45A8] file info
POP BC ;[45A9]
JR C,EPRD2 ;[45AA] C set if string
CALL RNUM ;[45AC] use RAM routines
JR EPRD3 ;[45AF]
EPRD2:
CALL RSTR ;[45B1]
EPRD3:
LD A,(DE) ;[45B4] look at terminator
INC DE ;[45B5]
CP ',' ;[45B6]
JR Z,EPRD1 ;[45B8] repeat if more args