build.gradle

plugins {
    id 'java'
}

group 'io.ballerina'
version '1.0-SNAPSHOT'

repositories {
    mavenCentral()
    flatDir {
        dirs "${rootProject.projectDir}/libs"
    }
}

dependencies {
    implementation project(":shell-core")

    implementation(group: 'info.picocli', name: 'picocli', version: '4.5.2')
    annotationProcessor 'info.picocli:picocli-codegen:4.5.2'

    implementation(group: 'org.jline', name: 'jline', version: '3.11.0')
    testImplementation('org.testng:testng:6.14.3') {
        because("To test the core functionality")
    }
    testImplementation(group: 'com.google.code.gson', name: 'gson', version: '2.8.6') {
        because("To load test cases")
    }
}

compileJava {
    doFirst {
        options.compilerArgs += [
                "-Aproject=${project.group}/${project.name}",
                '--module-path', classpath.asPath,
        ]
        classpath = files()
    }
}

def mainCliClass = 'io.ballerina.shell.cli.ReplShellLauncher'
task run(type: JavaExec) {
    main = mainCliClass
    standardInput = System.in
    classpath = sourceSets.main.runtimeClasspath
}

task fatJar(type: Jar) {
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
    manifest { attributes 'Main-Class': mainCliClass }
    from { configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) } }
    with jar
}

test {
    systemProperty "ballerina.home", "${rootProject.projectDir}/home"
    useTestNG()
}

ext.moduleName = 'io.ballerina.shell.cli'