build.gradle

buildscript {
    repositories {
        jcenter()
    }

    dependencies {
        classpath "org.ajoberstar:gradle-git:1.7.2"
    }
}

plugins {
    id 'groovy'
    id 'idea'
}

group = 'com.bmuschko'

defaultTasks 'clean', 'build'

apply from: "gradle/release.gradle"
apply from: "gradle/integration-test.gradle"
apply from: "gradle/functional-test.gradle"
apply from: "gradle/additional-artifacts.gradle"
apply from: "gradle/publishing.gradle"
apply from: "gradle/documentation.gradle"

task wrapper(type: Wrapper) {
    gradleVersion = '4.4.1'
}

tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
}

tasks.withType(GroovyCompile) {
    groovyOptions.encoding = 'UTF-8'
    options.encoding = 'UTF-8'
}

tasks.withType(Test) {
    if (project.hasProperty('rerun')) {
        outputs.upToDateWhen { false }
    }
    testLogging {
        showStandardStreams = true
        events 'started', 'passed', 'failed', 'skipped'
    }
}

repositories {
    jcenter()
    mavenLocal()
}

dependencies {
    compile localGroovy()
    compile gradleApi()
    testCompile gradleTestKit()
    testCompile 'junit:junit:4.12'
    testCompile 'commons-io:commons-io:2.5'
    testCompile('org.spockframework:spock-core:1.0-groovy-2.4') {
        exclude group: 'org.codehaus.groovy'
    }
}

ext.compatibilityVersion = '1.7'
sourceCompatibility = compatibilityVersion
targetCompatibility = compatibilityVersion

jar {
    manifest {
        attributes 'Implementation-Title': 'Gradle Clover plugin',
                   'Implementation-Version': version,
                   'Built-By': System.getProperty("user.name"),
                   'Built-Date': new Date(),
                   'Built-JDK': System.getProperty("java.version")
    }
}

idea.project {
    jdkName = '1.8'
    languageLevel = compatibilityVersion

    ipr.withXml { provider ->
        def node = provider.asNode()

        // Use GIT
        def vcsConfig = node.component.find { it.'@name' == 'VcsDirectoryMappings' }
        vcsConfig.mapping[0].'@vcs' = 'Git'

        // Set Gradle home
        def gradleSettings = node.appendNode('component', [name: 'GradleSettings'])
        gradleSettings.appendNode('option', [name: 'SDK_HOME', value: gradle.gradleHomeDir])
    }
}