build.gradle

plugins {
  id 'application'
  id 'checkstyle'
  id 'jacoco'
  id 'java'
  id "io.freefair.lombok" version "6.6.3"
  id 'io.spring.dependency-management' version '1.1.0'
  id 'org.springframework.boot' version '2.7.12'
  id 'com.github.kt3k.coveralls' version '2.12.2'
  id 'com.github.ben-manes.versions' version '0.46.0'
  id 'org.sonarqube' version '3.5.0.2730'
  id 'uk.gov.hmcts.java' version '0.12.43'
}

group = 'uk.gov.hmcts.reform'
version = '0.0.1'

java {
  toolchain {
    languageVersion = JavaLanguageVersion.of(17)
  }
}

sourceSets {
  functionalTest {
    java {
      compileClasspath += main.output
      runtimeClasspath += main.output
      srcDir file('src/functionalTest/java')
    }
    resources.srcDir file('src/functionalTest/resources')
  }

  integrationTest {
    java {
      compileClasspath += main.output
      runtimeClasspath += main.output
      srcDir file('src/integrationTest/java')
    }
    resources.srcDir file('src/integrationTest/resources')
  }

  smokeTest {
    java {
      compileClasspath += main.output
      runtimeClasspath += main.output
      srcDir file('src/smokeTest/java')
    }
    resources.srcDir file('src/smokeTest/resources')
  }
}

configurations {
  functionalTestImplementation.extendsFrom testImplementation
  functionalTestRuntimeOnly.extendsFrom runtimeOnly

  integrationTestImplementation.extendsFrom testImplementation
  integrationTestRuntimeOnly.extendsFrom runtimeOnly

  smokeTestImplementation.extendsFrom testImplementation
  smokeTestRuntimeOnly.extendsFrom runtimeOnly
}

tasks.withType(JavaCompile) {
  options.compilerArgs << "-Xlint:unchecked" << "-Werror"
}

// https://github.com/gradle/gradle/issues/16791
tasks.withType(JavaExec).configureEach {
  javaLauncher.set(javaToolchains.launcherFor(java.toolchain))
}

tasks.withType(Test) {
  useJUnitPlatform()

  testLogging {
    exceptionFormat = 'full'
  }
}

test {
  failFast = true
}

task functional(type: Test) {
  description = "Runs functional tests"
  group = "Verification"
  testClassesDirs = sourceSets.functionalTest.output.classesDirs
  classpath = sourceSets.functionalTest.runtimeClasspath
}

task integration(type: Test) {
  description = "Runs integration tests"
  group = "Verification"
  testClassesDirs = sourceSets.integrationTest.output.classesDirs
  classpath = sourceSets.integrationTest.runtimeClasspath
  failFast = true
}

task fortifyScan(type: JavaExec)  {
  main = "uk.gov.hmcts.fortifyclient.FortifyClientMainApp"
  classpath += sourceSets.test.runtimeClasspath
  jvmArgs = ['--add-opens=java.base/java.lang.reflect=ALL-UNNAMED']
}

task smoke(type: Test) {
  description = "Runs Smoke Tests"
  testClassesDirs = sourceSets.smokeTest.output.classesDirs
  classpath = sourceSets.smokeTest.runtimeClasspath
}

checkstyle {
  maxWarnings = 0
  toolVersion = '9.3'
  getConfigDirectory().set(new File(rootDir, 'config/checkstyle'))
}

jacocoTestReport {
  executionData(test, integration)
  reports {
    xml.required = true
    csv.required = false
    xml.destination file("${buildDir}/reports/jacoco/test/jacocoTestReport.xml")
  }
}

project.tasks['sonarqube'].dependsOn jacocoTestReport
project.tasks['check'].dependsOn integration

sonarqube {
  properties {
    property "sonar.projectName", "ccd-case-migration-starter"
    property "sonar.projectKey", "ccd-case-migration-starter"
    property "sonar.exclusions", "**/exception/*.java,**/domain/*.java,**/common/*.java,**/migration/auth/AuthTokenGeneratorConfiguration.java,**/migration/CaseMigrationRunner.java,**/ccd/HttpMessageConverterConfiguration.java"
    property "sonar.coverage.jacoco.xmlReportPaths", "${jacocoTestReport.reports.xml.destination.path}"
  }
}

// before committing a change, make sure task still works
dependencyUpdates {
  def isNonStable = { String version ->
    def stableKeyword = ['RELEASE', 'FINAL', 'GA'].any { qualifier -> version.toUpperCase().contains(qualifier) }
    def regex = /^[0-9,.v-]+$/
    return !stableKeyword && !(version ==~ regex)
  }
  rejectVersionIf { selection -> // <---- notice how the closure argument is named
    return isNonStable(selection.candidate.version) && !isNonStable(selection.currentVersion)
  }
}

apply from: './gradle/suppress.gradle'
// https://jeremylong.github.io/DependencyCheck/dependency-check-gradle/configuration.html
dependencyCheck {
  suppressionFile = 'config/owasp/suppressions.xml'
}

repositories {
  mavenLocal()
  mavenCentral()
  maven { url 'https://jitpack.io' }
}

ext {
  log4JVersion = "2.20.0"
  restAssuredVersion = '4.3.0!!'
  lombokVersion = "1.18.28"
  junit_version = "4.12"
  junitJupiterVersion = '5.9.3'
  junitVintageVersion = '5.9.3'
  powermockVersion = '2.0.9'
  springSecurity   =  '5.8.10'
  springCloudVersion = '2021.0.7'
}

ext['jackson.version'] = '2.15.3'
ext['snakeyaml.version'] = '2.0'
ext['spring-security.version'] = '5.8.10'

