build.gradle

// Copyright 2016 Proyectos y Sistemas de Mantenimiento SL (eProsima).
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
//     http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.

// internal plugins
apply plugin: 'java-library'
apply plugin: 'maven-publish'
apply plugin: 'eclipse' // Eclipse integration
apply plugin: 'antlr'

description = """"""

ext {
    publishURL = project.hasProperty('publishURL') ? project.publishURL.toString() : ''
    publishUsername = project.hasProperty('publishUsername') ? project.publishUsername.toString() : ''
    publishPassword = project.hasProperty('publishPassword') ? project.publishPassword.toString() : ''
}

repositories {
    mavenCentral()
}

dependencies {
    antlr('org.antlr:antlr4:4.13.0')
    implementation group: 'org.openjdk.nashorn', name: 'nashorn-core', version:'15.4'
}

generateGrammarSource {
    arguments += ["-long-messages", "-package", "com.eprosima.idl.parser.grammar"]
}

compileJava {
    sourceCompatibility = 1.8
    targetCompatibility = 1.8
    options.compilerArgs.add('-Xlint:deprecation')
    options.compilerArgs.add('-Xlint:unchecked')
}

// add the generated source files to the list of java sources

sourceSets {
    main {
        java {
            srcDir 'src/main/java'
            srcDir 'src/it/java' //integration tests
        }
    }
}

group = "com.eprosima"
version = "4.0.1"

//general properties
jar {
    duplicatesStrategy 'exclude'
    from { configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) } }
    archiveBaseName = 'idlparser'
    manifest {
        attributes("Created-By": "eProsima", "Main-Class": "com.eprosima.idl.test.TestIDLParser")
    }
}

task sourceJar(type: Jar, dependsOn: classes) {
   classifier = 'sources'
   from sourceSets.main.allJava
}

/**
 * Set up publishing. User must set the following properties
 * in ~/.gradle/gradle.properties or pass via -Pproperty=value
 * on command line.
 *
 * publishUsername=yourusername
 * publishPassword=yourpassword
 * publishUrl=https://some.url/maven/orgname/reponame/projectname
 */
publishing {
   publications {
      mavenJava(MavenPublication) {
         artifactId = "idl-parser"
         from components.java

         artifact sourceJar {
            classifier 'sources'
         }
      }
   }
   repositories {
      maven {
         url publishURL
         credentials.username = publishUsername
         credentials.password = publishPassword
      }
   }
}