build.gradle

plugins {
    id 'groovy'
    id 'application'
}

repositories {
    maven {
        name = 'Fabric'
        url = 'https://maven.fabricmc.net/'
    }
    mavenCentral()
}

tasks.withType(JavaCompile).configureEach {
    it.options.encoding = "UTF-8"
    it.options.release = 21
}

application {
    mainClass = 'dex.mcgitmaker.GitCraft'
}

dependencies {
    implementation "org.codehaus.groovy:groovy-all:${groovy_version}"

    // Loader and its deps
    implementation "net.fabricmc:fabric-loader:${fabric_loader_version}"
    implementation "org.ow2.asm:asm:${project.asm_version}"
    implementation "org.ow2.asm:asm-analysis:${project.asm_version}"
    implementation "org.ow2.asm:asm-commons:${project.asm_version}"
    implementation "org.ow2.asm:asm-tree:${project.asm_version}"
    implementation "org.ow2.asm:asm-util:${project.asm_version}"

    implementation("net.fabricmc:stitch:${stitch_version}") {
        exclude module: 'enigma'
    }

    // tinyfile management
    implementation("net.fabricmc:tiny-remapper:${tiny_remapper_version}")
    implementation "net.fabricmc:access-widener:${access_widener_version}"
    implementation "net.fabricmc:mapping-io:${mappingio_version}"

    implementation("net.fabricmc:lorenz-tiny:${lorenz_tiny_version}") {
        transitive = false
    }

    // https://mvnrepository.com/artifact/org.eclipse.jgit/org.eclipse.jgit
    implementation "org.eclipse.jgit:org.eclipse.jgit:${jgit_version}"

    // Decompiler, could be replaced with another fernflower fork
    implementation "org.vineflower:vineflower:${vineflower_version}"

    implementation project(":DateFetcher")
}

// Disable running DateFetcher for no reason
subprojects {
    afterEvaluate { subproject ->
        if (subproject.name == 'DateFetcher') {
            tasks.named("run").configure { task ->
                task.enabled = false
            }
        }
    }
}