build.gradle

plugins {
	id 'java'
	alias libs.plugins.intellij.plugin
	alias libs.plugins.git.version
	alias libs.plugins.osdetector
}

group = 'mp.code'
//version = versionDetails().lastTag

java {
	sourceCompatibility = targetCompatibility = JavaVersion.VERSION_17
}

repositories {
	mavenCentral()
	intellijPlatform {
		defaultRepositories()
	}
}

dependencies {
	implementation variantOf(libs.codemp) {
		classifier 'all'
	}

	compileOnly libs.lombok
	annotationProcessor libs.lombok

	intellijPlatform { // TODO: not all of these may be needed, but whatever
		intellijIdeaCommunity('2023.3')
		bundledPlugin("com.intellij.java")
		pluginVerifier()
		zipSigner()
		instrumentationTools()
	}
}

tasks {
	patchPluginXml {
		sinceBuild.set('222')
		untilBuild.set('242.*')
	}

	signPlugin {
		certificateChain.set(System.getenv('CERTIFICATE_CHAIN'))
		privateKey.set(System.getenv('PRIVATE_KEY'))
		password.set(System.getenv('PRIVATE_KEY_PASSWORD'))
	}

	publishPlugin {
		token.set(System.getenv('PUBLISH_TOKEN'))
	}
}

// useful for debugging
runIde.doFirst { environment 'RUST_BACKTRACE', 'full' }