build.gradle

plugins {
    id "architectury-plugin" version "3.4-SNAPSHOT"
    id "dev.architectury.loom" version "1.7-SNAPSHOT" apply false
    id 'io.github.juuxel.loom-quiltflower' version '1.8.0' apply false
}

architectury {
    minecraft = rootProject.minecraft_version
}

subprojects {
    apply plugin: "java"
    apply plugin: "dev.architectury.loom"
    apply plugin: "io.github.juuxel.loom-quiltflower"

    archivesBaseName = rootProject.archives_base_name
    version = rootProject.minecraft_version + "-" + rootProject.mod_version
    group = rootProject.maven_group

    loom {
        silentMojangMappingsLicense()
    }

    dependencies {
        minecraft "com.mojang:minecraft:${rootProject.minecraft_version}"
        // The following line declares the mojmap mappings, you may use other mappings as well
        mappings loom.officialMojangMappings()
        // The following line declares the yarn mappings you may select this one as well.
        // mappings "net.fabricmc:yarn:1.18.2+build.4:v2"
        implementation("org.lwjgl:lwjgl-openvr:3.3.3")
        implementation("org.lwjgl:lwjgl-openvr:3.3.3:natives-linux")
        implementation("org.lwjgl:lwjgl-openvr:3.3.3:natives-macos")
        implementation("org.lwjgl:lwjgl-openvr:3.3.3:natives-windows")
    }

    tasks.withType(JavaCompile) {
        options.encoding = "UTF-8"
        options.release = 21
    }

    java {
        withSourcesJar()
    }

    task copyJarToMain(type: Copy) {
        duplicatesStrategy = "include"
        if (project.name != "common" && project.name != "stubs") {
            from remapJar
            into "../build/libs"
        }
    }

    remapJar {
        // after remap, copy the final jsr to the main /build/libs folder
        finalizedBy copyJarToMain
    }
}

tasks.register('fixForge', Zip) {
    if (gradle.startParameter.taskNames.contains(name)) {
        if (!file('./build/libs/' + archives_base_name +
            '-' + minecraft_version +
            '-' + mod_version +
            '-forge_nonfunctional_without_changes.jar').exists() ||
            !file('./build/libs/' + archives_base_name +
                '-' + minecraft_version +
                '-' + mod_version +
                '-neoforge.jar').exists()) {
            throw new GradleException("forge and neoforge need to be built to run this task")
        }
        doFirst {
            println('unzipping jars')
        }
        copy {
            // extract all forge files
            from zipTree('./build/libs/' + archives_base_name +
                '-' + minecraft_version +
                '-' + mod_version +
                '-forge_nonfunctional_without_changes.jar')
            into './build/tmp/forge'
            // remove any refmap
            exclude "**/*-refmap.json"
            // remove the refmap from the mixin jsons
            eachFile { fileCopyDetails ->
                if (fileCopyDetails.name.endsWith('.json')) {
                    filter {
                        line -> line.contains('"refmap": "vivecraft-common-refmap.json"') ? '"dummy": ""' : line
                    }
                }
            }
        }
        copy {
            // override the general classes with the neoforge ones, since those are mapped correctly
            from zipTree('./build/libs/' + archives_base_name +
                '-' + minecraft_version +
                '-' + mod_version +
                '-neoforge.jar')
            into './build/tmp/forge'
            include '/org/vivecraft/**'
            exclude '**/neoforge/**', '**/Xplat*.class', '**/Xevents*.class'
        }

        // zip up the combined jar again
        archiveFileName = archives_base_name +
            '-' + minecraft_version +
            '-' + mod_version +
            '-forge.jar'
        destinationDirectory = file('./build/libs/')
        from './build/tmp/forge'

        doLast {
            println('removing temp files')
            delete './build/tmp/forge'
        }
    }
}

allprojects {
    apply plugin: "architectury-plugin"
    apply plugin: "maven-publish"

    repositories {
        // Add repositories to retrieve artifacts from in here.
        // You should only use this when depending on other mods because
        // Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
        // See https://docs.gradle.org/current/userguide/declaring_repositories.html
        // for more information about repositories.

        maven { url 'https://jitpack.io' }
        exclusiveContent {
            forRepository {
                maven {
                    name = "Modrinth"
                    url = "https://api.modrinth.com/maven"
                }
            }
            filter {
                includeGroup "maven.modrinth"
            }
        }

        exclusiveContent {
            forRepository {
                maven {
                    name = "Ladysnake Mods"
                    url = "https://maven.ladysnake.org/releases"
                }
            }
            filter {
                includeGroup 'io.github.ladysnake'
                includeGroup 'org.ladysnake'
                includeGroupByRegex 'dev\\.onyxstudios.*'
            }
        }

        exclusiveContent {
            forRepository {
                maven {
                    name = "fabricmc"
                    url = "https://maven.fabricmc.net/"
                }
            }
            filter {
                includeGroup "net.fabricmc"
                includeGroup "fabric-loom"
            }
        }

        maven {
            name = "neoforge"
            url = "https://maven.neoforged.net/releases/"
        }

        maven { url = "https://hephaestus.dev/release" }
        maven { url = "https://cursemaven.com" }
        maven { url = "https://maven.parchmentmc.org" }
        maven { url = "https://maven.tterrag.com/" }
        maven { url = "https://storage.googleapis.com/devan-maven/" }
        maven { url = "https://maven.shedaniel.me/" }
        maven { url = "https://aperlambda.github.io/maven" }
        maven { url = "https://maven.kotlindiscord.com/repository/terraformers/" }
        maven { url = "https://mvn.devos.one/releases/" }
        maven { url = "https://mvn.devos.one/snapshots/" }
        maven { url = "https://maven.terraformersmc.com/" }
        maven { url = "https://maven.cafeteria.dev/releases/" }
        maven { url = "https://maven.gegy.dev" }
        maven { url = "https://modmaven.dev" }
        exclusiveContent {
            forRepository {
                maven {
                    name = "JamiesWhiteShirt"
                    url = "https://maven.jamieswhiteshirt.com/libs-release"
                }
            }
            filter {
                includeGroup "com.jamieswhiteshirt"
            }
        }

        exclusiveContent {
            forRepository {
                ivy {
                    name = "Discord"
                    url = "https://cdn.discordapp.com/attachments/"
                    patternLayout {
                        artifact '/[organisation]/[module]/[revision].[ext]'
                    }
                    metadataSources { artifact() }
                }
            }
            filter {
                // discords are always just numbers
                includeGroupByRegex "^\\d*\$"
            }
        }
    }
}