build.gradle

buildscript {
    repositories {
        mavenCentral()
        jcenter()
        maven {
            url "https://dl.bintray.com/palantir/releases"
        }
        maven {
            url 'https://plugins.gradle.org/m2/'
        }
    }
    dependencies {
        classpath 'com.palantir:gradle-baseline-java:0.9.0'
        classpath "com.jfrog.bintray.gradle:gradle-bintray-plugin:${bintrayPlugin}"
        classpath "org.jfrog.buildinfo:build-info-extractor-gradle:4.0.0"
        classpath 'gradle.plugin.com.palantir.configurationresolver:gradle-configuration-resolver-plugin:0.1.0'
        classpath 'gradle.plugin.org.inferred:gradle-processors:1.2.2'
    }
}

repositories {
    mavenCentral()
    jcenter()
}

apply from: "gradle/idea.gradle"
apply plugin: 'java'

group = 'com.palantir.docker.compose'
version "git describe --tags --dirty".execute().text.trim()

apply plugin: 'com.palantir.baseline-config'
apply plugin: 'com.palantir.baseline-checkstyle'
apply plugin: 'com.palantir.baseline-eclipse'
apply plugin: 'com.palantir.baseline-findbugs'
apply plugin: 'com.palantir.baseline-idea'
apply from: "${rootDir}/gradle/publish.gradle"

apply plugin: 'org.inferred.processors'
apply plugin: 'com.palantir.configuration-resolver'

sourceCompatibility = 1.8
targetCompatibility = 1.8

configurations.all {
    exclude module: 'slf4j-log4j12'
    resolutionStrategy.force(
            "org.slf4j:slf4j-api:$slf4jVersion",
            "org.slf4j:slf4j-log4j12:$slf4jVersion",
    )
}

dependencies {
    compile "org.slf4j:slf4j-api:$slf4jVersion"
    compile "org.apache.commons:commons-lang3:3.0"
    compile "commons-io:commons-io:2.4"
    compile "com.google.guava:guava:$guavaVersion"
    compile "joda-time:joda-time:$jodaVersion"
    compile "com.github.zafarkhaja:java-semver:$javaSemverVersion"

    compile "junit:junit:$junitVersion"
    compile 'com.jayway.awaitility:awaitility:1.6.5'

    processor 'org.immutables:value:2.1.14'

    testCompile "org.slf4j:slf4j-log4j12:$slf4jVersion"
    testCompile "org.apache.logging.log4j:log4j-core:$log4jVersion"
    testCompile "org.apache.logging.log4j:log4j-slf4j-impl:$log4jVersion"

    testCompile "org.hamcrest:hamcrest-all:$hamcrestVersion"
    testCompile "org.mockito:mockito-core:$mockitoVersion"
    testCompile "com.github.tomakehurst:wiremock:2.0.6-beta"
    testCompile "com.google.code.findbugs:jsr305:3.0.0"
    testCompile "com.github.stefanbirkner:system-rules:1.16.1"
}

// Instead of copying files out of `$buildDir/test-results/` on CircleCI, we can
// just write them into the right place straight away.
if (System.env.CIRCLE_TEST_REPORTS) {
    test.reports.junitXml.destination = file(System.env.CIRCLE_TEST_REPORTS)
}