build.gradle

plugins {
    id 'java'
    id 'application'
    id 'org.openjfx.javafxplugin' version '0.0.10'
    id 'org.beryx.jlink' version '2.25.0'
    id 'java-library'
}

group 'com.setrader'
version '1.4'

repositories {
    mavenCentral()
}

ext {
    junitVersion = '5.8.2'
}

sourceCompatibility = '17'
targetCompatibility = '17'

tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
}

application {
    mainModule = 'com.setrader.se_trader'
    mainClass = 'com.setrader.se_trader.Main'
}

javafx {
    version = '17.0.1'
    modules = ['javafx.controls', 'javafx.fxml']
}

dependencies {

    //implementation('org.controlsfx:controlsfx:11.1.1') in modules requires org.controlsfx.controls;
    /*
    implementation('com.dlsc.formsfx:formsfx-core:11.5.0') {
        exclude(group: 'org.openjfx')
    } requires com.dlsc.formsfx;*/
    implementation('org.kordamp.bootstrapfx:bootstrapfx-core:0.4.0')

    implementation 'com.google.code.gson:gson:2.9.0'
    implementation 'org.json:json:20220320'
    implementation 'com.google.code.gson:gson:2.9.0'
    implementation 'org.apache.logging.log4j:log4j-api:2.17.2'
    implementation 'org.apache.logging.log4j:log4j-core:2.17.2'
    implementation 'com.aparapi:aparapi:3.0.0'
    //implementation 'io.github.typhon0:AnimateFX:1.2.3'    // Animations JavaFX Error

    testImplementation("org.junit.jupiter:junit-jupiter-api:${junitVersion}")
    testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:${junitVersion}")

}

test {
    useJUnitPlatform()
}

jlink {
    imageZip = project.file("${buildDir}/distributions/app-${javafx.platform.classifier}.zip")
    options = ['--strip-debug','--compress', '2','--no-header-files','--no-man-pages']
    forceMerge('log4j-api')

    launcher {
        name = 'SE Trader'
    }
    jpackage {
        // Set the environment property BADASS_JLINK_JPACKAGE_HOME or explicitly configure the below property
        // jpackageHome = '/usr/lib/jvm/adoptopenjdk-14-openj9-amd64'
        //
        installerOptions += [
                '--app-version', version,
                '--copyright', 'Copyrigtht 2022 Tomas Sobota',
                '--vendor', 'Tomas Sobota',
                '--license-file', 'LICENSE'
        ]
        if (org.gradle.internal.os.OperatingSystem.current().windows) {
            imageOptions += ['--icon', 'src/main/resources/res/se_trader_logo.ico']
            installerOptions += ['--win-per-user-install',
                                 '--win-dir-chooser',
                                 '--win-menu',
                                 '--win-shortcut',]
        }
    }
}

jlinkZip {
    group = 'distribution'
}