分享一下个人的懒人更新方案

[GFDGIT]

相关讨论：#117、#201

相信有不少朋友觉得懒人包的更新方式有点繁琐，尤其是在设置了不少个性化选项，还有那种既想追求更新又不想花太多时间折腾的心态。对此，我找到了一种懒人更新方案，只要不是非常巨大的变动，应该可以一劳永逸了。

前置条件：input-event脚本，MPV-lazy的安装目录名为MPV-lazy。在此基础我写了一个bat脚本，只要将mpv-lazy-xxxx.exe拖到bat上就可以进行更新了。

安装路径的结构如下，主要是多了一个DATA文件夹，当然可以随意换成其他名字，但bat和conf要做相应修改：

/.../
    └─MPV-lazy
        │  mpv.exe
        │  ...
        ├─DATA
        │  │  custom.conf
        │  │  custom_input.conf
        │  │  custom_profiles.conf
        │  │  升级.bat
        │  ├─scripts
        │  │  inputevent.lua
        │  │  ...
        │  └─_cache
        │      │  saved-props.json
        │      ├─icc
        │      ├─shader
        │      └─watch_later
        ├─installer
        ├─portable_config
        ├─vapoursynth64
        ├─vsgenstubs4
        └─__pycache__

其中，需要关注的是升级.bat和custom.conf文件：

• 升级.bat
  警告：这个bat会无差别删除它上一级目录下的所有文件，务必不要在工作目录外运行！！！

@echo off
@REM 若bat文件编码为ANSI，注释掉下面一行
chcp 65001

@REM 获取批处理文件所在路径和目录名
cd /d %~dp0
for /f "delims=" %%i in ("%cd%") do set folder=%%~ni

@REM 进入MPV安装目录
cd ..

echo 正在删除旧的程序文件...
del /q *.*
rd /s /q __pycache__ installer portable_config vapoursynth64 vsgenstubs4

echo.
echo 正在解压新安装包...
%1 -y -o%cd%\..

echo.
echo 正在恢复原有数据...
echo.>>.\portable_config/mpv.conf
echo  include = "~~/../%folder%/custom.conf">>.\portable_config\mpv.conf

echo.
echo 升级完成！
pause

• custom.conf

# 数据
watch-later-dir = "~~/../DATA/_cache/watch_later"
gpu-shader-cache-dir = "~~/../DATA/_cache/shader"
icc-cache-dir = "~~/../DATA/_cache/icc"
script-opts-append = save_global_props-cache_dir=~~/../DATA/_cache/

# 加载脚本
scripts-add=~~/../DATA/scripts/auto_sub_fonts_dir.lua
scripts-add=~~/../DATA/scripts/inputevent.lua

# 加载input.conf
script-opts-add = inputevent-configs="~~/input_uosc.conf,~~/../DATA/custom_input.conf"

### MPV设置 ###
include = "~~/../DATA/custom_profiles.conf"
snap-window = yes

### 脚本设置 ###
script-opts-append = thumbfast-hwdec=yes

[GFDGIT]

这样做的原理是，在mpv.conf中include了custom.conf，而custom.conf中重新设置了会产生数据的目录路径，用scripts-add命令加载了input-event脚本，再使用input-event加载了自定义的custom_input.conf。

所以，以后只需要在custom.conf和custom_input.conf中修改设置，更新时通过bat进行，就可以一步完成，同时不会丢失配置和数据了。

[hong-tm]

感觉有意思,钻研一下😗

[natural-harmonia-gropius]

补充一点，input-event 加载的额外键位必须有后缀，即使是最基础的单击也需要加 #@click

[GFDGIT]

是的，而且也不支持向uosc添加菜单项了，因为实际只有input-event读取了custom_input.conf。

对此，另一种方案是将自定义项写在input-uosc.conf后面，每次更新前将修改过的行复制出来，更新完再复制回去，也可以用bat实现，就是写起来比较啰嗦了。

[zhongfly]

每次更新前将修改过的行复制出来，更新完再复制回去

我觉得不必这样，每次更新时直接每次把lazy包里的input加上你自己的custom_input.conf，合成一个新的文件，然后mpv.conf里引用这个新文件
只不过每次编辑了自己的文件后，得重新合并一次

[GFDGIT]

我更新了bat，可以实现input的备份和更新了。

[GFDGIT]

更新一下升级.bat，不再依赖input-event了，并且增加了必要的出错检查。的确显得啰嗦了很多。。。

现在可以将自定义配置写在input_uosc.conf中，但要求从最后一行开始写，并以

#-#-# custom

为起始行，更新时会自动备份此行及以下的所有行，更新完自动恢复。

