build.gradle.kts

import com.github.benmanes.gradle.versions.updates.DependencyUpdatesTask
import sk.mholecy.meteorites.Clean

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    repositories {
        google()
        jcenter()
        maven { setUrl("https://maven.fabric.io/public") }
    }

    dependencies {
        classpath(Dependencies.gradlePlugin)
        classpath(kotlin(Dependencies.Kotlin.gradlePlugin, Versions.kotlin))
        classpath(Dependencies.NavigationComponents.safeArgs)
    }
}

allprojects {
    repositories {
        google()
        jcenter()
        maven { setUrl("https://jitpack.io") }
    }
}

plugins {
    idea
    id(Dependencies.Plugins.dependencyUpdates) version Versions.dependencyUpdates
}

tasks {
    register<Clean>("clean")

    named<DependencyUpdatesTask>("dependencyUpdates") {
        group = Project.TASK_GROUP
        resolutionStrategy {
            componentSelection {
                all {
                    val rejected = listOf("alpha", "beta", "rc", "cr", "m", "preview", "testing")
                        .map { qualifier -> Regex("(?i).*[.-]$qualifier[.\\d-]*") }
                        .any { it.matches(candidate.version) }
                    if (rejected) {
                        reject("Release candidate")
                    }
                }
            }
        }
    }
}