-
Notifications
You must be signed in to change notification settings - Fork 1
/
RunningCouplings.wl
3670 lines (2610 loc) · 99.8 KB
/
RunningCouplings.wl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(* ::Package:: *)
(* ::Title:: *)
(*RunningCouplings package*)
(* ::Subsubsection:: *)
(*metadata*)
(* : Title : RunningCouplings *)
(* : Author : Andrew Miller < amiller@physics.umn.edu > *)
(* : Context : RunningCouplings` *)
(* : Version : 0.1.01 *)
(* : Date : 2020-09-20 *)
(* : Mathematica Version : 12.0 *)
(* : Copyright : (c) 2020 Andrew Miller *)
(* ::Title::GrayLevel[0]:: *)
(*context RunningCouplings`*)
(* ::Subsubsection::GrayLevel[0]::Closed:: *)
(*begin package context*)
BeginPackage["RunningCouplings`"];
(* ::Section:: *)
(*usage messages*)
(* ::Subsection::Closed:: *)
(*configuration*)
ConfigureRunningCouplings::usage = "ConfigureRunningCouplings [\!\(\*SubscriptBox[\(name\), \(1\)]\) \[Rule] \!\(\*SubscriptBox[\(value\), \(1\)]\), \!\(\*SubscriptBox[\(name\), \(2\)]\) \[Rule] \!\(\*SubscriptBox[\(value\), \(2\)]\), \[Ellipsis]] sets the configuration options for RunningCouplings and stores them persistantly.
ConfigureRunningCouplings[] returns the current configuration.";
(* ::Subsection::Closed:: *)
(*utilities*)
TakagiFactorization::usage = "TakagiFactorization[m] gives the Takagi factorization for a numerical symmetric matrix m as a list of matrices {u, d, e}, where d is a diagonal matrix, m can be written as u.d.Transpose[u], and e is a matrix of residuals."
ComplexAround::usage = "ComplexAround[x, \[Delta]] attempts to extend the functionality of Around to numeric complex numbers. It has the same behaviors as Around."
(* ::Subsection::Closed:: *)
(*SMDR interface*)
BuildSMDR::usage = "BuildSMDR[opts] attempts to build the included SMDR package.";
SMDRCalcFit::usage = "SMDRCalcFit[opts] runs the SMDR function calc_fit.
SMDRCalcFit[args, opts] runs calc_fit for the association of input values args.";
SMDRCalcRGrun::usage = "SMDRCalcRGrun[q, opts] runs the SMDR function calc_RGrun to the RG scale q.
SMDRCalcFit[q, args, opts] runs calc_RGrun for the association of input values args.";
(* ::Subsection::Closed:: *)
(*mixing*)
MixingMatrix::usage = "MixingMatrix[\"name\", params, opts] calculates the mixing matrix \"name\" from the list of parameters params.
MixingMatrix[\"name\", params] calculates the matrix from the association of parameters params.
MixingMatrix[\"name\", {\!\(\*SubscriptBox[\(m\), \(1\)]\), \!\(\*SubscriptBox[\(m\), \(2\)]\)}, opts] calculates matrix from the Yukawa or mass matrices \!\(\*SubscriptBox[\(m\), \(1\)]\) and \!\(\*SubscriptBox[\(m\), \(2\)]\).";
MixingParameters::usage = "MixingParameters[\"name\", m, opts] calculates the parameters of mixing matrix \"name\" from the matrix m.
MixingParameters[\"name\", {\!\(\*SubscriptBox[\(m\), \(1\)]\), \!\(\*SubscriptBox[\(m\), \(2\)]\)}, opts] calculates the parameters from the Yukawa or mass matrices \!\(\*SubscriptBox[\(m\), \(1\)]\) and \!\(\*SubscriptBox[\(m\), \(2\)]\).
MixingParameters[\"name\", params, \"Parametrization\" \[Rule] \"para\"] calculates the parameters in the parametrization \"para\" from the association of parameters params.";
(* ::Subsection::Closed:: *)
(*renormalization*)
RenormalizeModel::usage = "RenormalizeModel[{\"model\", \"method\"}, q, params] runs the method \"method\" to renormalize the parameters params of the model \"model\" to the scale q.";
(* ::Subsection::Closed:: *)
(*RunningCouplings*)
RunningCouplings::usage = "RunningCouplings[\"model\", q, opts] calculates the running couplings in model \"model\" at the scale q using options opts.";
(* ::Subsection::Closed:: *)
(*running quantities*)
RunningGaugeCoupling::usage = "RunningGaugeCoupling[{\"model\", i}, q, opts] gives the \!\(\*SuperscriptBox[\(i\), \(th\)]\) gauge coupling at the scale q in the model \"model\".";
RunningYukawaCoupling::usage = "RunningYukawaCoupling[{\"model\", \"family\"}, q, opts] gives the Yukawa couplings for the family \"family\" at the scale q in the model \"model\".
YukawaCoupling[{\"model\", \"family\", i}, q, opts] gives the Yukawa coupling for the \!\(\*SuperscriptBox[\(i\), \(th\)]\) generation.
YukawaCoupling[{\"model\", \"name\"}, q, opts] gives the Yukawa coupling the fermion \"name\".";
RunningWeinbergOperator::usage = "RunningWeinbergOperator[\"model\", q, opts] gives the neutrino Weinberg operators at the scale q in the model \"model\".
RunningWeinbergOperator[{\"model\", i}, q, opts] gives the operator for the \!\(\*SuperscriptBox[\(i\), \(th\)]\) generation.";
RunningMixingParameter::usage = "RunningMixingParameters[{\"model\", \"matrix\"}, q, opts] gives the parameters of the mixing matrix \"matrix\" at the scale q in the model \"model\".
RunningMixingParameters[{\"model\", \"matrix\", \"param\"}, q, opts] gives the parameter \"param\".";
(* ::Section:: *)
(*package information*)
(* ::Subsubsection::Closed:: *)
(*general*)
`Developer`$Version = "0.1.0 (01 August 2019)";
`Developer`$VersionNumber = StringReplace[`Developer`$Version, "." ~~ Except["."] .. ~~ EndOfString :> ""];
`Developer`$ReleaseNumber = StringSplit[`Developer`$Version, {" ", "."}][[3]];
`Developer`$CreationDate := DateObject @ Last @ StringSplit[`Developer`$Version, {"(", ")"}]
`Developer`$PackageDirectory = DirectoryName @ $InputFileName;
(* ::Subsubsection::Closed:: *)
(*SMDR*)
`SMDR`$BaseDirectory = FileNameJoin @ {`Developer`$PackageDirectory, "smdr"};
`SMDR`$Version = StringDelete[Last @ Sort[StringCases[FileNames[All, `SMDR`$BaseDirectory], "smdr-" ~~ __] // Flatten], "smdr-"];
`SMDR`$SourceDirectory = FileNameJoin @ {`SMDR`$BaseDirectory, "smdr-" <> `SMDR`$Version};
`SMDR`$ExecutableDirectory = FileNameJoin @ {`SMDR`$SourceDirectory, "bin"};
`SMDR`$IncludeDirectory = FileNameJoin @ {`SMDR`$SourceDirectory, "include"};
`SMDR`$LibraryDirectory = FileNameJoin @ {`SMDR`$SourceDirectory, "lib"};
(* ::Chapter:: *)
(*context RunningCouplings`Private`*)
(* ::Subsubsection::GrayLevel[0]::Closed:: *)
(*begin private context*)
Begin @ "`Private`";
(* ::Subsubsection::GrayLevel[0]::Closed:: *)
(*imports*)
Needs @ "DifferentialEquations`InterpolatingFunctionAnatomy`"
Needs @ "JLink`"
(* ::Section:: *)
(*configuration settings*)
(* ::Subsection::Closed:: *)
(*configuration file*)
RunningCouplings`Config`$ConfigDirectory = If[
SameQ[ParentDirectory @ RunningCouplings`Developer`$PackageDirectory, FileNameJoin @ {$UserBaseDirectory, "Applications"}],
FileNameJoin @ {$UserBaseDirectory, "ApplicationData", FileNameTake @ RunningCouplings`Developer`$PackageDirectory},
RunningCouplings`Developer`$PackageDirectory
];
RunningCouplings`Config`$ConfigFile = FileNameJoin @ {RunningCouplings`Config`$ConfigDirectory, "config.m"};
(* ::Subsection::Closed:: *)
(*configuration options*)
$configDefault = Association[
"SMDRExecutableDirectory" :> RunningCouplings`SMDR`$ExecutableDirectory,
"NumericTolerance" -> 10^(-24),
"DoubletSingularVectors" -> Right
];
$configAlternatives = Association[
"SMDRExecutableDirectory" -> _String | _File,
"NumericTolerance" -> _Integer,
"DoubletSingularVectors" -> Left | "Left" | Right | "Right"
];
(* ::Subsection:: *)
(*configuration API*)
(* ::Subsubsection::Closed:: *)
(*ConfigureRunningCouplings*)
ConfigureRunningCouplings::optx = "Unknown configuration option ``.";
ConfigureRunningCouplings::valng = "Value of configuration option `1` is not one of `2`.";
SyntaxInformation @ ConfigureRunningCouplings = {"ArgumentsPattern" -> {OptionsPattern[]}, "OptionNames" -> Keys @ $configDefault};
ConfigureRunningCouplings[rules__Rule] := (
iConfigureRunningCouplings[rules];
Export[RunningCouplings`Config`$ConfigFile, RunningCouplings`Config`$Config, "Package"];
Normal @ RunningCouplings`Config`$Config
)
ConfigureRunningCouplings[] := Normal @ RunningCouplings`Config`$Config
(* ::Subsubsection::Closed:: *)
(*iConfigureRunningCouplings*)
iConfigureRunningCouplings[] := Module[
{goodopts, badopts},
goodopts = KeyTake[RunningCouplings`Config`$Config, Keys @ $configDefault];
badopts = KeyDrop[RunningCouplings`Config`$Config, Keys @ $configDefault];
Scan[Message[ConfigureRunningCouplings::optx, First @ #] &, Normal @ badopts];
KeyValueMap[
If[!MatchQ[#2, $configAlternatives @ #1],
Message[ConfigureRunningCouplings::valng, #1 -> #2, TextString[List @@ $configAlternatives @ #1]];
KeyDropFrom[goodopts, #1]
] &,
goodopts
];
RunningCouplings`Config`$Config = Join[$configDefault, goodopts]
]
iConfigureRunningCouplings[rules__Rule] := Module[
{goodopts, badopts},
goodopts = KeyTake[<|rules|>, Keys @ $configDefault];
badopts = KeyDrop[<|rules|>, Keys @ $configDefault];
Scan[Message[ConfigureRunningCouplings::optx, First @ #] &, Normal @ badopts];
KeyValueMap[
If[!MatchQ[#2, $configAlternatives @ #1],
Message[ConfigureRunningCouplings::valng, #1 -> #2, TextString[List @@ $configAlternatives @ #1]];
KeyDropFrom[goodopts, #1]
] &,
goodopts
];
AppendTo[RunningCouplings`Config`$Config, goodopts]
]
(* ::Subsection::Closed:: *)
(*initial setting*)
If[
FileExistsQ @ RunningCouplings`Config`$ConfigFile,
RunningCouplings`Config`$Config = Normal @ Import[RunningCouplings`Config`$ConfigFile, "Package"],
RunningCouplings`Config`$Config = $configDefault
];
(* ::Subsection::Closed:: *)
(*aliases*)
$config := RunningCouplings`Config`$Config
$smdrExecutableDirectory := $config @ "SMDRExecutableDirectory"
$context = Context[];
(* ::Section:: *)
(*utilities*)
(* ::Subsubsection::Closed:: *)
(*relativeFilePath*)
InstallJava[];
relativeFilePath[base_String, target_String] := JavaBlock[
With[
{
basepath = JavaNew["java.io.File", base],
targetpath = JavaNew["java.io.File", target]
},
basepath @ toPath[] @ relativize[targetpath @ toPath[]] @ toString[]
]
]
(* ::Subsubsection::Closed:: *)
(*fortranNumberString*)
fortranNumberString = NumberString ~~ ((("e" | "E") ~~ ("+" | "-" | "") ~~ DigitCharacter ..) | "")
(* ::Subsubsection::Closed:: *)
(*toPreciseNumber*)
toPreciseNumber[s_String] := SetPrecision[
Interpreter["Number"][s],
StringLength @ StringDelete[s, {"-", StartOfString ~~ "0." ~~ ("0" ...), ".", "e" ~~ __ ~~ EndOfString}, IgnoreCase -> True]
]
toPreciseNumber[n : (_Real | _Integer), ref_Real] := SetPrecision[
n,
Length[RealDigits[ref][[1]]] + RealDigits[n][[2]] - RealDigits[ref][[2]]
]
toPreciseNumber[n_, ref_] := n
(* ::Subsubsection::Closed:: *)
(*toRoundedNumber*)
SetAttributes[toRoundedNumber, Listable];
toRoundedNumber[i_Integer] := i
toRoundedNumber[n_Real] := With[
{digits = Length @ #1 - #2 & @@ (RealDigits @ n)},
Round[n, 10^(-digits)]
]
toRoundedNumber[s_String] := With[
{digits = Total[StringCases[s, {"." ~~ val : DigitCharacter .. :> - StringLength[val], "e" ~~ val : ( ("+" | "-") ~~ DigitCharacter .. ) ~~ EndOfString :> ToExpression @ val}] // Flatten]},
Round[ToExpression @ s, 10^digits]
]
(* ::Subsubsection::Closed:: *)
(*roundTo*)
roundTo[n_? NumericQ, ref_? NumericQ] := With[
{digits = Length @ #1 - #2 & @@ (RealDigits @ ref)},
Round[n, 10.^(-digits)]
]
(* ::Subsubsection::Closed:: *)
(*numericMatrixQ*)
numericMatrixQ = MatrixQ[#, NumericQ] &
(* ::Subsubsection::Closed:: *)
(*numericSymmetricMatrixQ*)
Options @ numericSymmetricMatrixQ = Options @ SymmetricMatrixQ;
numericSymmetricMatrixQ[m_, opts : OptionsPattern[]] := And[MatrixQ[m, NumericQ], SymmetricMatrixQ[m, opts]]
(* ::Subsubsection::Closed:: *)
(*orderColumns*)
orderColumns[m_? MatrixQ, Reverse] := Transpose[Reverse @ Transpose[m]]
orderColumns[m_? MatrixQ, order_List] /; ContainsExactly[order, Range[Length @ m]] := Transpose[Transpose[m][[order]]]
(* ::Subsubsection::Closed:: *)
(*flattenAssociation*)
flattenAssociation[a_Association] := Association[
Normal[a] //. (k_ -> v_Association) :> Normal[KeyMap[Append[{k}, #] &, v]]
]
(* ::Subsubsection::Closed:: *)
(*nestedMerge*)
nestedMerge[a : {__Association}] := Merge[a, nestedMerge]
nestedMerge[a_] := Last @ a
(* ::Subsubsection::Closed:: *)
(*nestAssociation*)
nestAssociation[a_Association] := nestedMerge[
KeyValueMap[
Association[
ReplaceAll[
#1,
{
{k1_, k2_} :> (k1 -> <|k2 -> #2|>),
{k1_, k2_, k3__} :> (k1 -> <|{k2, k3} -> #2|>),
{k_} :> (k -> #2),
_ :> (#1 -> #2)
}
]
] &,
a
]
]
(* ::Subsubsection::Closed:: *)
(*aroundMod*)
aroundMod[Around[v_, u_], n_, d_:0] := Around[Mod[v, n, d], u]
aroundMod[m_, n_, d_:0] := Mod[m, n, d]
(* ::Subsubsection::Closed:: *)
(*TakagiFactorization*)
Options @ TakagiFactorization = Options @ SingularValueDecomposition;
SyntaxInformation @ TakagiFactorization = {"ArgumentsPattern" -> {_, OptionsPattern[]}, "OptionNames" -> Keys @ Options @ TakagiFactorization};
TakagiFactorization::symx = "Warning: matrix `1` is not symmetric within numeric precision.";
(* algorithm following https://mathoverflow.net/questions/125960/diagonalizing-a-complex-symmetric-matrix *)
TakagiFactorization[
m_? numericMatrixQ,
opts : OptionsPattern[]
] := With[
{svd = SingularValueDecomposition[N @ m, opts]},
If[! SymmetricMatrixQ @ m, Message[TakagiFactorization::symx, m]];
With[
{d = ConjugateTranspose[svd[[1]]].N[m].Conjugate[svd[[1]]]},
With[
{v = svd[[1]].DiagonalMatrix[Exp[I Diagonal[Arg @ d] / 2]]},
{v, svd[[2]], Abs[m - v.svd[[2]].Transpose[v]]}
]
]
]
(* ::Subsubsection:: *)
(*ComplexAround*)
(* ::Subsubsubsection::Closed:: *)
(*info*)
SyntaxInformation @ ComplexAround = SyntaxInformation @ Around;
(* ::Subsubsubsection::Closed:: *)
(*single argument*)
ComplexAround[v_] := v
(* ::Subsubsubsection::Closed:: *)
(*real case*)
ComplexAround[
v_? NumericQ /; Im[v] == 0,
u : (_? NumericQ | {_? NumericQ, _? NumericQ}) /; AllTrue[{u} // Flatten, Im[#] == 0 &]
] := Around[Re @ v, Re @ u]
(* ::Subsubsubsection::Closed:: *)
(*properties*)
ComplexAround[
v_? NumericQ,
(_? NumericQ | {_? NumericQ, _? NumericQ})
]["Value"] := v
ComplexAround[
_? NumericQ,
u : (_? NumericQ | {_? NumericQ, _? NumericQ})
]["Uncertainty"] := u
(* ::Subsubsubsection::Closed:: *)
(*complex number behaviors*)
ComplexAround[
v_? NumericQ,
u_? NumericQ
] /; Im[u] < 0 := ComplexAround[v, Conjugate @ u]
ComplexAround[
v_? NumericQ,
u : {_? NumericQ, _? NumericQ}
] /; AnyTrue[Im[u], Negative] := ComplexAround[v, u /. c_Complex /; Im[c] < 0 :> Conjugate @ c]
ComplexAround /: func_[ComplexAround[v_? NumericQ, u : (_? NumericQ | {_? NumericQ, _? NumericQ})]] /; MatchQ[func, (Re | Im)] := Around[func @ v, func @ u]
ComplexAround /: Conjugate[ComplexAround[v_? NumericQ, u : (_? NumericQ | {_? NumericQ, _? NumericQ})]] := ComplexAround[Conjugate @ v, u]
ComplexAround /: Abs[c : ComplexAround[_? NumericQ, (_? NumericQ | {_? NumericQ, _? NumericQ})]] := Sqrt[Re[c]^2 + Im[c]^2]
ComplexAround /: Arg[c : ComplexAround[_? NumericQ, (_? NumericQ | {_? NumericQ, _? NumericQ})]] := With[
{
atan = Piecewise[
{
{ArcTan[#1 / #2], #2["Value"] > 0},
{ArcTan[#1 / #2] + \[Pi], And[#2["Value"] < 0, #1["Value"] >= 0]},
{ArcTan[#1 / #2] - \[Pi], And[#2["Value"] < 0, #1["Value"] < 0]},
{\[Pi] / 2, And[#2["Value"] == 0, #1["Value"] > 0]},
{-\[Pi] / 2, And[#2["Value"] == 0, #1["Value"] < 0]}
},
0
] &
},
atan[Im @ c, Re @ c]
]
(* ::Subsubsubsection::Closed:: *)
(*arithmetic operations*)
ComplexAround /: Plus[
x : (_? NumericQ | _Around | _ComplexAround),
y : ComplexAround[_, _]
] := With[
{
re = Re @ x + Re @ y,
im = Im @ x + Im @ y
},
ComplexAround[
Replace[re, a_Around :> a @ "Value"] + I Replace[im, a_Around :> a @ "Value"],
Replace[re, {a_Around :> a @ "Uncertainty", _? NumericQ :> 0.0}] + I Replace[im, {a_Around :> a @ "Uncertainty", _? NumericQ :> 0.0}]
]
]
ComplexAround /: Times[
x : (_? NumericQ | _Around | _ComplexAround),
y : ComplexAround[_, _]
] := With[
{
re = (Re[x] Re[y] - Im[x] Im[y]),
im = (Im[x] Re[y] + Re[x] Im[y])
},
ComplexAround[
Replace[re, a_Around :> a @ "Value"] + I Replace[im, a_Around :> a @ "Value"],
Replace[re, {a_Around :> a @ "Uncertainty", _? NumericQ :> 0.0}] + I Replace[im, {a_Around :> a @ "Uncertainty", _? NumericQ :> 0.0}]
]
]
ComplexAround /: Power[x_ComplexAround, y_] := With[
{
re = (Re[x]^2 + Im[x]^2)^(y / 2) Cos[y Arg[x]],
im = (Re[x]^2 + Im[x]^2)^(y / 2) Sin[y Arg[x]]
},
ComplexAround[
Replace[re, a_Around :> a @ "Value"] + I Replace[im, a_Around :> a @ "Value"],
Replace[re, {a_Around :> a @ "Uncertainty", _? NumericQ :> 0.0}] + I Replace[im, {a_Around :> a @ "Uncertainty", _? NumericQ :> 0.0}]
]
]
(* ::Subsubsubsection::Closed:: *)
(*boxes*)
ComplexAround /: MakeBoxes[
c : ComplexAround[_? NumericQ, (_? NumericQ | {_? NumericQ, _? NumericQ})],
form : (StandardForm | TraditionalForm)
] := With[
{
re = Replace[ToBoxes[Re @ c, form], InterpretationBox[t_TemplaceBox, _] :> t],
im = Replace[ToBoxes[Im @ c, form], InterpretationBox[t_TemplaceBox, _] :> t]
},
InterpretationBox[RowBox @ {re, "+", im, "\[ImaginaryI]"}, c]
]
(* ::Subsubsection::Closed:: *)
(*NAroundReplace*)
Options @ NAroundReplace = {"UncertaintyFunction" -> Automatic};
SyntaxInformation @ NAroundReplace = {"ArgumentsPattern" -> {_, {__}, OptionsPattern[]}, "OptionNames" -> Keys @ Options @ NAroundReplace};
NAroundReplace[expr_, rules : {__Rule}, opts : OptionsPattern[]] := With[
{
values = rules /. a_Around :> a @ "Value",
keys = Cases[rules, ((k_ -> _Around) | (k_ :> _Around)) :> k],
ufunc = OptionValue @ "UncertaintyFunction" /. Automatic -> (Sqrt[{Total[Select[#, Negative]^2], Total[Select[#, Positive]^2]}] &)
},
With[
{
centralvalue = expr /. values,
uncertainty = Flatten[
Map[
{
expr /. <|values, # -> Min[Lookup[rules, #]["Interval"]]|>,
expr /. <|values, # -> Max[Lookup[rules, #]["Interval"]]|>
} &,
keys
],
1
]
},
If[
Length @ uncertainty > 0,
If[
NumericQ @ centralvalue,
ComplexAround[
centralvalue,
(ufunc[Re @ uncertainty - Re @ centralvalue] /. {x_, y_} /; x == y :> x)
+ (ufunc[Im @ uncertainty - Im @ centralvalue] /. {x_, y_} /; x == y :> x) I
],
ReplacePart[
centralvalue,
Map[
With[
{v = Extract[centralvalue, #]},
# -> ComplexAround[
v,
(ufunc[Re @ uncertainty[[All, Sequence @@ #]] - Re @ v] /. {x_, y_} /; x == y :> x)
+ (ufunc[Im @ uncertainty[[All, Sequence @@ #]] - Im @ v] /. {x_, y_} /; x == y :> x) I
]
] &,
Flatten[Position[centralvalue, #] & /@ DeleteDuplicates[Cases[centralvalue, _? NumericQ, \[Infinity]]], 1]
]
]
],
centralvalue
]
]
]
(* ::Subsubsection::Closed:: *)
(*NAroundApply*)
Options @ NAroundApply = {"UncertaintyFunction" -> Automatic};
SyntaxInformation @ NAroundApply = {"ArgumentsPattern" -> {_, {__}, OptionsPattern[]}, "OptionNames" -> Keys @ Options @ NAroundApply};
NAroundApply[func_, args_List, opts : OptionsPattern[]] := With[
{
rules = AssociationThread[Range[Length @ args] -> args],
keys = Position[args, _Around, 1] // Flatten,
values = (# /. a_Around :> a @ "Value") &,
ufunc = OptionValue @ "UncertaintyFunction" /. Automatic -> (Sqrt[{Total[Select[#, Negative]^2], Total[Select[#, Positive]^2]}] &)
},
With[
{
centralvalue = func @@ (values @ args),
uncertainty = Flatten[
Map[
{
func @@ Values[<|values @ rules, # -> Min[Lookup[rules, #]["Interval"]]|>],
func @@ Values[<|values @ rules, # -> Max[Lookup[rules, #]["Interval"]]|>]
} &,
keys
],
1
]
},
If[
Length @ uncertainty > 0,
If[
NumericQ @ centralvalue,
ComplexAround[
centralvalue,
(ufunc[Re @ uncertainty - Re @ centralvalue] /. {x_, y_} /; x == y :> x)
+ (ufunc[Im @ uncertainty - Im @ centralvalue] /. {x_, y_} /; x == y :> x) I
],
ReplacePart[
centralvalue,
Map[
With[
{v = Extract[centralvalue, #]},
# -> ComplexAround[
v,
(ufunc[Re @ uncertainty[[All, Sequence @@ #]] - Re @ v] /. {x_, y_} /; x == y :> x)
+ (ufunc[Im @ uncertainty[[All, Sequence @@ #]] - Im @ v] /. {x_, y_} /; x == y :> x) I
]
] &,
Flatten[Position[centralvalue, #] & /@ DeleteDuplicates[Cases[centralvalue, _? NumericQ, \[Infinity]]], 1]
]
]
],
centralvalue
]
]
]
(* ::Subsubsection::Closed:: *)
(*ComplexAroundReplace*)
SyntaxInformation @ ComplexAroundReplace = {"ArgumentsPattern" -> {_, _}};
ComplexAroundReplace[
expr_,
rules : {__Rule}
] := With[
{
re = (Re[expr] // ComplexExpand) /. rules,
im = (Im[expr] // ComplexExpand) /. rules
},
If[
And[MatchQ[re, (_Around | _? NumericQ)], MatchQ[im, (_Around | _? NumericQ)]],
ComplexAround[
Replace[re, a_Around :> a @ "Value"] + I Replace[im, a_Around :> a @ "Value"],
Replace[re, {a_Around :> a @ "Uncertainty", _? NumericQ :> 0.0}] + I Replace[im, {a_Around :> a @ "Uncertainty", _? NumericQ :> 0.0}]
],
ReplacePart[
re,
Map[
With[
{
r = Extract[re, #],
i = Extract[im, #]
},
# -> ComplexAround[
Replace[r, a_Around :> a @ "Value"] + I Replace[i, a_Around :> a @ "Value"],
Replace[r, {a_Around :> a @ "Uncertainty", _? NumericQ :> 0.0}] + I Replace[i, {a_Around :> a @ "Uncertainty", _? NumericQ :> 0.0}]
]
] &,
Union[
Flatten[Position[re, #] & /@ DeleteDuplicates[Cases[re, _Around, \[Infinity]]], 1],
Flatten[Position[im, #] & /@ DeleteDuplicates[Cases[im, _Around, \[Infinity]]], 1]
]
]
]
]
]
(* ::Section:: *)
(*SMDR interface*)
(* ::Subsection:: *)
(*compile SMDR*)
(* ::Subsubsection::Closed:: *)
(*getCCompiler*)
getCCompiler[] := StringCases[
FindList[FileNameJoin @ {RunningCouplings`SMDR`$SourceDirectory, "Makefile"}, "CC"],
StartOfString ~~ (WhitespaceCharacter ...) ~~ "CC" ~~ (WhitespaceCharacter ...) ~~ "=" ~~ c__ :> StringTrim @ c
] // Flatten // First
(* ::Subsubsection::Closed:: *)
(*getCCompilerFlags*)
getCCompilerFlags[compiler_] := Module[{makefile, flags},
makefile = OpenRead[FileNameJoin @ {RunningCouplings`SMDR`$SourceDirectory, "Makefile"}];
Find[makefile, compiler];
flags = ReadLine @ makefile;
flags = If[
StringQ @ flags,
StringCases[flags, StartOfString ~~ (WhitespaceCharacter ...) ~~ "SMDR_OPT" ~~ (WhitespaceCharacter ...) ~~ "=" ~~ f : (Except["#"] ...) :> StringTrim @ f] // First,
""
];
Close @ makefile;
If[
StringContainsQ[flags, Whitespace],
"\"" <> flags <> "\"",
flags
]
]
(* ::Subsubsection:: *)
(*BuildSMDR*)
(* ::Subsubsubsection::Closed:: *)
(*iBuildSMDR*)
Options @ iBuildSMDR = {
"ArchiveCommand" -> Automatic,
"CCompiler" -> Automatic,
"CCompilerFlags" -> Automatic,
"MakePath" -> Automatic
};
BuildSMDR::makex = "SMDR compilation failed. Error in make call."
BuildSMDR::compx = "SMDR compilation failed. Please run BuildSMDR with adjusted options or specify the configuration option \"SMDRExecutableDirectory\"."
mem : iBuildSMDR[opts : OptionsPattern[]] := Monitor[
Module[
{make},
With[
{
ccompiler = OptionValue @ "CCompiler" /. Automatic :> getCCompiler[],
makepath = OptionValue @ "MakePath"
},
With[
{
ccompilerflags = OptionValue @ "CCompilerFlags" /. Automatic :> getCCompilerFlags @ ccompiler,
ar = OptionValue @ "ArchiveCommand"
},
make = Check[
RunProcess[
{
If[StringQ @ makepath, FileNameJoin @ {makepath, "make"}, "make"],
"-C",
RunningCouplings`SMDR`$SourceDirectory,
"CC=" <> ccompiler,
"SMDR_OPT=" <> ccompilerflags,
If[StringQ @ ar, "AR=" <> ar, Nothing]
}
],
Failure[
"CompilationError",
Association[
"Message" -> BuildSMDR::makex,
"CCompiler" -> ccompiler,
"CCompilerFlags" -> ccompilerflags,
"ArchiveCommand" -> ar,
"MakeCommand" -> StringRiffle[_
{
If[StringQ @ makepath, FileNameJoin @ {makepath, "make"}, "make"],
"-C",
RunningCouplings`SMDR`$SourceDirectory,
"CC=" <> ccompiler,
"SMDR_OPT=" <> ccompilerflags,
If[StringQ @ ar, "AR=" <> ar, Nothing]
}
]
]
] // Throw
];
If[
make @ "ExitCode" != 0,
RunProcess @ {"make", "-C", RunningCouplings`SMDR`$SourceDirectory, "clean"};
Failure[
"CompilationError",
Association[
"Message" -> BuildSMDR::compx,
"CCompiler" -> ccompiler,
"CCompilerFlags" -> ccompilerflags,
"ArchiveCommand" -> ar,
"MakeCommand" -> StringRiffle[
{
"make", "-C",
RunningCouplings`SMDR`$SourceDirectory,
"CC=" <> ccompiler,
"SMDR_OPT=" <> ccompilerflags,
If[StringQ @ ar, "AR=" <> ar, Nothing]
}
],
"StandardError" -> "\n" <> make @ "StandardError"
]
] // Throw
];