build.gradle

buildscript {
	repositories { jcenter() }

	dependencies {
		classpath "com.github.jruby-gradle:jruby-gradle-plugin:${jrubyVersion}"
		classpath "org.asciidoctor:asciidoctor-gradle-plugin:${asciidoctorGradleVersion}"
	}
}

apply plugin: "groovy"
apply plugin: 'maven-publish'
apply from: 'gradle/bash.gradle'
apply from: 'gradle/docs.gradle'

version = project.findProperty("newVersion") ?: project.findProperty("defaultVersion")

// Scripts docs generation

repositories {
	jcenter()
	// no https for rubgems :(
	maven { url "http://rubygems-proxy.torquebox.org/releases/" }
	maven { url "https://repo.spring.io/libs-snapshot-local" }
	maven { url "https://repo.spring.io/libs-milestone-local" }
	maven { url "https://repo.spring.io/libs-release-local" }
}

apply plugin: "com.github.jruby-gradle.base"
import com.github.jrubygradle.JRubyExec

dependencies {
	jrubyExec "rubygems:asciidoctor:1.5.8"

	compile "org.codehaus.groovy:groovy-all:${groovyVersion}"
	compile "io.cloudpipelines:project-crawler:${projectCrawlerVersion}"
	compile "com.fasterxml.jackson.core:jackson-core:${jacksonVersion}"
	compile "com.fasterxml.jackson.core:jackson-databind:${jacksonVersion}"
	compile "com.fasterxml.jackson.dataformat:jackson-dataformat-yaml:${jacksonVersion}"
}

jruby {
	defaultRepositories false
}

task generateScriptsReadme(type: JRubyExec) {
	script "${projectDir}/tools/coalesce-readme.rb"
	scriptArgs "-i ${projectDir}/src/tasks/BASH_SCRIPTS.adoc", "-o ${projectDir}/src/tasks/README.adoc"// don't run on CI
	enabled = !System.getenv("JENKINS_HOME")
}

generateDocs.dependsOn(generateScriptsReadme)
// Scripts docs generation

apply from: "gradle/custom.gradle"