build.gradle

subprojects { ->
    group = GROUP
    version = VERSION_NAME

    apply plugin: 'checkstyle'

    task checkstyle(type: Checkstyle) {
        configFile rootProject.file('checkstyle.xml')
        source 'src/main/java'
        ignoreFailures false
        showViolations true
        include '**/*.java'
        classpath = files()
    }

    afterEvaluate {
        if (project.getPlugins().hasPlugin('com.android.application') ||
                project.getPlugins().hasPlugin('com.android.library')) {
            preBuild.dependsOn('checkstyle')
        } else {
            compileJava.dependsOn('checkstyle')
        }
    }

    repositories {
        mavenCentral()
        jcenter()
        google()
    }

    buildscript {
        repositories {
            mavenCentral()
            google()
            maven {
                url "https://plugins.gradle.org/m2/"
            }
        }
        dependencies {
            classpath 'com.android.tools.build:gradle:3.0.1'
        }
    }
}

ext {
    minSdkVersion = 15
    targetSdkVersion = 26
    compileSdkVersion = 26
    buildToolsVersion = '26.0.2'
    sourceCompatibilityVersion = JavaVersion.VERSION_1_7
    targetCompatibilityVersion = JavaVersion.VERSION_1_7
}

ext.deps = [
        android           : 'com.google.android:android:4.1.1.4',
        supportcompat     : 'com.android.support:support-compat:26.0.2',
        supportAnnotations: 'com.android.support:support-annotations:26.0.2',
        appcompat         : 'com.android.support:appcompat-v7:26.1.0',
        javapoet          : 'com.squareup:javapoet:1.9.0',
        rxandroid         : 'io.reactivex.rxjava2:rxandroid:2.0.1',
        rxjava            : 'io.reactivex.rxjava2:rxjava:2.1.7',
        compiletesting    : 'com.google.testing.compile:compile-testing:0.12',
        robolectric       : 'org.robolectric:robolectric:3.5',
        mockito           : 'org.mockito:mockito-core:1.+',
        junit             : 'junit:junit:4.12',
        autoservice       : 'com.google.auto.service:auto-service:1.0-rc3',
        autocommon        : 'com.google.auto:auto-common:0.8',
        lint              : 'com.android.tools.lint:lint:26.0.0',
        lintapi           : 'com.android.tools.lint:lint-api:26.0.0',
        lintchecks        : 'com.android.tools.lint:lint-checks:26.0.0',
        linttests         : 'com.android.tools.lint:lint-tests:26.0.0'
]

task clean(type: Delete) {
    delete rootProject.buildDir
}