build.gradle

buildscript {
    repositories {
        jcenter()
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }
    dependencies {
        classpath 'org.kt3k.gradle.plugin:coveralls-gradle-plugin:2.0.1'
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.2'
        //classpath "com.gradle.publish:plugin-publish-plugin:0.9.0"
    }
}

group = 'io.github.robwin'
version = '0.9.2'
description = 'A Swagger to Markup (AsciiDoc and Markdown) converter Maven Plugin.'

apply plugin: 'groovy'
apply plugin: 'maven-publish'
apply plugin: 'jacoco'
apply plugin: 'com.github.kt3k.coveralls'
apply plugin: 'com.jfrog.bintray'
apply from: 'gradle/publishing.gradle'
//apply plugin: 'java-gradle-plugin'
//apply plugin: "com.gradle.plugin-publish"

sourceCompatibility = 1.7
targetCompatibility = 1.7

tasks.withType(GroovyCompile) {
    sourceCompatibility = "1.7"
    targetCompatibility = "1.7"
    options.deprecation = true
    options.encoding = 'UTF-8'
    options.compilerArgs << "-Xlint:unchecked"
}

repositories {
    jcenter()
    mavenCentral()
    mavenLocal()
}

dependencies {
    compile 'io.github.robwin:swagger2markup:0.9.2'
    compile 'org.apache.maven:maven-plugin-api:3.3.3'
    compile 'org.apache.maven.plugin-tools:maven-plugin-annotations:3.4'
    testCompile 'junit:junit:4.12'
    testCompile 'ch.qos.logback:logback-classic:1.1.3'
    testCompile 'org.assertj:assertj-core:2.1.0'
    testCompile 'org.mockito:mockito-core:1.10.19'
}


task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

task pluginDescriptor(type: Exec) {
    commandLine 'mvn', '-e', '-B', 'install', 'org.apache.maven.plugins:maven-plugin-plugin:3.4:descriptor', '-DskipTests'
}

jacocoTestReport {
    reports {
        xml.enabled = true // coveralls plugin depends on xml format report
        html.enabled = true
    }
}

tasks.coveralls {
    dependsOn 'check'
}

artifacts {
    archives sourcesJar
    archives javadocJar
}

task wrapper(type: Wrapper) {
    gradleVersion = '2.8'
}