json.peg

%%

  String _escape(int charCode) {
    switch (charCode) {
      case 0x22:
        return '"';
      case 0x2f:
        return '/';
      case 0x5c:
        return '\\';
      case 0x62:
        return '\b';
      case 0x66:
        return '\f';
      case 0x6e:
        return '\n';
      case 0x72:
        return '\r';
      case 0x74:
        return '\t';
      default:
        throw StateError('Unable to escape charCode: $charCode');
    }
  }

%%

@event
Start = Spaces v:Value @eof() ;

@event
Array = OpenBracket ↑ v:Values CloseBracket ;

@inline
CloseBrace = v:'}' Spaces ;

@inline
CloseBracket = v:']' Spaces ;

@inline
Colon = v:':' Spaces ;

@inline
Comma = v:',' Spaces ;

String
EscapeChar = c:["/bfnrt\\] { $$ = _escape(c); } ;

String
EscapeHex = 'u' v:HexNumber { $$ = String.fromCharCode(v); } ;

HexNumber = @indicate('Expected 4 digit hex number', HexNumber_) ;

@inline
int
HexNumber_ = v:$[0-9A-Fa-f]{4} { $$ = int.parse(v, radix: 16); } ;

@inline
bool
False = 'false' Spaces { $$ = false; } ;

@inline
@event
Key = String ;

@event
MapEntry<String, Object?>
KeyValue = k:Key Colon ↑ v:Value { $$ = MapEntry(k, v); };

KeyValues = @list(KeyValue, Comma ↑ v:KeyValue);

@inline
Object?
Null = 'null' Spaces { $$ = null; } ;

@inline
num
Number_ = v:$(
  [-]?
  ([0] / [1-9][0-9]*)
  ([.] ↑ [0-9]+)?
  ([eE] ↑ [-+]? [0-9]+)?
  ) { $$ = num.parse(v); } ;

num
Number = v:@expected('number', Number_) Spaces ;

@event
Map<String, Object?>
Object = OpenBrace ↑ kv:KeyValues CloseBrace { $$ = kv.isEmpty ? const {} : Map.fromEntries(kv); };

@inline
OpenBrace = v:'{' Spaces ;

@inline
OpenBracket = v:'[' Spaces ;

@inline
Quote = v:'"' Spaces ;

Spaces = [ \n\r\t]* ;

@inline
StringChars = @stringChars(
    $[\u{20}-\u{21}\u{23}-\u{5b}\u{5d}-\u{10ffff}]+,
    [\\],
    (EscapeChar / EscapeHex)
  ) ;

String
String = '"' ↑ v:StringChars Quote ;

@inline
bool
True = 'true' Spaces { $$ = true; } ;

@event
Value =
    String
  / Object
  / Array
  / Number
  / True
  / False
  / Null ;

Values = @list(Value, Comma ↑ v:Value) ;