Calf.spx

onMsg "start", => {
	setXYpos -80, 0
	turnTo 90
	show
}

onMsg "menu", => {
	hide
}

onMsg "menu", => {
	for !calfPlay {
		if calfDie == false {
			for i := 0; i < 10; i++ {
				if calfPlay == false {
					changeYpos -0.5
				}
				wait 0.05
			}
			for i := 0; i < 10; i++ {
				if calfPlay == false {
					changeYpos 0.5
				}
				wait 0.05
			}
		}
	}
}

onMsg "tap", => {
	setCostume 0
	for calfPlay {
		calfGravity = calfGravity - 0.25
		wait 0.05
	}
}

onMsg "tap", => {
	for calfPlay {
		for !(keyPressed(KeySpace) || mousePressed) {
			wait 0.01
		}
		calfGravity = 0.8
		for i := 0; i < 10; i++ {
			changeYpos 3.5
			wait 0.03
		}
		wait 0.03
	}
}

onMsg "tap", => {
	for calfPlay {
		for !(keyPressed(KeySpace) || mousePressed) {
			wait 0.01
		}
		play mwing, true
		wait 0.04
	}
}

onMsg "tap", => {
	for calfPlay {
		if touching("Pipe") || touching(EdgeTop) || ypos < -123.9 {

			calfPlay = false
			calfDie = true
			calfGravity = 0
			broadcast "game over"
			gotoFront
			break
		}
		wait 0.03
	}
}

onMsg "tap", => {
	flag := 0
	for calfPlay {
		if calfGravity != 0.0 {

			if heading < 150 && flag == 0 {
				turn calfGravity*-0.75
			} else {
				if heading < 90 {
					flag = 0
				} else {
					flag = 1
				}
				turn calfGravity*0.75
			}
			changeYpos calfGravity
		}
		wait 0.03
	}
}

onMsg "game over", => {
	if touching("Pipe") {
		play mhit, true
	}
	play mdie, false
}

onMsg "game over", => {
	stop OtherScriptsInSprite
	wait 0.1
	for !touching("Ground") {
		changeYpos -10
		wait 0.04
	}
	setYpos -124
	turnTo 180
	for !calfPlay{

		nextCostume
		wait 0.1
	}
}