build.gradle

buildscript {
  ext {
    kotlinVersion = "1.2.10"
    springBootVersion = "2.0.0.M7"
  }
  repositories {
    mavenCentral()
    maven { url "https://repo.spring.io/snapshot" }
    maven { url "https://repo.spring.io/milestone" }
  }
  dependencies {
    classpath("org.springframework.boot:spring-boot-gradle-plugin:$springBootVersion")
    classpath("org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion")
    classpath("org.jetbrains.kotlin:kotlin-allopen:$kotlinVersion")
  }
}

plugins {
  id "idea"
  id "java"
  id "eclipse"
}

allprojects {
  group = "daggerok"
  version = "0.0.1"
  targetCompatibility = sourceCompatibility = JavaVersion.VERSION_1_8
}

subprojects {
  apply plugin: "kotlin"
  apply plugin: "kotlin-spring"
  apply plugin: "org.springframework.boot"
  apply plugin: "io.spring.dependency-management"

  compileKotlin {
    kotlinOptions.jvmTarget = JavaVersion.VERSION_1_8
  }

  compileTestKotlin {
    kotlinOptions.jvmTarget = JavaVersion.VERSION_1_8
  }

  repositories {
    mavenCentral()
    maven { url "https://repo.spring.io/snapshot" }
    maven { url "https://repo.spring.io/milestone" }
  }

  dependencies {
    compile("org.springframework.boot:spring-boot-starter-webflux")
    compile("org.jetbrains.kotlin:kotlin-stdlib-jre8:$kotlinVersion")
    compile("org.jetbrains.kotlin:kotlin-reflect:$kotlinVersion")
    testCompile("org.springframework.boot:spring-boot-starter-test")
    testCompile("io.projectreactor:reactor-test")
  }
}

task wrapper(type: Wrapper) {
  distributionType = "ALL"
  gradleVersion = "4.4.1"
}