-
Notifications
You must be signed in to change notification settings - Fork 1
/
Encode.elm
865 lines (618 loc) · 22 KB
/
Encode.elm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
module Cbor.Encode exposing
( Encoder, encode, sequence, maybe, keyValue
, bool, int, float, string, bytes, null, undefined
, float16, float32, float64
, list, indefiniteList, length, associativeList, dict, size
, Step, record, fields, field, optionalField, tuple, elems, elem, optionalElem
, beginString, beginBytes, beginList, beginDict, break
, tag, tagged
, any, raw
)
{-| The Concise Binary Object Representation (CBOR) is a data format whose design
goals include the possibility of extremely small code size, fairly small message
size, and extensibility without the need for version negotiation. These design
goals make it different from earlier binary serializations such as ASN.1 and
MessagePack.
## Encoder
@docs Encoder, encode, sequence, maybe, keyValue
## Primitives
@docs bool, int, float, string, bytes, null, undefined
## Fancier Primitives
@docs float16, float32, float64
## Simple Data-Structures
@docs list, indefiniteList, length, associativeList, dict, size
## Records & Tuples
@docs Step, record, fields, field, optionalField, tuple, elems, elem, optionalElem
## Streaming
Four CBOR items (arrays, maps, byte strings, and text strings) can be encoded
with an indefinite length. This is useful if the encoding of the item needs to
begin before the number of items inside the array or map, or the total length
of the string, is known. (The application of this is often referred to as
"streaming" within a data item.)
> **NOTE**:
>
> Indefinite-length arrays and maps are dealt with differently than
> indefinite-length byte strings and text strings.
@docs beginString, beginBytes, beginList, beginDict, break
## Tagging
@docs tag, tagged
## Debugging
@docs any, raw
-}
import Bitwise exposing (or, shiftLeftBy)
import Bytes exposing (Bytes, Endianness(..))
import Bytes.Encode as E
import Bytes.Floating.Encode as E
import Cbor exposing (CborItem(..))
import Cbor.Tag exposing (Tag(..))
import Dict exposing (Dict)
{------------------------------------------------------------------------------
Encoder
------------------------------------------------------------------------------}
{-| Describes how to encode a data structure or a type into binary CBOR
-}
type Encoder
= Encoder E.Encoder
{-| Turn a CBOR `Encoder` into [`Bytes`](https://package.elm-lang.org/packages/elm/bytes/latest/Bytes#Bytes).
-}
encode : Encoder -> Bytes
encode (Encoder e) =
E.encode e
{-| Combine a bunch of encoders sequentially.
-}
sequence : List Encoder -> Encoder
sequence =
List.map (\(Encoder e) -> e) >> E.sequence >> Encoder
{-| Optionally encode a value. `Nothing` is encoded as [`null`](#null).
-}
maybe : (a -> Encoder) -> Maybe a -> Encoder
maybe encodeA m =
case m of
Nothing ->
null
Just a ->
encodeA a
{-| Encode a key-value pair as a sequence of a key and a value. This is merely a
shorthand for a `sequence` on a 2-tuple.
E.keyValue E.string E.int ( "a", 14 )
== E.sequence
[ E.string "a"
, E.int 14
]
-}
keyValue : (a -> Encoder) -> (b -> Encoder) -> ( a, b ) -> Encoder
keyValue encodeA encodeB ( a, b ) =
sequence
[ encodeA a
, encodeB b
]
{-------------------------------------------------------------------------------
Primitives
-------------------------------------------------------------------------------}
{-| Encode booleans.
E.bool False == Bytes<0xF4>
E.bool True == Bytes<0xF5>
-}
bool : Bool -> Encoder
bool n =
Encoder <|
E.unsignedInt8 <|
if n then
0xF5
else
0xF4
{-| Encode integers from `-9007199254740992` (`-2⁵³`) to `9007199254740991` (`2⁵³ - 1`).
E.int 0 == Bytes<0x00>
E.int 1337 == Bytes<0x19, 0x05, 0x39>
-}
int : Int -> Encoder
int n =
Encoder <|
if n <= -9007199254740992 then
unsigned 1 9007199254740991
else if n < 0 then
unsigned 1 (negate n - 1)
else
unsigned 0 n
{-| Encode floating numbers with maximum precision (64-bit).
E.float 0 == Bytes<0xFB, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00>
E.float -4.1 == Bytes<0xFB, 0xC0, 0x10, 0x66, 0x66, 0x66, 0x66, 0x66, 0x66>
> **NOTE**:
>
> This is an alias for [`float64`](#float64).
-}
float : Float -> Encoder
float =
float64
{-| Encode a [`String`](https://package.elm-lang.org/packages/elm/core/latest/String#String) of fixed size as a (definite) CBOR text string.
E.string "" == Bytes<0x60>
E.string "IETF" == Bytes <0x64, 0x49, 0x45, 0x54, 0x46>
E.string "🌈" == Bytes<0x64, 0xF0, 0x9F, 0x8C, 0x88>
-}
string : String -> Encoder
string str =
Encoder <|
E.sequence
[ unsigned 3 (E.getStringWidth str)
, E.string str
]
{-| Encode raw [`Bytes`](https://package.elm-lang.org/packages/elm/bytes/latest/Bytes#Bytes) of fixed size as a (definite) CBOR byte string.
E.bytes Bytes<> == Bytes<0x40>
E.bytes Bytes<0x01, 0x02, 0x03, 0x04> = Bytes<0x44, 0x01, 0x02, 0x03, 0x04>
-}
bytes : Bytes -> Encoder
bytes bs =
Encoder <|
E.sequence
[ unsigned 2 (Bytes.width bs)
, E.bytes bs
]
{-| Create a CBOR `null` value. This can be decoded using [`Cbor.decode.maybe`](https://package.elm-lang.org/packages/elm-toulouse/cbor/latest/Cbor-Decode#maybe).
E.null == Bytes<0xF6>
-}
null : Encoder
null =
Encoder <| E.unsignedInt8 0xF6
{-| Create a CBOR `undefined` value. This can be decoded using [`Cbor.decode.maybe`](https://package.elm-lang.org/packages/elm-toulouse/cbor/latest/Cbor-Decode#maybe).
E.undefined == Bytes<0xF7>
-}
undefined : Encoder
undefined =
Encoder <| E.unsignedInt8 0xF7
{-------------------------------------------------------------------------------
Fancier Primitives
-------------------------------------------------------------------------------}
{-| Encode floating numbers with half-precision (16-bit).
E.float16 0.0 == Bytes<0xF9, 0x00, 0x00>
E.float16 -0.0 == Bytes<0xF9, 0x80, 0x00>
E.float16 1.5 == Bytes<0xF9, 0x3E, 0x00>
-}
float16 : Float -> Encoder
float16 n =
Encoder <|
E.sequence
[ majorType 7 25
, E.float16 BE n
]
{-| Encode floating numbers with simple precision (32-bit).
E.float32 0.0 == Bytes<0xFA, 0x00, 0x00, 0x00, 0x00>
E.float32 3.4028234663852886e38 == Bytes<0xFA, 0x7F, 0x7F, 0xFF, 0xFF>
-}
float32 : Float -> Encoder
float32 n =
Encoder <|
E.sequence
[ majorType 7 26
, E.float32 BE n
]
{-| Encode floating numbers with double precision (64-bit).
E.float64 0 == Bytes<0xFB, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00>
E.float64 -4.1 == Bytes<0xFB, 0xC0, 0x10, 0x66, 0x66, 0x66, 0x66, 0x66, 0x66>
-}
float64 : Float -> Encoder
float64 n =
Encoder <|
E.sequence
[ majorType 7 27
, E.float64 BE n
]
{-------------------------------------------------------------------------------
Data-Structures
-------------------------------------------------------------------------------}
{-| Turn a `List` into a (definite) CBOR array
E.list E.int [1,2,3] == Bytes<0x83, 0x01, 0x02, 0x03>
-}
list : (a -> Encoder) -> List a -> Encoder
list e xs =
sequence <|
Encoder (unsigned 4 (List.length xs))
:: List.map e xs
{-| Turn a `List` into a (indefinite) CBOR array
-}
indefiniteList : (a -> Encoder) -> List a -> Encoder
indefiniteList fn =
List.foldr (\x xs -> fn x :: xs) [ break ] >> (::) beginList >> sequence
{-| Encode a (definite) list length only. This may be useful to stream a
definite list or simply, to have even more fine-grained control over the
creation of a definite list.
E.sequence
[ E.length 2
, E.int 1
, E.int 2
]
== E.list E.int [ 1, 2 ]
-}
length : Int -> Encoder
length =
Encoder << unsigned 4
{-| Turn a `(key, value)` associative list into a (definite) CBOR map. Note
that, if keys are `comparable`, you should consider using a [`Dict`](https://package.elm-lang.org/packages/elm/core/latest/Dict#Dict) and
[`dict`](#dict) instead.
-}
associativeList : (k -> Encoder) -> (v -> Encoder) -> List ( k, v ) -> Encoder
associativeList k v xs =
sequence <|
Encoder (unsigned 5 (List.length xs))
:: List.map (keyValue k v) xs
{-| Turn a [`Dict`](https://package.elm-lang.org/packages/elm/core/latest/Dict#Dict) into a (definite) CBOR map.
E.dict E.string E.int (Dict.fromList [ ( "a", 1 ), ( "b", 2 ) ])
== Bytes<0xA2, 0x61, 0x61, 0x01, 0x61, 0x62, 0x02>
-}
dict : (k -> Encoder) -> (v -> Encoder) -> Dict k v -> Encoder
dict k v =
associativeList k v << Dict.toList
{-| Encode a (definite) dict size only. This may be useful to stream a
definite dict or simply, to have even more fine-grained control over the
creation of a definite dict.
-}
size : Int -> Encoder
size =
Encoder << unsigned 5
{-------------------------------------------------------------------------------
Records / Tuples
-------------------------------------------------------------------------------}
{-| An intermediate (opaque) step in the encoding of a record or tuple. See
[`record`](#record) or [`tuple`](#tuple) for more detail.
-}
type Step k result
= Step { steps : List Encoder, encodeKey : k -> Encoder, this : result }
{-| Encode a record as a (definite) CBOR map. Keys in the map can be arbitrary
CBOR but are expected to be homogeneous across the record.
type alias Album =
{ artist : String
, title : String
, label : Maybe String
}
-- In this example, we use compact integer as keys.
encodeAlbumCompact : Album -> E.Encoder
encodeAlbumCompact =
E.record E.int <|
E.fields
>> E.field 0 E.string .artist
>> E.field 1 E.string .title
>> E.optionalField 2 E.string .genre
-- In this example, we use more verbose string keys.
encodeAlbumVerbose : Album -> E.Encoder
encodeAlbumVerbose =
E.record E.string <|
E.fields
>> E.field "artist" E.string .artist
>> E.field "title" E.string .title
>> E.optionalField "label" E.string .genre
-}
record : (k -> Encoder) -> (Step k record -> Step k record) -> record -> Encoder
record encodeKey step this =
let
(Step { steps }) =
step <|
Step { steps = [], encodeKey = encodeKey, this = this }
in
sequence (size (List.length steps // 2) :: List.reverse steps)
{-| A helper that makes writing record encoders nicer. It is equivalent to
`identity`, but let us align encoders to fight compulsory OCDs.
-}
fields : Step k record -> Step k record
fields =
identity
{-| Encode a field of record and step through the encoding. See [`record`](#record)
for detail about usage.
-}
field : k -> (field -> Encoder) -> (record -> field) -> Step k record -> Step k record
field k encodeValue extract (Step { steps, encodeKey, this }) =
Step
{ steps = encodeValue (extract this) :: encodeKey k :: steps
, encodeKey = encodeKey
, this = this
}
{-| Encode an optional field of record and step through the encoding. See [`record`](#record)
for detail about usage.
> **NOTE**:
>
> When the value is `Nothing`, the field (and its key) is completely omitted
> from the final record.
-}
optionalField : k -> (field -> Encoder) -> (record -> Maybe field) -> Step k record -> Step k record
optionalField k encodeValue extract ((Step { this }) as step) =
case extract this of
Nothing ->
step
Just a ->
field k encodeValue (always a) step
{-| Encode a record / tuple as a (definite) CBOR array.
type alias Track =
{ title : String
, duration : Int
}
encodeTrack : Track -> E.Encoder
encodeTrack =
E.tuple <|
E.elems
>> E.elem E.string .title
>> E.elem E.int .duration
-}
tuple : (Step Never tuple -> Step Never tuple) -> tuple -> Encoder
tuple step this =
let
(Step { steps }) =
step <|
Step { steps = [], encodeKey = never, this = this }
in
sequence (length (List.length steps) :: List.reverse steps)
{-| A helper that makes writing tuple encoders nicer. It is equivalent to
`identity`, but let us align encoders to fight compulsory OCDs.
-}
elems : Step Never tuple -> Step Never tuple
elems =
identity
{-| Encode an elements of a tuple and step through the encoding. See [`tuple`](#tuple)
for detail about usage.
-}
elem : (elem -> Encoder) -> (tuple -> elem) -> Step Never tuple -> Step Never tuple
elem encodeElem extract (Step { steps, encodeKey, this }) =
Step
{ steps = encodeElem (extract this) :: steps
, encodeKey = encodeKey
, this = this
}
{-| Optionally encode an element in a tuple. See [`tuple`](#tuple)
for detail about usage.
-}
optionalElem :
(elem -> Encoder)
-> (tuple -> Maybe elem)
-> Step Never tuple
-> Step Never tuple
optionalElem encodeElem extract ((Step { this }) as step) =
case extract this of
Nothing ->
step
Just e ->
elem encodeElem (always e) step
{-------------------------------------------------------------------------------
Streaming
-------------------------------------------------------------------------------}
{-| Encode a [`Bytes`](https://package.elm-lang.org/packages/elm/bytes/latest/Bytes#Bytes)
of indefinite length in chunks. This indicates the beginning of multiple calls
to [`bytes`](#bytes), followed by a [`break`](#break) to signal the end of the
stream. For example:
E.sequence
[ E.beginBytes
, E.bytes Bytes<0x01, 0x02>
, E.bytes Bytes<0x03, 0x04>
, E.break
]
-}
beginBytes : Encoder
beginBytes =
Encoder <| majorType 2 tBEGIN
{-| Encode a [`String`](https://package.elm-lang.org/packages/elm/core/latest/String#String)
of indefinite length in chunks. This indicates the beginning of multiple calls
to [`string`](#string), followed by a [`break`](#break) to signal the end of the
stream. For example:
E.sequence
[ E.beginString
, E.string "elm"
, E.string "rocks"
, E.string "!"
, E.break
]
-}
beginString : Encoder
beginString =
Encoder <| majorType 3 tBEGIN
{-| Encode a `List` of indefinite length. This indicates the beginning of
multiple calls for encoding elements, followed by a [`break`](#break) to signal
the end of the stream. For example:
E.sequence
[ E.beginList
, E.string "elm"
, E.string "rocks"
, E.string "!"
, E.break
]
-}
beginList : Encoder
beginList =
Encoder <| majorType 4 tBEGIN
{-| Encode a [`Dict`](https://package.elm-lang.org/packages/elm/core/latest/Dict#Dict)
of indefinite length. This indicates the beginning of multiple calls for
encoding pairs of elements, followed by a [`break`](#break) to signal the end of
the stream. For example:
E.sequence
[ E.beginDict
, E.keyValue E.int E.string ( 1, "elm" )
, E.keyValue E.int E.string ( 2, "rocks" )
, E.keyValue E.int E.string ( 3, "!" )
, E.break
]
-}
beginDict : Encoder
beginDict =
Encoder <| majorType 5 tBEGIN
{-| Encode termination of an indefinite structure. See
[`beginString`](#beginString), [`beginBytes`](#beginBytes),
[`beginList`](#beginList), [`beginDict`](#beginDict) for detail about usage.
-}
break : Encoder
break =
Encoder <| E.unsignedInt8 tBREAK
{-------------------------------------------------------------------------------
Debugging
-------------------------------------------------------------------------------}
{-| Encode any generic CBOR item. This is particularly useful when dealing with
heterogeneous data structures (e.g. tuples).
E.list E.any [ CborInt 42, CborBool True, CborString "awesome!" ]
-}
any : CborItem -> Encoder
any item =
case item of
CborInt32 i ->
int i
CborInt64 ( msb, lsb ) ->
Encoder
(E.sequence
(if msb >= 0 then
-- Positive
[ majorType 0 27
, E.unsignedInt32 BE msb
, E.unsignedInt32 BE lsb
]
else if lsb >= 1 then
-- Negative and not exactly a multiple of 2^32
[ majorType 1 27
, E.unsignedInt32 BE (negate msb)
, E.unsignedInt32 BE (lsb - 1)
]
else if lsb == 0 then
-- Negative and exactly a multiple of 2^32
[ majorType 1 27
, E.unsignedInt32 BE (negate msb - 1)
, E.unsignedInt32 BE 0xFFFFFFFF
]
else
-- Forbidden for lsb < 0
-- Bytes encoding will fail
[ majorType 1 27
, E.unsignedInt32 BE -1
]
)
)
CborBytes bs ->
bytes bs
CborString str ->
string str
CborList xs ->
list any xs
CborMap xs ->
associativeList any any xs
CborTag t x ->
sequence [ tag t, any x ]
CborBool b ->
bool b
CborFloat f ->
float f
CborNull ->
null
CborUndefined ->
undefined
{-| Unsafe encoder to inject any arbitrary bytes into the encoding sequence. **Do
not use** unless you know what you're doing, this may result in invalid CBOR
encoding!
-}
raw : Bytes -> Encoder
raw =
E.bytes >> Encoder
{-------------------------------------------------------------------------------
Tagging
-------------------------------------------------------------------------------}
{-| Encode a particular [`Tag`](https://package.elm-lang.org/packages/elm-toulouse/cbor/latest/Cbor-Tag#Tag) as a CBOR tag prefix.
-}
tag : Tag -> Encoder
tag t =
Encoder <|
case t of
StandardDateTime ->
unsigned 6 0
EpochDateTime ->
unsigned 6 1
PositiveBigNum ->
unsigned 6 2
NegativeBigNum ->
unsigned 6 3
DecimalFraction ->
unsigned 6 4
BigFloat ->
unsigned 6 5
Base64UrlConversion ->
unsigned 6 21
Base64Conversion ->
unsigned 6 22
Base16Conversion ->
unsigned 6 23
Cbor ->
unsigned 6 24
Uri ->
unsigned 6 32
Base64Url ->
unsigned 6 33
Base64 ->
unsigned 6 34
Regex ->
unsigned 6 35
Mime ->
unsigned 6 36
IsCbor ->
unsigned 6 55799
Unknown i ->
unsigned 6 i
{-| Helper to quickly a tagged value
E.tagged t encodeA a == E.sequence [ E.tag t, encodeA a ]
-}
tagged : Tag -> (a -> Encoder) -> a -> Encoder
tagged t encodeA a =
sequence [ tag t, encodeA a ]
{-------------------------------------------------------------------------------
Internals
-------------------------------------------------------------------------------}
{-| Marks the beginning of an indefinite structure
-}
tBEGIN : Int
tBEGIN =
31
{-| Marks the end of an indefinite structure
-}
tBREAK : Int
tBREAK =
0xFF
{-| Encode a major type and its additional payload. Major types are encoded
using 3 bits in a single byte. The meaning given to the additional value depends
on the major type itself.
Major type -----* *---------- 5-bit additional data
| |
| |
/------------\ /----------------------\
2⁷ | 2⁶ | 2⁵ | 2⁴ | 2³ | 2² | 2¹ | 2⁰
-}
majorType : Int -> Int -> E.Encoder
majorType major payload =
E.unsignedInt8 <| or payload (shiftLeftBy 5 major)
{-| Encode an unsigned int using the given major type and payload.
Small ints (< 24) are directly encoded as part of the major type payload, and do
no require extra bytes. Biggers values requires more bytes, the number of
extra bytes being specified by the payload.
value | payload | description
--- | --- | ---
0 <= n < 24 | n | value encoded directly in the payload
24 <= n < 256 | 24 | value encoded with 1 extra byte (int8)
256 <= n < 65536 | 25 | value encoded with 2 extra bytes (int16)
65536 <= n < 4294967296 | 26 | value encoded with 4 extra bytes (int32)
n >= 4294967296 | 27 | value encoded with 8 extra bytes (int64)
Note that, we don't have any way to encode unsigned int64 in Elm, so we
artificially _emulate_ this by splitting the number in two, encoding both part
on 32-bit.
-}
unsigned : Int -> Int -> E.Encoder
unsigned major n =
if n < 24 then
majorType major n
else if n < 256 then
E.sequence
[ majorType major 24
, E.unsignedInt8 n
]
else if n < 65536 then
E.sequence
[ majorType major 25
, E.unsignedInt16 BE n
]
else if n < 4294967296 then
E.sequence
[ majorType major 26
, E.unsignedInt32 BE n
]
else
E.sequence
[ majorType major 27
, E.unsignedInt32 BE (n // 4294967296)
, E.unsignedInt32 BE n
]