Bazel examples: hermetic JDK for build (not test)

Works in target- and host-config.

Still need to figure out how to use it for testing.

Author: laszlocsomor

bazel/2022-12-23--hermetic-java/.bazelversion

@@ -0,0 +1 @@
+6.0.0

bazel/2022-12-23--hermetic-java/BUILD

@@ -0,0 +1,60 @@
+# Build java 19:
+#   bazel build //:app --java_language_version=19
+#
+# Run with java 19:
+#   JAVA_HOME=$PWD/zulu19.30.11-ca-jdk19.0.1-linux_x64  bazel run //:app  --java_language_version=19
+#
+# Run with Bazel-supported java 17:
+#   bazel run //:app  --java_language_version=17 --java_runtime_version=remotejdk_17
+#
+#   Supported values of --java_runtime_version are localjdk, localjdk_[version], remotejdk_11, and
+#   remote_jdk17.  (https://bazel.build/docs/user-manual#java-runtime-version)
+#
+# Build as tool with Bazel-supported java 17:
+#   bazel build //:x  --java_language_version=17 --java_runtime_version=remotejdk_17 --tool_java_language_version=17 --tool_java_runtime_version=remotejdk_17
+#
+# Build as tool with java 19:
+#   bazel build //:x  --java_language_version=19 --java_runtime_version=19 --tool_java_language_version=19 --tool_java_runtime_version=19
+
+genrule(
+    name = "x",
+    outs = ["x.out"],
+    cmd = "$(location :app) x > $@",
+    tools = [":app"],
+)
+
+java_library(
+    name = "app_lib",
+    srcs = ["Main.java"],
+)
+
+java_binary(
+    name = "app",
+    main_class = "Main",
+    runtime_deps = [":app_lib"],
+)
+
+load(
+    "@bazel_tools//tools/jdk:default_java_toolchain.bzl",
+    "BASE_JDK9_JVM_OPTS",
+    "DEFAULT_JAVACOPTS",
+    "DEFAULT_TOOLCHAIN_CONFIGURATION",
+    "default_java_toolchain",
+)
+
+default_java_toolchain(
+    name = "my_jdk",
+    configuration = DEFAULT_TOOLCHAIN_CONFIGURATION,
+    java_runtime = ":my_jdk_runtime",
+    javacopts = DEFAULT_JAVACOPTS,
+    jvm_opts = BASE_JDK9_JVM_OPTS,
+    source_version = "19",
+    target_version = "19",
+)
+
+java_runtime(
+    name = "my_jdk_runtime",
+    srcs = ["@my_jdk//:files"],
+    java = "@my_jdk//:bin/java",
+)
+

bazel/2022-12-23--hermetic-java/Main.java

@@ -0,0 +1,18 @@
+public class Main {
+  // Sealed classes require Java 17
+  public static abstract sealed class Foo permits Bar {
+  }
+
+  private static final class Bar extends Foo {
+  }
+
+	public static void main(String[] args) {
+    // Switch expression requires Java 14 (or 12 / 13 with preview)
+		var x = switch (args.length) {
+			case 0 -> "no args";
+			case 1 -> "one arg";
+			default -> "many args";
+		};
+		System.out.println(x);
+	}
+}

bazel/2022-12-23--hermetic-java/README.md

@@ -0,0 +1,23 @@
+# Bazel demo: hermetic JDK from repo
+
+## What
+
+Demonstrate using JDK19 in target- and host-configuration. The JDK comes from an archive on disk, in
+the source tree (not checked in), and it's newer than any JDK that Bazel supports by default.
+
+## Why
+
+Wanted to build Java 13 code using a custom JDK 19 (instead of one Bazel downloads for me), and it
+was difficult to figure out how to set up the toolchains, so here's the result of my efforts.
+
+## How
+
+1. Download a JDK 19 archive (e.g. the [Zulu JDK](https://www.azul.com/downloads/?package=jdk#download-openjdk))
+1. Put the file in the workspace root
+1. Update the `WORKSPACE` file: `my_jdk.src` is the archive's name, `my_jdk.strip_prefix` is the
+   directory name inside the archive (to strip)
+1. Build (see `BUILD` for more examples):
+
+   ```sh
+   bazel build //:x  --java_language_version=19 --java_runtime_version=19 --tool_java_language_version=19 --tool_java_runtime_version=19
+   ```

bazel/2022-12-23--hermetic-java/WORKSPACE

@@ -0,0 +1,9 @@
+load("//:archive.bzl", "local_repository_archive")
+
+local_repository_archive(
+    name = "my_jdk",
+    src = "//:zulu19.30.11-ca-jdk19.0.1-linux_x64.tar.gz",
+    strip_prefix = "zulu19.30.11-ca-jdk19.0.1-linux_x64",
+)
+
+register_toolchains("//:my_jdk_definition", "//my_tool_jdk:toolchain")

bazel/2022-12-23--hermetic-java/archive.bzl

@@ -0,0 +1,30 @@
+def _impl(repository_ctx):
+    repository_ctx.extract(
+        repository_ctx.attr.src,
+        stripPrefix = repository_ctx.attr.strip_prefix,
+    )
+
+    repository_ctx.file(
+        "BUILD",
+        content = """# Generated by local_repository_archive rule
+package(default_visibility = ["//visibility:public"])
+
+_FILES = glob(["**"])
+
+filegroup(
+    name = "files",
+    srcs = _FILES,
+)
+
+exports_files(_FILES)
+""",
+        executable = False,
+    )
+
+local_repository_archive = repository_rule(
+    implementation = _impl,
+    attrs = {
+        "src": attr.label(mandatory = True, allow_single_file = True),
+        "strip_prefix": attr.string(),
+    },
+)

bazel/2022-12-23--hermetic-java/my_tool_jdk/BUILD

@@ -0,0 +1,13 @@
+load("@bazel_tools//tools/jdk:local_java_repository.bzl", "local_java_runtime")
+
+local_java_runtime(
+    name = "my_jdk_runtime",
+    java_home = None,
+    runtime_name = "//:my_jdk_runtime",
+    version = "19",
+)
+
+alias(
+    name = "toolchain",
+    actual = "runtime_toolchain_definition",
+)