dependencies {
  implementation("org.springframework.cloud:spring-cloud-starter-bootstrap")
  implementation group: 'org.springframework.boot', name: 'spring-boot-starter-actuator'
  implementation group: 'org.springframework.boot', name: 'spring-boot-starter-aop'
  implementation group: 'org.springframework.boot', name: 'spring-boot-starter-json'
  implementation group: 'org.springframework', name: 'spring-context-support'
  implementation group: 'com.github.hmcts', name: 'idam-java-client', version: '1.5.5'
  implementation group: 'com.github.hmcts', name: 'service-auth-provider-java-client', version: '3.1.4'
  implementation group: 'com.github.hmcts', name: 'core-case-data-store-client', version: '4.9.2'

  testImplementation group: 'org.springframework.boot', name: 'spring-boot-starter-test'
  testImplementation group: 'com.github.tomakehurst', name: 'wiremock', version: '2.33.2'

  implementation group: 'org.springdoc', name: 'springdoc-openapi-ui', version: '1.7.0'

  implementation group: 'com.github.hmcts.java-logging', name: 'logging', version: '6.0.1'

  implementation group: 'org.apache.logging.log4j', name: 'log4j-api', version: log4JVersion
  implementation group: 'org.apache.logging.log4j', name: 'log4j-to-slf4j', version: log4JVersion
  testImplementation group: 'io.rest-assured', name: 'rest-assured', version: '4.5.1'

  testImplementation group: 'org.springframework.boot', name: 'spring-boot-starter-test'

  testImplementation('org.junit.jupiter:junit-jupiter:5.9.3')
  testImplementation "org.junit.jupiter:junit-jupiter-api:${junitJupiterVersion}"
  testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:${junitJupiterVersion}"
  testRuntimeOnly "org.junit.vintage:junit-vintage-engine:${junitVintageVersion}"
  testImplementation group:'org.mockito', name: 'mockito-junit-jupiter', version:'3.12.4'
  testImplementation group: 'org.powermock', name: 'powermock-api-mockito2', version: powermockVersion
  testImplementation group: 'org.powermock', name: 'powermock-module-junit4', version: powermockVersion
  testRuntimeOnly "org.junit.platform:junit-platform-commons:1.9.3"
  implementation group: 'org.projectlombok', name: 'lombok', version: lombokVersion
  annotationProcessor group: 'org.projectlombok', name: 'lombok', version: lombokVersion
  testAnnotationProcessor group: 'org.projectlombok', name: 'lombok', version: lombokVersion

  testImplementation 'com.github.hmcts:fortify-client:1.3.0:all'

  implementation group: 'commons-fileupload', name: 'commons-fileupload', version: '1.5'
  implementation group: 'commons-io', name: 'commons-io', version: '2.12.0'
  implementation group: 'org.springframework.security', name: 'spring-security-oauth2-resource-server', version: springSecurity
  implementation group: 'org.springframework.security', name: 'spring-security-oauth2-client', version: springSecurity
  implementation group: 'org.springframework.security', name: 'spring-security-oauth2-jose', version: springSecurity
  implementation group: 'org.springframework.security', name: 'spring-security-oauth2-core', version: springSecurity
  implementation group: 'org.springframework.security', name: 'spring-security-config', version: springSecurity
}

dependencyManagement {
  imports {
    mavenBom "org.springframework.cloud:spring-cloud-dependencies:${springCloudVersion}"
  }

  dependencies {
    dependency 'com.google.guava:guava:30.1.1-jre'

    dependencySet(group: 'commons-beanutils', version: '1.9.4') {
      entry 'commons-beanutils'
    }

    dependencySet(group: 'io.rest-assured', version: '4.5.1') {
      entry 'json-path'
      entry 'xml-path'
    }
    dependencySet(group: 'org.codehaus.groovy', version: '3.0.17') {
      entry 'groovy'
      entry 'groovy-xml'
      entry 'groovy-json'
    }
  }
}

mainClassName = 'uk.gov.hmcts.reform.migration.CaseMigrationRunner'

bootJar {
  archiveFileName = 'ccd-case-migration.jar'
  archiveBaseName = 'ccd-case-migration'
  archiveVersion = project.version.toString()
}

wrapper {
    distributionType = Wrapper.DistributionType.ALL
}

configurations.all {
  exclude group: 'org.bouncycastle', module: 'bcprov-jdk15on'
  exclude group: 'org.springframework.boot', module: 'spring-boot-starter-security'
  exclude group: 'org.springframework.security', module: 'spring-security-rsa'
}

test {
  timeout = Duration.ofMinutes(30)
  environment("AZURE_APPLICATIONINSIGHTS_INSTRUMENTATIONKEY", "some-key")
  systemProperty 'java.locale.providers', 'COMPAT'

  useJUnitPlatform()

  testLogging {
    events "failed"
    exceptionFormat "short"

    debug {
      events "passed", "started", "skipped", "failed"
      exceptionFormat "full"
    }

    info.events = ["failed", "skipped"]
  }

  reports {
    html.enabled = true
  }

  jvmArgs = [
    '--add-modules', 'java.se',
    '--add-exports', 'java.base/jdk.internal.ref=ALL-UNNAMED',
    '--add-opens', 'java.base/java.lang=ALL-UNNAMED',
    '--add-opens', 'java.base/java.nio=ALL-UNNAMED',
    '--add-opens', 'java.base/sun.nio.ch=ALL-UNNAMED',
    '--add-opens', 'java.management/sun.management=ALL-UNNAMED',
    '--add-opens', 'jdk.management/com.sun.management.internal=ALL-UNNAMED'
  ]
}