-
Notifications
You must be signed in to change notification settings - Fork 1
/
build.gradle.kts
142 lines (131 loc) · 4.4 KB
/
build.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
plugins {
alias(libs.plugins.kotlinMultiplatform)
alias(libs.plugins.kotlinSerialization)
alias(libs.plugins.kotlinDokka)
`maven-publish`
signing
}
repositories {
mavenCentral()
}
kotlin {
jvmToolchain(11)
jvm {
withJava()
testRuns.named("test") {
executionTask.configure {
useJUnitPlatform()
}
}
}
macosArm64()
macosX64()
linuxX64()
mingwX64()
sourceSets {
commonMain.dependencies {
implementation(libs.common.ktor.core)
implementation(libs.common.ktor.contentNegotiation)
implementation(libs.common.ktor.serialization)
implementation(libs.common.ktor.logging)
}
commonTest.dependencies {
implementation(libs.common.test.kotlin)
implementation(libs.common.test.ktorMock)
}
jvmMain.dependencies {
implementation(libs.jvm.ktor.client)
implementation(libs.jvm.ktor.logging)
}
macosMain.dependencies {
implementation(libs.macos.ktor.client)
}
linuxMain.dependencies {
implementation(libs.linux.ktor.client)
}
mingwMain.dependencies {
implementation(libs.mingw.ktor.client)
}
}
}
val dokkaJar = tasks.register<Jar>("dokkaJar") {
dependsOn(tasks.dokkaHtml)
from(tasks.dokkaHtml.flatMap { it.outputDirectory })
archiveClassifier.set("javadoc")
}
group = "com.ioki"
version = "0.0.5-SNAPSHOT"
publishing {
publications {
publications.withType<MavenPublication> {
artifact(dokkaJar)
artifactId = artifactId.replace("kmp-", "")
pom {
name.set("KMP Lokalise Api")
description.set("Lokalise API v2 Kotlin Multiplatform client library")
url.set("https://github.com/ioki-mobility/kmp-lokalise-api")
licenses {
license {
name.set("MIT")
url.set("https://opensource.org/licenses/MIT")
}
}
organization {
name.set("ioki")
url.set("https://ioki.com")
}
developers {
developer {
name.set("Stefan 'StefMa' M.")
email.set("StefMaDev@outlook.com")
url.set("https://StefMa.guru")
organization.set("ioki")
organizationUrl.set("https://ioki.com")
}
}
scm {
url.set("https://github.com/ioki-mobility/kmp-lokalise-api")
connection.set("scm:git:git://github.com/ioki-mobility/kmp-lokalise-api.git")
developerConnection.set("scm:git:ssh://git@github.com/ioki-mobility/kmp-lokalise-api.git")
}
}
}
}
repositories {
maven("https://maven.pkg.github.com/ioki-mobility/kmp-lokalise-api") {
name = "GitHubPackages"
credentials {
username = project.findProperty("githubPackagesUser") as? String
password = project.findProperty("githubPackagesKey") as? String
}
}
maven("https://s01.oss.sonatype.org/content/repositories/snapshots/") {
name = "SonatypeSnapshot"
credentials {
username = System.getenv("SONATYPE_USER")
password = System.getenv("SONATYPE_PASSWORD")
}
}
maven("https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/") {
name = "SonatypeStaging"
credentials {
username = System.getenv("SONATYPE_USER")
password = System.getenv("SONATYPE_PASSWORD")
}
}
}
}
signing {
val signingKey = System.getenv("GPG_SIGNING_KEY")
val signingPassword = System.getenv("GPG_SIGNING_PASSWORD")
useInMemoryPgpKeys(signingKey, signingPassword)
sign(publishing.publications)
}
// Workaround taken from here:
// https://github.com/gradle/gradle/issues/26091#issuecomment-1722947958
// Maybe fix can be found here:
// https://github.com/gradle/gradle/pull/26292
tasks.withType<AbstractPublishToMaven>().configureEach {
val signingTasks = tasks.withType<Sign>()
mustRunAfter(signingTasks)
}