-
Notifications
You must be signed in to change notification settings - Fork 1
/
flake.nix
180 lines (157 loc) · 5.45 KB
/
flake.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
{
description = "Phenix infrastructure";
nixConfig.allow-import-from-derivation = true; # Allowed due to nixpkgs patching.
nixConfig.extra-substituters = "https://cache.garnix.io";
nixConfig.extra-trusted-public-keys = "cache.garnix.io:CTFPyKSLcx5RMJKfLo5EEPUObbA78b0YQ2DTCJXqr9g=";
inputs = {
nixpkgs.url = "nixpkgs/bc571a7386d20d50f6a6a71c66598695237afacb";
nixpkgs-unstable.url = "nixpkgs/nixos-unstable";
systems.url = "github:nix-systems/default-linux";
# Extra packages
nix-minecraft.url = "github:Infinidoge/nix-minecraft";
nix-minecraft.inputs.nixpkgs.follows = "nixpkgs";
nix-minecraft.inputs.flake-utils.follows = "flake-utils";
# Secret management
sops-nix.url = "github:Mic92/sops-nix";
sops-nix.inputs.nixpkgs.follows = "nixpkgs";
sops-nix.inputs.nixpkgs-stable.follows = "nixpkgs";
# Formatting
pre-commit-hooks.url = "github:cachix/pre-commit-hooks.nix";
pre-commit-hooks.inputs.nixpkgs.follows = "nixpkgs";
pre-commit-hooks.inputs.nixpkgs-stable.follows = "nixpkgs";
pre-commit-hooks.inputs.flake-compat.follows = "flake-compat";
pre-commit-hooks.inputs.flake-utils.follows = "flake-utils";
treefmt-nix.url = "github:numtide/treefmt-nix";
treefmt-nix.inputs.nixpkgs.follows = "nixpkgs";
# Utils
devshell.url = "github:numtide/devshell";
devshell.inputs.nixpkgs.follows = "nixpkgs";
# Compatibility
flake-compat.url = "github:edolstra/flake-compat";
flake-compat.flake = false;
flake-utils.url = "github:numtide/flake-utils";
};
outputs = {
self,
nixpkgs,
nixpkgs-unstable,
systems,
nix-minecraft,
sops-nix,
pre-commit-hooks,
treefmt-nix,
devshell,
...
}: let
# Outputs a set of attrsets with each supported system architecture as keys.
# Inputs common `pkgs` and `system` attributes for use by the caller.
# This makes supporting multiple system-architectures easy.
eachSystem = f:
nixpkgs.lib.genAttrs (import systems) (system:
f {
inherit system;
pkgs = nixpkgs.legacyPackages.${system};
});
in {
# -- NixOS Configurations --
# Holds the set of our NixOS configured servers.
nixosConfigurations = {
nona = self.lib.mkSystem self {
system = "x86_64-linux";
overlays = [
nix-minecraft.overlay
self.overlays.packages
self.overlays.prometheus-systemd-exporter
];
modules = [
sops-nix.nixosModules.sops
./nixos/mixins/starship.nix
./nixos/hosts/nona
{
services.nextcloud.package = nixpkgs.lib.mkForce nixpkgs-unstable.legacyPackages."x86_64-linux".nextcloud27;
}
];
};
};
# -- NixOS Modules --
# Modules create or modify configurable options included in a full nixos configuration.
nixosModules = {
minecraft-server = import ./nixos/modules/minecraft-server.nix;
bad-python-server = import ./nixos/modules/bad-python-server.nix;
};
# -- Packages --
# Exposes derivations as top level packages so others can use them.
packages = eachSystem ({pkgs, ...}: import ./nixos/packages/top-level/all-packages.nix {inherit pkgs;});
# -- Library --
# Holds our various functions and derivations aiding in deploying nixos.
lib = import ./nixos/lib {inherit (nixpkgs) lib;};
# -- Overlays --
# Allows modification of nixpkgs in-place, adding and modifying its functionality.
overlays = {
packages = final: _prev: {
phenix =
final.lib.recurseIntoAttrs
(import ./nixos/packages/top-level/all-packages.nix {inherit (final) pkgs;});
};
prometheus-systemd-exporter = import ./nixos/overlays/prometheus-systemd-exporter.nix;
};
# -- Formatter --
# Abstracts all formatting tools into one command, `nix fmt <location>`.
formatter = eachSystem ({pkgs, ...}:
treefmt-nix.lib.mkWrapper pkgs {
projectRootFile = "flake.nix";
programs.alejandra.enable = true;
programs.deadnix.enable = true;
});
# -- Development Shells --
# Scoped environments including packages and shell-hooks to aid project development.
devShells = eachSystem ({
system,
pkgs,
}: {
default = devshell.legacyPackages.${system}.mkShell {
devshell = {
startup = {
motd = nixpkgs.lib.mkForce {text = "";};
pre-commit = {text = self.checks.${system}.pre-commit.shellHook;};
};
packages = with pkgs; [
nixUnstable
# Deployment
nixos-rebuild
# Secrets management
age
ssh-to-age
sops
# Formatters
alejandra
deadnix
];
};
};
});
# -- Tests --
# Verify locally that our nix configurations and file formatting is correct.
checks = eachSystem ({
system,
pkgs,
}: {
pre-commit = pre-commit-hooks.lib.${system}.run {
src = ./.;
excludes = ["-deps.nix$" "-composition.nix$" ".patch$"];
hooks = {
alejandra.enable = true;
deadnix.enable = true;
editorconfig-checker.enable = true;
codespell = {
enable = true;
name = "codespell";
language = "system";
entry = "${pkgs.codespell}/bin/codespell -L anull -- ";
types = ["text"];
};
};
};
});
};
}