-
-
Notifications
You must be signed in to change notification settings - Fork 5
/
clifford.mac
1673 lines (1486 loc) · 35.7 KB
/
clifford.mac
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*******************************
Clifford algebra in Maxima
Clifford: a lightweight package for performing Geometric Algebra calculations
@version
2.5.4 Date 9 May 2023
- FV algorithm added
- listofclivars fix
- permsign fix
2.5.3 Date 30 Apr 2022
- fix in lvect
- bladep
- cspan - constructs a vector v spanning a full subspace mv: v & mv =0;
2.5.2 Date 5 Dec 2021
- nclv
- bugfix in dotreverse
- bugfix in bdecompose
- norm
- multtrace moved to climatrep
2.5.1 Date 16 Jul 2021
- bugfix in clihdual
- bugfix in cinvblade
2.5.0 Date 29 Jan 2021
- matrix code moved to climatrep
- mingrade
2.4.9 Date 26 Jan 2020
- change in | and & binding power
- fix in dotsimpc
- psnorm removed
- lvect
- bugfix in maxgrade
2.4.8 Date 12 Dec 2019
- clidual deprecated
- clihdual - Hodge dual implementation
- added documentation of Hodge dual computation
- bugfix in bivectors
2.4.7 Date 17 Sept 2019
- dotexpand removed
- bugfix in dual and clidual
2.4.6 Date 1 Sept 2019
- bugfix in operpart
- inprotype='ic computes the Hestenes contraction
2.4.5 Date 20 Feb 2019
- bugfix in operpart
2.4.4 Date 18 May 2018,
- fix in clidual
- fix in dual
- grades function
- countsym depreciation
2.4.3 Date 23 Aug 2017
- bugfixes in map usage
2.4.2 Date 17 July 2017
-bugfix in explodeop
- change in oppart
- dotexpand
2.4.1 Date 17 Jun 2017
- simplification of Clifford exponents
- trigsimp inncorporated in cliffsimpall
- solving
older log: changelog.txt
@license This library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
This library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with this library; if not, write to the Free Software
Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
*/
max_version:args(build_info ())[1];
if orderlessp(max_version,"5.37") then error("Maxima verision ", max_version, " not supported");
ttyoff:true;
"vector symbol";
asymbol:e;
"number of dimensions";
ndim:0;
signature:[];
"pseudoscalar";
%iv:1;
"square of the pseudoscalar";
%ivnorm:1;
"elements of the algebra";
%elements:[1];
_debug:false;
dotexptsimp :false;
noundisp :true;
dotscrules:true;
powerdisp:true;
dotconstrules:false;
prederror :false;
stringdisp:true;
ratprint:false;
powerdisp:true;
pfeformat: true;
/*
custom operators
*/
infix ("xor", 60, 60);
"xor" (a, b):= block ([la:[], lb:[], u],
if listp(a) and listp(b) then (
la: sublist (a, lambda([u], not member(u, b)) ),
lb: sublist (b, lambda([u], not member(u, a)) ),
append(la, lb)
) else
(a or b) and not (a and b)
);
/*
different types of products
*/
infix ("|", 110, 109);
texput ("|", " \\circ ", infix);
wedgesimp:true;
inprotype:sym;
"Hestenes product type";
ipdecomp:false;
declare("|", additive);
"|"(a, b):= block ([l,r, qq, ret:0, u],
if ndim=0 then return ( buildq([a,b], "|"(a, b))),
if scalarp(a) or scalarp(b) then (
if inprotype='lc then
if scalarp(a) then ret: a*b else ret:0
elseif inprotype='rc then
if scalarp(b) then ret: a*b else ret:0
elseif inprotype='sym then ret:a.b,
if ipdecomp=true and (scalarp(a) or scalarp(b)) then return(0),
ret:expand(ret),
return(ret)
),
if not mapatom(a) then a:expand(a),
if not mapatom(b) then b:expand(b),
/*display( inop(a), inop(b)),*/
if inop(a)="+" then return (map( lambda ([u], u | b), a)),
if inop(b)="+" then return (map( lambda ([u], a | u), b)),
if wedgesimp then (
if not freeof(".", a) then
a:cliffsimp1(a),
if not freeof(".", b) then
b:cliffsimp1(b)
),
l:maxgrade(a),
r:maxgrade(b),
qq: l-r,
ret:expand(a.b),
/*display(l, r, qq, ret),*/
if inprotype='rc then
if qq<0 then return(0)
elseif qq<= l+r then
ret:cliffsimp1(ret),
if inprotype='lc then
if qq>0 then return(0)
else (
qq:-qq,
if qq<= l+r then
ret:cliffsimp1(ret)
),
if inprotype='sym then (
qq:abs(qq),
ret:cliffsimp1(ret)
),
if inprotype='ic then (
qq:abs(qq),
ret:cliffsimp1(ret)
),
/*display(ret, qq),*/
ret:grpart(ret, qq),
ret:ratsimp(ret)
);
/*texput ("\\", " \\circ ", infix);*/
"alt-Grassman product type";
ipdecompalt:false;
"outer product";
infix("&", 110, 109);
declare("&", additive);
"&"(a, b):= block ([l,r, ret:0],
if ndim=0 then return ( buildq([a,b], "&"(a, b))),
if ipdecompalt=true and (scalarp(a) or scalarp(b)) then return(0),
if not mapatom(a) then a:expand(a),
if not mapatom(b) then b:expand(b),
if inop(a)="+" then return (map( lambda ([u], u & b), a)),
if inop(b)="+" then return (map( lambda ([u], a & u), b)),
if wedgesimp then (
if not freeof(".", a) then
a:cliffsimp1(a),
if not freeof(".", b) then
b:cliffsimp1(b)
),
l:maxgrade(a),
r:maxgrade(b),
ret:cliffsimp1(a.b),
ret:grpart(ret, l+r),
ret
);
texput ("&", " \\wedge ", infix);
scprod(xx, yy):=block ([ret],
ret: dotsimpc(expand(xx.yy)),
scalarpart(ret)
);
/*
various products
- move in a special package
*/
outprod(a, b):= block ([ss:0, ret:0, lva, lvb, z, lvu],
if ipdecompalt=true and (scalarp(a) or scalarp(b)) then return(0)
elseif scalarp(a) or scalarp(b) then return(a*b),
if not mapatom(a) then a:expand(a),
if not mapatom(b) then b:expand(b),
if inop(a)="+" then return (map( lambda ([u], outprod(u , b)), a)),
if inop(b)="+" then return (map( lambda ([u], outprod(a , u)), b)),
if wedgesimp then (
if not freeof(".", a) then
a:cliffsimp1(a),
if not freeof(".", b) then
b:cliffsimp1(b)
),
lva:sublist(listofvars(a), lambda([u], not freeof(asymbol, u))),
lvb:sublist(listofvars(b), lambda([u], not freeof(asymbol, u))),
lvu:sublist (lva, lambda([u], member(u, lvb)) ),
z: length(lvu),
if z>0 then 0 else(
ret:cliffsimp1(a.b),
ss:scalarpart(ret),
ret-ss
)
);
/* change for dimensionality */
/*dualcoeff(a):=coeff(dotsimpc(a.a.a.dual(a)), %iv);*/
dualcoeff(a):=block([ss:scprod(a,a) ],
if ss#0 then
coeff(dotsimpc(a.dual(a))/ss, %iv)
else 0
);
/*infix ("<<", 110, 109); */
lcprod(a, b):= block([bi, ss, ret ],
bi:dual(b),
ret:outprod(a, bi),
ss:dualcoeff(a),
ss*dual(ret)
);
/*infix (">>", 110, 109); */
rcprod(a, b):= block([ai, ss, ret ],
ai:dual(a),
ret:outprod(ai, b),
ss:dualcoeff(b),
ss*dual(ret)
);
dotproduct(a,b):=block([ ret, u, ss, ai, bi],
ret:lcprod(a, b) + rcprod(a, b),
u:scprod(a, b),
ret -u
);
regproduct(a, b):=block([ai, bi, ss],
ai:(dual(a)),
bi:(dual(b)),
ss:dualcoeff(a)*dualcoeff(b)*%ivnorm,
ss*dual(ai & bi)
);
regproduct2(a, b):=block([ai, bi, ss],
ai:(dual(a)),
bi:(dual(b)),
ss:dualcoeff(a)*dualcoeff(b)*%ivnorm,
ss*dotsimpc ( ai & bi )
);
/**
This part implements a generic partition split operation
will be moved to operpart
*/
inop(expr):= if not mapatom (expr) then inpart(expr, 0) else 'nil;
inargs(expr):= if not mapatom (expr) then substinpart( "[", expr, 0) else 'nil;
/*
partition by predicate with expression reconstruction
literal meaning
*/
oppart(expr, predf):=block(
[sop, lst, lsttrue:[], lstfalse:[], ltrue, lfalse, err ],
mode_declare([lsttrue, lstfalse, lst, err], list),
if mapatom(expr) then (
if apply(predf, [expr]) then (ltrue:expr, lfalse:'nil)
else (lfalse:expr, ltrue:'nil),
return( [ltrue, lfalse])
) else (
sop:inop(expr),
expr:rest(expr, 0),
lst: inargs(expr),
if _debug=true then display( sop, lst),
for v in lst do (
if apply(predf, [v]) then push(v, lsttrue)
else push(v, lstfalse)
),
lsttrue:reverse(lsttrue),
lstfalse:reverse(lstfalse),
if _debug=true then display(lsttrue, lstfalse),
err:errcatch (
ltrue:if not emptyp(lsttrue) then
/*substinpart(sop, lsttrue, 0) */
if sop#"[" then
implodeop(lsttrue, sop)
else lsttrue
else 'nil,
lfalse:if not emptyp(lstfalse) then
/*substinpart(sop, lstfalse, 0) */
if sop#"[" then
implodeop(lstfalse, sop)
else lstfalse
else 'nil,
if _debug=true then display( ltrue, lfalse),
lst:[ ltrue, lfalse]
),
if _debug=true then display(err),
if emptyp(err) then lst:['nil, 'nil ]
),
lst
);
/*
splits an expression by occurencess of an operator
*/
explodeop(expr, sop):=block([lst, w],
if mapatom(expr) then return ([expr]),
lst: inargs(expr),
lreduce(append, map(lambda([w], explodeop(w, sop)), lst))
);
/*
combinees a list by operator
*/
implodeop(lsta, sop):=block([w],
if not listp(lsta) then return (lsta),
xreduce(sop, maplist(lambda([w], implodeop(w, sop)), lsta))
);
declare(resimplify, evfun);
resimplify(ex):=expand(ex, 0, 0);
/**
end of operpart
*/
/*
real predicate
*/
realp (x):= featurep(x, real);
/*
returns scalar variables
*/
scalarsym():=sublist(props, lambda( [z], if symbolp(z) then scalarp(z) else false));
/*
returns clifford variables
*/
clivars():= block([ uu, z],
sublist(values, lambda([z], uu:ev(z), not freeof(asymbol, uu )))
);
/*
returns variables excluding clifford symbols
*/
clivarsq(expr):= block([ z],
sublist(listofvars(expr), lambda([z], freeof(asymbol, z ) ))
);
alias (nclv, clivarsq);
/*
returns cliffod symbols
*/
clisym():=block([z],
sublist(props, lambda( [z], if symbolp(z) then not freeof(asymbol, z) else false))
);
/*
simplification of dot-products, ordergreat
*/
dotsimp1(ab):=block([a, b],
if mapatom(ab) or op(ab)#"." then return(ab),
a:inpart(ab,1),
b:rest(ab),
if orderlessp(a,b) then -b.a else ab
);
/*
simplification of dot-products, orderless
*/
dotsimp2(ab):=block([a, b],
if mapatom(ab) or op(ab)#"." then return(ab),
a:inpart(ab,1),
b:rest(ab),
if ordergreatp(a,b) then -b.a else ab
);
/*
toggles debugging
*/
toggle_debug():= _debug: not _debug;
/*
list of clifford variables
*/
clv(expr):=(
sublist(listofvars(expr), lambda([u], not freeof(asymbol, u)))
);
/*
simplification of dot-products
*/
declare (dotsimpc, evfun);
dotsimpc(ab):=block([ba, c:1, v, w:1, q, r, l, z, sop],
mode_declare(w, fixnum),
mode_declare([r,l], any),
sop:inop(ab),
if mapatom(ab) or freeof(".", ab) or sop='nil or sop="^" or sop="^^" then return(ab),
if sop="+" then
map(dotsimpc, ab)
else if sop="*" then (
[r,l]: oppart(ab, lambda([u], freeof(".", u))),
if _debug=true then display(sop, r, l),
r:subst(nil=1, r),
l:subst(".","*",l),
r*dotsimpc(l)
) else (
/*ba:copy(ab),*/
v:copy(inargs(ab)),
if _debug=true then display(sop, v),
/* fix for exp*/
if not freeof (%e, v) then return(ab),
w:sublist( v, lambda ([z], not freeof(asymbol,z) and mapatom(z))),
w:permsign(w),
if w#0 then (
v:sort(v),
for q in v do c:c.q,
if _debug=true then display(w, v),
w*c
) else ab
)
);
/*
internal function: parity of permutation calculation
*/
permsign(arr):=block([k:0, len, ret:0, nil ] ,
local(arr),
mode_declare([k, len], fixnum),
if not listp(arr) then return (false),
len:length(arr),
for i:1 thru len do (
if not mapatom(arr[i]) then ret:nil,
for j:i+1 thru len do
if ordergreatp(arr[i], arr[j]) then k:k+1
),
if ret#nil then
if evenp(k) then 1 else -1
else 0
);
/*
Abstract Clifford algebra construction
*/
matchdeclare([aa, ee], lambda([u], not freeof(asymbol,u) and freeof ("+", u) and not scalarp(u) ), [bb,cc], true,
[kk, mm, nn], lambda( [z], integerp(z) and z>0));
if get('clifford,'version)=false then (
simp:false,
tellsimp(aa[kk].aa[kk], signature[kk] ),
tellsimpafter(aa[kk].aa[mm], dotsimp2(aa[kk].aa[mm])),
tellsimpafter(bb.ee.cc, dotsimpc(bb.ee.cc)),
tellsimpafter(aa[kk]^^nn, powsimp(aa[kk]^^nn)),
simp:true
);
/* experimental code*/
if get('clifford,'version)=false then (
/* simplification of involution*/
tellsimpafter('cinvolve('cinvolve(bb)), bb)
);
/*
simplification rules
*/
matchdeclare(dd, lambda([u], freeof(asymbol, u)), [gg, hh], lambda([u], not freeof(asymbol, u)));
matchdeclare(ds, lambda([u], not freeof(asymbol, u) and not (freeof("^", u) or freeof("^^", u) ) ), rn, numberp);
defrule (clifsimp1, dd*bb, dd.dotsimpc(bb));
defrule (clifsimp11, bb.cc, bb.dotsimpc(cc));
defrule (clifsimp10, bb, dotsimpc(bb));
defrule (clifsimp21, bb/gg, bb . dotinvsimp(1/gg));
defrule (clifsimp3, ds, powsimp(ds));
defrule (clifsimp4, exp(gg). exp(hh), exp(gg+hh));
declare (cliexpsimp, evfun);
cliexpsimp(expr):=block([l,r, ret:1],
if inop(expr)="+" or listp(expr) then
expr:map(cliexpsimp, expr ),
if not freeof(%e, expr) then (
[l,r]:oppart(expr, lambda([u], freeof(%e, u))),
/*display(l,r),*/
r:apply1( r, clifsimp4),
if not freeof(asymbol, l) then
l:dotsimpc(l),
if not freeof(%e, r) then
r: cliexpsimp(r),
ret:subst(nil=1, l)*r
) else ret:expr,
ret
);
trigp(expr):=block([u, %trigf: 'sin or 'cos or 'tan or 'cot],
map(lambda([u], not freeof(u, expr)), %trigf)
);
/*
full simplification of expressions
inncludes dot-products and inverses
*/
declare (cliffsimpall, evfun);
cliffsimpall(expr):=block([res, aa, bb, sop, simp:true],
sop:inop(expr),
if equal(sop, "=") then (
aa:cliffsimpall(lhs(expr)),
bb:cliffsimpall(rhs(expr)),
return( aa = bb)
) else (
res:subst("^"="^^", expr),
res:expand(res),
res:apply1(res, clifsimp3, clifsimp21),
res:apply1(res, clifsimp1, clifsimp10),
/*if not freeof(%e, res) then
res:cliexpsimp(res),*/
if trigp(res) then
res: trigsimp(res),
ratsimp(res)
)
);
/*
simplification of dot-products
*/
cliffsimp1(expr):=block([res],
res:expand(expr),
apply1(res, clifsimp1, clifsimp10)
);
/*
simplification of inverses
*/
declare (dotinvsimp, evfun);
dotinvsimp(ab):=block( [a,b,c,s:ab],
if mapatom(ab) or freeof(asymbol, ab) then return(ab),
if inop(ab)="+" then
s: map(dotinvsimp, ab)
elseif op(ab)="/" then (
a:part(ab,1),
b:part(ab,2),
s:a*cinv(b)
),
s
);
/*
Clifford inverse
rewrite in view of the Faddev-Leverier algorithm
- cinvblade - for blades
- cinv - general utility for multivectors
*/
cinv(ab):=block( [s, b, u:1],
if atom(ab) or freeof(asymbol, ab) then
if ab#0 then return(1/ab) else return('nan),
"first attempt - conjugattion",
b:dotconjugate(ab),
s:expand(b.ab),
if not freeof(asymbol, s) then s: apply1(s, clifsimp10, clifsimp21),
"second attempt - reversal for blades",
if not freeof(asymbol, s) then (
b:creverse(ab),
s:expand(b.ab),
if not freeof(asymbol, s) then s: apply1(s, clifsimp10, clifsimp21)
),
if _debug=true then display(s),
if s#0 and freeof(asymbol, s) then
return(b/s)
else return(1/ab)
);
/*
simplification of exponents
*/
powsimp(aa):=block( [a, k, p:1],
if atom(aa) then return(aa),
if inop(aa)="^^" then (
a:inpart(aa,1),
k:inpart(aa,2),
if numberp(k) then (
for j:1 thru k do p:p.a,
dotsimpc(p)
) else aa
) else aa
);
/*
constructor of the algebra
lsig[1] - number of positive elements
lsig[2] - number of negative elements
lsig[3] - number of positive elements
lsig[4] - sets signature
*/
clifford(var, [lsig]):=block([m, a, p:0, n:0, r:0, s:1],
if emptyp(lsig) or length(lsig)>3 then error(" invalid signature"),
p:lsig[1],
if length(lsig)=2 then
n:lsig[2],
if length(lsig)=3 then (
n:lsig[2],
r:lsig[3]
),
/* optionally we can reverse the sign convention */
if length(lsig)=4 then (
n:lsig[2],
r:lsig[3],
s: signum (lsig[4]),
if s=0 then s:1
),
if not (numberp(n) or numberp(p) or numberp(r) or numberp(s) ) then error(" provide numbers"),
m:p+r+n,
if _debug=true then print(m,p,n,r),
if m<=0 then return (false),
local (a),
a[i,j]:= if i#j then 0 else (
if i<=p then s else if i>n+p then 0 else -s
),
ndim:m,
makebasis(var),
signature:makelist(a[i,i], i, m),
%iv:pscalar(),
/*aform:genmatrix (a, m, m),*/
%ivnorm:dotsimpc(%iv.%iv),
%elements:elements(),
signature
);
/*
sets the signature of the algebra
*/
set_signature(arr):=block(
if not listp(arr) or length(arr)#ndim then return(false),
signature:arr,
%iv:pscalar(),
%ivnorm:dotsimpc(%iv.%iv),
"aform"
);
/*
toggles the signature of the algebra
*/
toggle_signature():=block(
signature:-signature,
%iv:pscalar(),
%ivnorm:dotsimpc(%iv.%iv)
);
/*
constructs the complete basis of the algebra
- additional declarations added for compatibility with complex
operations
*/
makebasis(var):= block([ ee],
asymbol: var,
ee:buildq([asymbol], declare(asymbol, real)),
ev(ee,nouns),
ee:buildq([asymbol], declare(asymbol, mainvar)),
ev(ee,nouns),
ee:buildq([asymbol], array(asymbol, ndim) ),
ev(ee,nouns)
);
/*
constructs the vectors of the algebra
*/
vectors():=makelist(asymbol[i], i, 1, ndim);
/*
constructs the bi-vectors of the algebra
*/
bivectors():=grelem(2);
grelem(k):=block([u],
if k=0 then [0]
else
sublist(%elements, lambda([u], countsymb(u, asymbol)=k))
);
/*
constructs the pseudoscalar of the algebra
*/
pscalar([k]):=block([s:1],
if not emptyp(k) then k:min(k[1], ndim) else k: ndim,
for i:1 thru k do s:s.asymbol[i],
s
);
/*
releases all rules
*/
release():=block(
remrule ("^^", all),
remrule ("^", all),
remrule (".", all),
remrule ("*", all),
remrule ("/", all),
rem('clifford,'version),
rem('clifford,'author),
rem('clifford,'copyright)
);
alias (countsym, countsymb);
/*
counts occurences of a symbol in an expression
*/
countsymb(ab, sym):=block([inflag:true, i],
if not symbolp(sym) then error("symbol expected"),
if freeof(sym, ab) then return(0),
if atom(ab) then
if sym=ab then return(1),
if subvarp(ab) then
if sym=op(ab) then return(1),
xreduce("+", maplist( lambda([i], countsymb(i, sym)), ab))
);
/*
grade decomposition of expressions
*/
grade(expr, [gradexpand]):=block([cc, sop, k ],
local(cc),
if ndim=0 then error("ndim =0"),
array(cc, fixnum, ndim),
if emptyp(gradexpand) then gradexpand:true
else gradexpand:gradexpand[1],
if not mapatom(expr) then
if gradexpand then expr:expand(expr),
sop: inop(expr),
if sop="+" then (
for v in expr do (
k:countsym(v, asymbol),
if _debug=true then display(k,v),
cc[k]:cc[k] +v
)
)else ( "simple expression",
k:countsym(expr, asymbol),
cc[k]:cc[k] +expr
),
listarray(cc)
);
/*
grade decomposition of expressions
factors and produces a matrix
*/
matrixgrade(expr):=block([ret],
ret:grade(expr),
ret:maplist ( lambda([u], factorby( u, %elements)) , ret),
transpose(matrix(ret))
);
/*
maximal grade of an expression
*/
maxgrade(expr):=block([lst:[] ],
if freeof (asymbol, expr) then return (0),
if not mapatom(expr) then expr:expand(expr),
if inop(expr)="+" then (
lst:maplist(maxgrade, expr),
lmax(lst)
) else
countsymb(expr, asymbol)
);
/*
minimal grade of an expression
*/
mingrade(expr):=block([lst:[] ],
if freeof (asymbol, expr) then return (0),
if not mapatom(expr) then expr:expand(expr),
if inop(expr)="+" then (
lst:maplist(mingrade, expr),
lmin(lst)
) else
countsymb(expr, asymbol)
);
/*
Partial factoring by subexpression
*/
factorby(expr, z):=block([quot, res, ret, ee, u, n, sop, %qq, radsubstflag:true ],
if emptyp(z) then return (expr),
if atom(expr) then return (expr),
if matrixp(expr) then
return(matrixmap(lambda([u], factorby(u, z)), expr)),
if listp(expr) then
ret: maplist(lambda([u], factorby(u, z)), expr)
else (
if listp(z) then z:flatten(z)
else z:[z],
sop:op(expr),
if _debug=true then display(expr, sop ),
if sop="*" then
ret:map( lambda([u], factorby(u, z) ), expr)
else if sop="/" then
ret:factorby(num(expr), z)/factorby(denom(expr), z)
else if sop="^" then (
[ee, n]:args(expr),
ret:factorby(ee, z),
ret:ret^n
) else (
if inop(z[1]) = "^" then (
[ee, n]:inargs(z[1]),
assume(%qq>0),
expr:ratsubst(%qq, ee, expr),
expr:ratsubst(%qq^(1/n), %qq, expr),
/*display(ee, n),*/
[quot, res]:divide(expr, %qq),
/*display(quot, res, expr),*/
res:subst(z[1], %qq, res),
quot:subst(z[1], %qq, quot),
quot:radcan(quot)
) else
[quot, res]:divide(expr, z[1]),
if length(z)>1 then
res:factorby(res, rest(z)),
if res#0 then
ret:factor(quot)*z[1]+res
else ret:quot*z[1]+res
)
),
ret
);
declare (quotsimp, evfun);
quotsimp(expr):=block([quot, res, dd:denom(expr) ],
[quot, res]:divide(expr, dd),
factor(quot)*factor(dd)+factor(res)
);
simpfact(expr, z):=block([ret:expr, u, maperror:false, mapprint:false],
ret:factor(ret),
if not mapatom(ret) and not numberp(ret) then
map(lambda([u], factorby(u, z)), ret) else ret
);
listofclivars(expr):=block([u],
if length(%elements)=1 then %elements:elements(),
sublist(%elements, lambda ([u], not freeof(u, expr)))
);
declare (clifact, evfun);
clifact(expr):=block([lcv:[], ret: expr],
if not mapatom(expr) then (
lcv: listofclivars(expr),
if not emptyp(lcv) then
ret:factorby(expr, lcv)
),
ret
);
alias(clicoeff2, clicoeff);
/*
computes the element decomposition
clicoeff2 depreciated
*/
clicoeff(expr, smat):=block([u, ee:[], z:[], cc:[], qq ],
if length(%elements)=1 then %elements:elements(),
cc:map(lambda([u], coeff(expr, u)), %elements),
z:sublist_indices(cc, lambda([u], u#0)),
ee:makelist(%elements[i], i, z),
qq:expand(expr-substinpart("+", makelist (cc[i]*%elements[i], i, z), 0)),
cc:makelist(cc[i], i, z),
if qq#0 then (
cc: cons(qq, cc),
ee: cons(1, ee)
),
if smat='list then
[ee, cc]
else if smat='mat and not emptyp(cc) then
[ transpose(matrix(ee)), transpose(matrix(cc))] else [ ]
);
/*
computes the blade decomposition
*/
bdecompose(expr):=block([gr:expr, v, zz, lst],
if not freeof(".", expr) then
gr: expand(expr),
if length(%elements)=1 then
%elements:elements(),
if gr#0 then
gr:map( lambda([v], factorby(v, %elements) ), gr ),
gr:grade(gr),
lst:map(lambda([v], if v#0 then clicoeff(v, 'mat) else 0), gr),
lst:sublist(lst, lambda([zz], zz#0))
);
/*
solves for a list of vairables in clifford-valued equation
*/
clisolve(expr, lst):=block([ee, al, u, ret:expr, maperror:false, sol, solveexplicit:true],
if inop(expr)="=" then
ret:expand(lhs(expr)-rhs(expr)),
[ee, al]:clicoeff(ret,'list),
sol:map(lambda( [v], map(lambda( [u], solve(factor(v), u)), lst)), al),
sol:flatten(sol),
sol:setify(sol),
listify(sol)
);
/*
Clifford reverse of expressions
*/
/* canonical implementation*/
creverse(x):=block ([l, v:0, len, k],
if not freeof(".",x) then
l:grade(expand(x))
else
l:grade(x),
len: length(l),
for i:1 thru len do (
k:mod(i-1,4),
k: (if k=0 or k=1 then 1 else -1),
v:v+ k * l[i]
),
v
);