build.gradle

apply plugin: 'scala'
apply plugin: 'jacoco'
apply plugin: 'com.github.kt3k.coveralls'
apply plugin: 'idea'
apply plugin: 'eclipse'

buildscript {
    repositories {
        jcenter()
        mavenLocal()
        mavenCentral()
    }
    dependencies {
        classpath 'org.kt3k.gradle.plugin:coveralls-gradle-plugin:2.8.1'
    }
}

ext {
    scalaVersion = '2.11.8'
    scalaBaseVersion = scalaVersion.substring(0, scalaVersion.lastIndexOf("."))
    scalaTestVersion = '3.0.0'
    scalaMockVersion = '3.5.0'

    typeSafeConfigVersion = '1.3.1'
    kafkaVersion = '0.10.1.0'
    guavaVersion = '21.0'
    findBugsVersion = '3.0.2'
    junitVersion = '4.12'
}

repositories {
    mavenCentral()
}

dependencies {
    compile group: 'org.scala-lang', name: 'scala-library', version: scalaVersion
    compile group: 'com.typesafe', name: "config", version: typeSafeConfigVersion
    compile group: 'org.apache.kafka', name: "kafka_$scalaBaseVersion", version: kafkaVersion
    compile group: 'org.apache.kafka', name: 'kafka-clients', version: kafkaVersion
    compile group: 'com.google.guava', name: 'guava', version: guavaVersion
    compile group: 'com.google.code.findbugs', name: 'jsr305', version: findBugsVersion

    testCompile group: 'junit', name: 'junit', version: junitVersion
    testCompile group: 'org.scalatest', name: "scalatest_$scalaBaseVersion", version: scalaTestVersion
    testCompile group: 'org.scalamock', name: "scalamock-scalatest-support_$scalaBaseVersion", version: scalaMockVersion
}

jar {
    from {
        (configurations.runtime).collect {
            it.isDirectory() ? it : zipTree(it)
        }
    }
    manifest {
        attributes(
                'Main-Class': 'com.github.mmolimar.vkitm.VKitM',
                'Class-Path': configurations.runtime.collect { it.getName() }.join(' ')
        )
    }
    exclude('*.conf')
}

jacocoTestReport {
    reports {
        xml.enabled true
        html.enabled true
        csv.enabled false
    }
}