• 升级.bat

@echo off
@REM 切换代码页，所有文件都需要使用utf-8编码
chcp 65001>nul

@REM 判断升级安装包名称是否符合要求
set filename=%~nx1
set pattern="mpv-lazy-[0-9][0-9][0-9][0-9][0-9][0-9].*exe"
echo "%filename%"|findstr /r %pattern%>nul || goto error1

@REM 获取批处理文件所在路径和数据目录名
cd /d %~dp0
for /f "delims=" %%i in ("%cd%") do set DATA_dir=%%~ni

@REM 判断 MPV-lazy 安装目录名是否符合要求
cd ..
for /f "delims=" %%i in ("%cd%") do set MPV_dir=%%~ni
echo "%MPV_dir%"|findstr /IR "\<mpv-lazy\>">nul || goto error2

@REM 备份 input_uosc.conf 中的自定义部分到 temp.conf
set input_conf=.\portable_config\input_uosc.conf
for /f "tokens=1 delims=:" %%i in ('findstr /n /c:"#-#-# custom" %input_conf%') do ( set /a line=%%i+1 & goto first_match )
:first_match
if DEFINED line (echo 正在备份input.conf设置...) else goto error3
for /f "skip=%line% tokens=1* delims=[]" %%a in ('find /n /v "" %input_conf%') do echo=%%b>>.\%DATA_dir%\temp.conf

:continue
echo 正在删除旧的程序文件...
del /q *.*
rd /s /q __pycache__ installer portable_config vapoursynth64 vsgenstubs4

echo 正在解压新安装包...
%1 -y -o%cd%\..

echo 正在恢复mpv.conf设置...
echo=>>.\portable_config/mpv.conf
echo  include = "~~/../%DATA_dir%/custom.conf">>.\portable_config\mpv.conf

if DEFINED line (
    echo 正在恢复input.conf设置...
    echo=>>.\portable_config\input_uosc.conf
    echo=>>.\portable_config\input_uosc.conf
    type .\%DATA_dir%\temp.conf>>.\portable_config\input_uosc.conf
    del /q .\%DATA_dir%\temp.conf
)

echo 升级完成！ & goto end

:error1
echo 新安装包格式错误! & goto end

:error2
echo 目录名必须为 MPV-lazy（不区分大小写）正在退出！
goto end

:error3
echo input_uosc.conf 中找不到自定义项，请确认!
set /p confirm="输入 y 继续升级，否则退出："
if "%confirm%"=="y" goto continue

:end
echo 按任意键退出 & pause>nul

Edit：

1. MPV-lazy安装目录不区分大小写，仍要求完全匹配，否则解压新安装包路径将出错。
2. msg命令需要专业版系统，已更换为echo。

[hong-tm]

我的意思是，你应该写成 video-sync = audio 而不是 #video-sync = xxxx

收到,🤣我自己本来想着直接video-sync = no 了,就看到你的回复,回去看了之前的文档
# 默认值audio（与音频/系统时钟同步）通常兼容性最好但有偶尔的丢帧和重复

[GFDGIT]

你这缓存目录写的啥 script-opts-append = save_global_props-cache_dir=~~/../DATA/_cache/ 非法路径导致脚本崩了

咦，我这边这么写能正常工作啊？

[hooke007]

因为他那边没有这个路径，脚本里没有自动创建文件夹的机制

[GFDGIT]

因为他那边没有这个路径，脚本里没有自动创建文件夹的机制

我将gpu-shader-cache和watch-later的目录也放在这个路径，应该是会自动创建的，除非这两个功能他都关闭了。

[hong-tm]

我将gpu-shader-cache和watch-later的目录也放在这个路径，应该是会自动创建的，除非这两个功能他都关闭了。

应该是前面某个时候删除了,我想着尽量精简

[hooke007]

从上面的例子来看，这个东西对毫无mpv使用基础的来讲还是很折腾的~~
各种意义上想绝对懒人化还得自己很了解mpv

[hong-tm]

还需要完善和无脑化🤣

[GFDGIT]

额，确实还是需要一点基础的。一方面是脚本不可能写得面面俱到，总会有考虑不周的地方。然后，相对路径写起来也是比较容易出错。

[letterk]

还需要完善和无脑化🤣

没法无脑化
毕竟portable_config才是懒人包的本体, 里面涉及scripts, shaders, vs
如果出现大的增删, 各种关联全乱, 真要无脑就啥都别改, 一律用默认设置

[Yunuuuu]

我目前是配合scoop和git，可以达到完美，更新脚本用 git pull就行，更新mpv用scoop update mpv

[hong-tm]

插眼🫠