-
Notifications
You must be signed in to change notification settings - Fork 0
/
forth.asm
2323 lines (1980 loc) · 95.6 KB
/
forth.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
; 253 слова head
; 103 слова используют $col
; 9 слова использует $con
; 29 слова использует $use
; 1 слово forth
masm
.8086
.MODEL SMALL
LOCALS
LINK=0
.LALL
; Макроопределения
; Описание примитивов и слов высокого уровня
HEAD MACRO length,name,lchar,labl,code
LINK$=$
DB length ; NFA 7 бит равен 1.
; 6 - признак immediate. 5- слово не описано smudge
IFNB <name>
DB name
ENDIF
DB lchar ; последний символ слова + 128 (7 бит = 1).
DW LINK ; LFA предыдущее слово (адрес первого символа имени)
LINK=LINK$
labl LABEL FAR ; CFA
IFNB <code> ;
DW code
ELSE
DW $+2
ENDIF
ENDM
HEAD2 MACRO length, name, lchar, labl, code
LINK$=$
DB length ; NFA 7 ��� ࠢ�� 1.
; 6 - �ਧ��� immediate. 5- �� �� ���ᠭ� smudge
IFNB <name>
DB '&name','>'
ENDIF
DB lchar ; ������ ᨬ��� �� + 128 (7 ��� = 1).
DW LINK ; LFA �।��饥 �� (���� ��ࢮ�� ᨬ���� �����)
LINK=LINK$
labl LABEL FAR ; CFA
IFNB <code> ;
DW code
ELSE
DW $+2
ENDIF
ENDM
debug equ 1
NEXT MACRO ; переход к исполнению следующего слова
local m1
LODSW ; DS:[SI] -> AX ; SI = SI + 2
MOV BX, AX ; BX равен CFA следующего слова
; ------ call debugger --------
IF debug
cmp byte ptr [di+102Q], 0
jz m1
call printWORD
call pause
m1:
ENDIF
; -----------------------------
JMP WORD PTR [BX]
ENDM
TITLE FORTH Interpreter
ARRAY SEGMENT
$TIME DW 0,0 ; TIMER COUNTER
$DATE DW 0 ; DATE
; Сегмент стека и словарь пользователя размещен в конце текста
; интерпретатора. Для версии, записываемой в ПЗУ, их нужно
; разместить здесь.
DSKBUF DW 3 DUP(0,512 DUP(0),0) ; Экранные буферы на 1024 байта
ENDBUF DW 0 ; 6 1034 (40Ah) 2062(80Eh) адреса буферов
XTIB DW 92 DUP(0) ; Входной буфер
XR0 DW 0,0 ; Стек возвратов растет в область
; меньших адресов. ADD BP - убрать данные
XUP DW 102 DUP(0) ; USER-область на нее указывает DI
$STI DW TASK-7 ; ; Стартовая таблица PFA слова TASK
$US DW XUP ; ; адрес user области
; переменные
$STK DW XS0 ;+6 ; SO
$RS DW XR0 ;+8 ; RO стек возвратов
DW XTIB ;+10 ; входной буфер
DW 1Fh ;+12 ; WIDTH 31 буква
DW 0 ;+14 ; WARNING
DW XDP ;+16 ; словарь FENCE (забор)
DW XDP ;+18 ; DP
DW XVOC ;+20 ; словарь VOCL в слове Forth
$BUF DW DSKBUF ;+22 ; экранный буфер FIRST
DW ENDBUF ;+24 или 30Q ; LIMIT
ASSUME CS:ARRAY, DS:ARRAY, ES:ARRAY, SS:STCK
$INI PROC FAR
JMP ENT
; ** PRIMITIVES **
HEAD 83h,'IN',311Q,INIT ;INI
ENT: MOV CX, ARRAY
MOV DS, CX ; Установка DX
MOV ES, CX
MOV AX, $STI ; Восстановление словаря (PFA слова TASK)
LEA SI, FORTH+6 ; Адрес места нахождения в PFA forth
MOV [SI], AX ;
MOV SI, $BUF
MOV CX, 1739 ; Установка счетчика 1730
XXX: MOV WORD PTR [SI],0 ; Обнуление массивов
ADD SI, 2
LOOP XXX
; INIT 'OFFSET, USE, PREV
MOV BX, $US ; xup
MOV CX, $BUF ; TO 'USE'
MOV [BX]+72Q,CX ; USE ? адрес блока
MOV [BX]+74Q,CX ; PREV ? адрес блока
MOV word ptr [BX]+102Q,00h ; отладка выключена
MOV CX, 10 ; Установка счетчика USER (14Q надо на 2 меньше уже)
MOV DI, $US ; Запись адреса области USER
ADD DI, 6 ; почему 6.... ? User переменные начинаются с 6 адреса
LEA SI, $STK ; Запись начального адреса
; заполняем начальные значения переменых
REP MOVS WORD PTR ES:[DI], WORD PTR DS:[SI]
MOV BP, $RS ; Установка начального значения
; указателя стека возвратов
; пересекается с областью TIB
; RS растет в область с меньшими адресами
MOV DI, $US
MOV WORD PTR [DI+32Q],7 ; Установка цвета вывода текста
MOV WORD PTR [DI+42Q],0 ; Сброс флага печати
LEA SI, GO$
NEXT
; здесь инструкции языка форт. указатель на них в SI
GO$: DW SPSTO,DECIMA,FORTH,DEFIN, ONE,LOA, quit; загрузка первого экрана
$INI ENDP
include debug.asm
; BX - WP находится адрес исполняемого слова
; SI - IP-регистр должен сохраняться
; DI - указатель области USER
; BP - указатель стека возвратов
; SP - указатель стека параметров
HEAD 87h,'EXECUT',305Q,EXEC ;
; в стеке адрес поля CFA (НЕ PFA)
POP BX
JMP WORD PTR [ BX ]
HEAD 83h,'LI',324Q,LIT ; LIT
LODSW
PUSH AX
NEXT
HEAD 86h,'TERMO',316Q,TERMON ; TERMON
; NumLock, ScrollLock, CapsLock, Ins. Состояние этих клавиш записывается
; в область данных BIOS в два байта с адресами 0000h:0417h и 0000h:0418h
POP AX
PUSH ES
MOV CX, 0
MOV ES, CX
MOV ES:417H,AX
POP ES
NEXT
HEAD 87h,'?BRANC',310Q,ZBRAN ; ?BRANCH
; переход, если 0 в стеке (FALSE)
POP AX
CMP AX, 0
JE CNT
ADD SI, 2 ; без перехода пропускаем следующее слово (адрес перехода)
NEXT
HEAD 86h,'BRANC',310Q,BRAN ; BRANCH
; безусловный переход. SI указывает на число инструкций,
; которые нужно пропустить
CNT: ADD SI, [SI] ; si содержит число инструкций,
; которые необходимо пропустить
NEXT
HEAD 84h,'(DO',251Q,XDO ; (DO)
POP AX ; в стек данных начальное значение цикла
SUB BP, 2
POP [BP] ; конечное значение цикла
SUB BP, 2
MOV WORD PTR [BP],AX ; в стек возвратов начальное значение цикла
; RS растет в сторону с меньшими адресами
; BP до входа в слово.
; BP-2 - конечное значение цикла
; BP-4 - начальное значение
NEXT
HEAD 86h,'(LOOP',251Q,XLOOP ; (LOOP)
; Приращение индекса цикла LOOP и может быть ветвление
INC WORD PTR [BP] ; начальное значение увеличиваем
LOP: MOV AX, [BP] ; индекс
CMP AX, [BP+2] ; предел цикла
JL CNT
LV: ADD BP, 4 ; удаляем параметры цикла
ADD SI, 2 ; переход к следующеу слову
NEXT
HEAD 87h,'(+LOOP',251Q,XPLOO ; (+LOOP)
; n ---
POP AX
ADD [BP], AX
CMP AX, 0
JL $LESS
JMP LOP
$LESS: MOV CX, [BP] ; Работа с отрицательными приращениями
CMP [BP]+2, CX
JLE LV
JMP CNT
HEAD 86h,'(FIND',251Q,PFIND ; PFIND
; addr1 addr2 --- pfa b tf (ok) оператор поиска
; Адрес строки NFA => PFA длина TRUE/FALSE (!реально СFA !)
POP AX ; NFA последнего слова в context словаре
POP CX ; addr1 строка для поиска. первый байт длина образца
PUSH BP ; сохранение содержимого регистров
PUSH SI ; --
PUSH DI ; --
MOV SI, CX ; адрес образца
SUB BP, BP ;
MOV DI, AX ; NFA последнего слова в словаре
MOV DX,WORD PTR [SI] ; длина строки поиска и первый символ
AND DX, 77577Q ; 7F7f - сброс старших битов. кажется лишним
CLD ; DF=0 (вперед)
FAST: MOV CX,WORD PTR [DI] ;
AND CX, 77477Q ; сброс 7-ых и 6 бита в первом байте
CMP DX, CX ; сравним длину и первый символ
JE SLOW ; если равны, может то, что ищем
MATCH: CMP WORD PTR [DI], 0 ; ищем конец nfa
JS $SIG ; BPL
INC DI ; следующий символ в слове
JMP MATCH
$SIG: ADD DI, 2 ; переход к полю LFA
CMP WORD PTR [DI],0 ; список слов закончился
JE FAIL ; LFA =0, поиск не удачен
MOV DI,WORD PTR [DI] ; переход к другому слову в словаре
JMP FAST
SLOW: MOV BP,WORD PTR [DI] ; длина и первый символ найденого слова
MOV BX, SI ; адрес образца
JMP SLOW1
$LOOP: INC BX ; перебор символов
MOV AX,WORD PTR [BX]
MOV CX,WORD PTR [DI]
AND CX, 77777Q ; 7FFFh
CMP AX, CX
JNE MATCH ; не совпало, переход на начало
SLOW1: INC DI
TEST WORD PTR -1[DI],100000Q ; 8000h
JZ $LOOP ; переход, если 7 бит РАВЕН 0
MOV DX, BP ; длина слова
ADD DI, 5 ; PFA найденого слова
MOV AX, DI
POP DI ; восстановление содержимого регистров
POP SI
POP BP
SUB AX, 2 ; CFA
PUSH AX
AND DX, 377Q ; FFh выделяем байт длины и ФЛАГОВ
PUSH DX ; в стек
JMP TRUE ; Установка флага "Найдено"
FAIL: POP DI
POP SI
POP BP
JMP FALSE
HEAD 85h,'DIGI',324Q,DIGIT ; DIGIT
; ASCII-DIGIT BASE=>DIGIT-VALUE TRUE (FALSE)
POP AX ; AX=BASE
POP CX
SUB CX, 60Q ; VALID DIGIT = ASCII-60
JL FALSE
CMP CX, 9 ; Если >9
JLE M09
SUB CX, 7
CMP CX, 10
JL FALSE
M09: CMP CX, AX ; Если не меньше BASE, то ошибка
JGE FALSE
PUSH CX ; Запись цифры в стек
JMP TRUE ; "Успешный" выход
; ** Стандартные слова **
; ** Условные операторы **
HEAD 82h,'0',275Q,ZEQU ; 0=
POP AX
CMP AX, 0
JE TRUE
FALSE: SUB AX, AX
PUT: PUSH AX
NEXT
TRUE: MOV AX, 1
JMP PUT
HEAD 83h,'0<','>'+80h,NZEQ ; 0<>
POP AX
CMP AX, 0
JNE TRUE
JMP FALSE
HEAD 82h,'0',276Q,ZGRET ; 0>
POP AX
CMP AX, 0
JG TRUE
JMP FALSE
HEAD 83h,'0=',276Q,ZEQGR ; 0=>
POP AX
CMP AX, 0
JGE TRUE
JMP FALSE
HEAD 82h,'0',274Q,ZLESS ; 0<
POP AX
CMP AX, 0
JS TRUE ; Если минус
JMP FALSE
HEAD 83h,'0=',274Q,ZEQLES ; 0=<
POP AX
CMP AX, 0
JS TRUE ; Если минус
JE TRUE ; или ноль
JMP FALSE
HEAD 81h,,275Q,EQUAL ; =
POP AX
POP CX
CMP CX, AX
JE TRUE
JMP FALSE
HEAD 82h,'<','>'+80h,NEQ ; <>
POP AX
POP CX
CMP CX, AX
JE FALSE1
JMP TRUE1
HEAD 82h,'U',274Q,ULESS ; U<
POP AX
POP CX
CMP CX, AX
JB TRUE1 ; для чисел без знака
JMP FALSE1
HEAD 81h,,274Q,LESS ; <
POP AX
POP CX
CMP AX, CX
JG TRUE1
JMP FALSE1
HEAD 82h,'=',274Q,EQLES ; =<
POP AX
POP CX
CMP AX, CX
JGE TRUE1
JMP FALSE1
HEAD 81h,,276Q,GREAT ; >
POP AX
POP CX
CMP AX, CX
JL TRUE1
JMP FALSE1
HEAD 82h,'=',276Q,EQGR ; =>
POP AX
POP CX
CMP AX, CX
JLE TRUE1
JMP FALSE1
HEAD 84h,'EVE', 'N'+80h, $EVEN ; EVEN
; проверка на четность
pop ax
test ax, 1 ; проверяем младший бит
jz true1 ; если бит=0, то число четное
FALSE1: SUB AX, AX
PUT1: PUSH AX
NEXT
TRUE1: MOV AX, 1
JMP PUT1
; ******************
HEAD 84h,'ENC',314Q,ENCL ; ENCLOSE
; addr1 c -- addr1 n1 n2 n3
POP AX ; разделитель
POP CX ; начальный адрес
MOV BX, CX
A: CMP BYTE PTR [BX], AL ; обход разделителей в начале
JNE NOTEQ
AAA1: INC BX
JMP A
NOTEQ: CMP BYTE PTR [BX], 15Q ; обход перевода строки
JE AAA1
CMP BYTE PTR [BX], 12Q
JE AAA1 ; обход перевода строки
MOV DX, BX ; начало лексемы
PUSH DX
AA: CMP BYTE PTR [BX], 0
JE ZZZ ; если нуль
CMP BYTE PTR [BX], AL ; не нуль, ищем конец лексемы
JE EQW
INC BX
JMP AA
EQW: MOV AX, BX
SUB BX, DX
PUSH BX
SUB AX, CX
INC AX
PUSH AX
NEXT ; выход из слова
ZZZ: CMP BX, DX
JNE EQW
INC BX
JMP EQW
; ** Дисплей **
HEAD 84h,'PAG',305Q,$PAGE ; PAGE
; Установка активной страницы ( PAGE --)
POP AX
; вход: AL = номер страницы (большинство программ использует страницу 0)
MOV AH, 5
INT 10h
NEXT
HEAD 85h,'PIX1','3'+80h,PIX13 ; pixel 13h mode
; color y x ->
pop bx
pop ax
mov dx, 320
mul dx
add ax, bx
mov bx, 0a000h
pop cx
push es
mov es, bx
mov bx, ax
mov es:[bx], cl
pop es
NEXT
HEAD 85h,'PIX1','2'+80h,PIX12 ; pixel 12h mode
; color y x ->
; ax - row
; bx - column
; ch - color
pop bx
pop ax
pop cx
mov ch, cl
push es
call pixptr12
mov dx, 3ceh
shl ah, cl
mov al, 8
out dx, ax
mov ax, 205h
out dx, ax
mov ax, 3
out dx, ax
mov al, es:[bx]
mov es:[bx], ch
mov ax, 0ff08h
out dx, ax
mov ax, 5
out dx,ax
mov ah, 3
out dx, ax
pop es
NEXT
pixptr12 proc
; ax-row
; bx-column
; returns
; es:bx -> pixel
; cl - bit position
; ah - bitmask
push dx
mov cl, bl
mov dx, 80
mul dx
shr bx, 3
add bx, ax
mov ax, 0a000h
mov es, ax
and cl, 7
xor cl, 7
mov ah, 1
pop dx
ret
pixptr12 endp
HEAD 83h,'PI',330Q,PIX ; PIX
; COLCOD ROW COLUMN --> - запись графической точки
POP CX ; колонка x?
POP DX ; строка y?
POP AX ; код цветности
;PUSH DX ; сохранение DX
;MOV DX, BX ; BH = номер видео страницы ??? где
;SUB DH, DH ; ошибка в коде
push ax
MOV AH, 0Fh ; Чтение текущей страницы
INT 10h ; в BH
pop ax ; код цветности
MOV AH, 0Ch ;
INT 10h ; запись графической точки
;POP DX ; восстановление DX
NEXT
HEAD 84h,'MOD','A'+80h,MODA ; MODA
; установка режима. ( М --> - )
POP AX
SUB AH, AH ; 00H уст. видео режим. Очистить экран
; установить поля BIOS, установить режим.
INT 10h
NEXT
HEAD 83h,'EM',311Q,EMI$ ; EMI
POP CX ; Число символов
POP AX ; Символ
PUSH CX ; Сохранение содержимого CX
PUSH AX ; Сохранение содержимого AХ
MOV BX, [DI+32Q] ; Установка атрибута
MOV AH, 0Fh ; Чтение текущей страницы
INT 10h ; в BH
POP AX ; Восстановление содержимого AX
MOV AH, 9 ; Запись строки символов
INT 10h
MOV AH, 3 ; Чтение положения курсора
INT 10h
POP CX
ADD DL, CL ; DH,DL = строка, колонка (считая от 0)
MOV AH, 2 ; Установка положения курсора
$EM: INT 10h
CMP WORD PTR [DI+42Q], 0 ; сброс флага печати
JNE PRINT
OK: NEXT
HEAD 84h,'EMI',324Q,EMIT,$EMIT ; EMIT
; вывод текста без атрибутов (по умолчанию)
$EMIT LABEL FAR
POP AX
ENT$: PUSH AX
MOV AH, 15 ; Чтение текущей страницы
INT 10h
POP AX
MOV AH, 14 ;
JMP $EM
PRINT: MOV DX, 0 ; Установка номера принтера
SUB AH, AH
INT 17h
TEST AH, 29h
JE OK
ERR4: MOV AL, AH
ADD AL, 60Q
MOV AH, 14
INT 10h
MOV DX, OFFSET ERMES4
MOV AH, 9H
INT 21H
JMP TYPE$
ERMES4 DB " PRINTER ERROR $" ;
HEAD 82h,'R',303Q,RC ; RC
MOV AX, 13
JMP ENT$
HEAD 82h,'I',314Q,IL ; BELL
MOV AX, 7
JMP ENT$
HEAD 84h,'PRI',316Q,PRIN ; PRINT-FLAG
INC WORD PTR [DI+42Q]
MOV DX, 0 ; Установка номера принтера
MOV AH, 1 ; Инициализация принтера
INT 17H
TEST AH, 29h
JNE ERR4
NEXT
HEAD 83h,'TT',331Q,TTY ; TERMI-FLAG
TYPE$: MOV WORD PTR [DI+42Q],0
NEXT
HEAD 83h,'SC',314Q,SCL ; SCL
; SCREEN CLEAR
;MOV CX, 2048 ; Загрузка счетчика
;MOV AH, 15
;INT 10h ; Установка текущей страницы
mov dx, 1855h ; DH,DL = строка, колонка (считая от 0)
sub cx, cx
;MOV AH, 2 ; Курсор в исходное положение
;INT 10h
mov bh, 0 ; атрибут
; 09H писать символ/атрибут в текущей позиции курсора
CLEAR: MOV AX, 0600H ; число пустых строк, вдвигаемых снизу (0=очистить все окно)
INT 10h
NEXT
HEAD 83h,'FI',330Q,FIX ; FIX
; Позиционирование курсора: COL ROW FIX
MOV AH, 0Fh
INT 10h ; Запись текущего номера страницы в BX
POP DX
MOV DH, DL ; строка
POP AX
MOV DL, AL ; столбец
MOV AH, 2 ; уст. позицию курсора. установка
; на строку 25 делает курсор невидимым.
INT 10h ; Фиксация положения курсора
NEXT
HEAD 84h,'DSP',314Q,DSPL ; DSPL
; LOAD GRAFBUFFER (b adr DSPL)
; записывает байт в графическую память
POP BX ; адрес
POP AX ; байт
PUSH ES ; сохранение регистра сегмента
MOV CX, 0B000H ; GRAFBUF
MOV ES, CX
MOV BYTE PTR ES:[BX], AL
POP ES
NEXT
; ** Терминал **
HEAD 83h,'KE',331Q,KEY ; KEY
; читать (ожидать) следующую нажатую клавишу
; выход: AL = ASCII символ (если AL=0, AH содержит расширенный код ASCII )
; AH = сканкод или расширенный код ASCII
SUB AH, AH
INT 16h
SUB AH, AH
PUSH AX
NEXT
HEAD 86h,'EXPEC',324Q,EXPE ; EXPECT
; adr count ->
MOV AH, 0AH ; ввод строки в буфер
POP CX ; Число символов
POP BX ; Адрес буфера SS
MOV BYTE PTR [BX], CL ; Засылка ожидаемого числа
MOV DX, BX
INT 21h
MOV AL, BYTE PTR [BX+1] ; фактически введено символов
SUB AH, AH ;
ADD BX, AX ; адрес конца строки
MOV WORD PTR [BX+2],0 ; +2, т.к. в начале строки мах длина
; и число введенных символов
NEXT
HEAD 85h,'?TER',244Q,?TER$ ; ?TER$
PUSH ES
SUB CX, CX
MOV ES, CX
OR BYTE PTR ES:[417H], 40Q
TER: MOV AH, 1 ; проверить готовность символа (и показать его, если так)
; выход: ZF = 1 если символ не готов.
; ZF = 0 если символ готов.
; AX = как для подфункции 00H (но символ здесь не
; удаляется из очереди).
INT 16h
JZ TER
SUB AH, AH ; читать (ожидать) следующую нажатую клавишу
INT 16h
AND BYTE PTR ES:[417H],337Q ; Сброс 'NUM LOCK'
POP ES ; Восстановление ES
PUSH AX ; Запись символа
NEXT
; ** Ввод/Вывод **
HEAD 84h,'POR',324Q,PORT ; PORT
POP DX
POP AX
OUT DX, AL
NEXT
HEAD 84h,'REA',304Q,READ ; READ
POP DX
IN AL, DX
SUB AH, AH
PUSH AX
NEXT
; ** Арифметика **
HEAD 82h,'1',253Q,ONEP ; 1+
POP AX
INC AX
PUSH AX
NEXT
HEAD 82h,'2',253Q,TWOP ; 2+
POP AX
ADD AX, 2
PUSH AX
NEXT
HEAD 82h,'1',255Q,ONEM ; 1-
POP AX
DEC AX
PUSH AX
NEXT
HEAD 82h,'2',252Q,MUL2 ; 2*
POP AX
SAL AX, 1
PUSH AX
NEXT
HEAD 82h,'2',257Q,DIV2 ; 2/
POP AX
SAR AX, 1
PUSH AX
NEXT
HEAD 82h, 'U', 252Q,USTAR ; U*
; u1 u2 --- ud
POP AX
POP CX
MUL CX
PUSH AX
PUSH DX
NEXT
HEAD 82h,'U',257Q,USLAS ; U/
; ud u1 --- u2 u3
POP CX ; Делитель
POP DX
POP AX
DIV CX
PUSH DX ; Остаток
PUSH AX ; Засылка результата
NEXT
HEAD 82h,'M',252Q,MSTAR ; M*
POP AX
POP CX
IMUL CX
PUSH AX
PUSH DX
NEXT
HEAD 86h,'DMINU',323Q,DMINU ; DMINUS
; Изменение знака числа двойной длины
POP AX
DMIN: NEG AX
POP CX
NEG CX
SBB AX, 0 ; sub with borrow
PUSH CX
PUSH AX
G$: NEXT
HEAD 84h,'DAB',323Q,DABS ; DABS
POP AX
CMP AX, 0
JS DMIN
PUSH AX
NEXT
HEAD 82h,'M',257Q,MSLAS ; M/
POP CX ; Делимое
POP DX
POP AX
IDIV CX
PUSH DX
PUSH AX
NEXT
HEAD 81h,,253Q,PLUS ; +
POP AX
POP CX
ADD AX, CX
PUSH AX
NEXT
HEAD 81h,,255Q,SUBB ; -
; n1 n2 -> n1-n2
POP CX
POP AX
SUB AX, CX
PUSH AX
NEXT
HEAD 82h,'D',253Q,DPLUS ; D+
POP AX
POP CX
MOV BX, SP
ADD SS:[BX+2], CX
ADC SS:[BX], AX
NEXT
HEAD 82h,'M',253Q,MPLUS ; M+
POP CX
MOV BX, SP
ADD SS:[BX+2], CX
ADC word ptr SS:[BX], 0
NEXT
HEAD 85h,'MINU',323Q,MINUS ; MINUS
POP AX
NEG AX
PUSH AX
NEXT
HEAD 84h,'SWA',302Q,SWAB ; SWAB
; обмен байтами слова в стеке
POP AX
XCHG AL, AH
PUSH AX
NEXT
HEAD 83h,'AB',323Q,$ABS ; ABS
POP AX
CMP AX, 0
JNS AB
NEG AX
AB: PUSH AX
NEXT
HEAD 83h,'AN',304Q,$AND ; AND
POP AX
POP CX
AND AX, CX
ENDA: PUSH AX
NEXT
HEAD 82h,'O',322Q,$OR ; OR
POP AX
POP CX
OR AX, CX
JMP ENDA
HEAD 83h,'XO',322Q,$XOR ; XOR
POP AX
POP CX
XOR AX, CX
JMP ENDA
HEAD2 84h,<S->,304Q,STOD ; S->D ; sds S->
POP AX
PUSH AX
MOV CX, DX ; Сохранение содержимого DX
CWD ; sign bit AX to DX
PUSH DX
MOV DX, CX ; Восстановление DX
NEXT
HEAD 83h,'MI',316Q,MIN ; MIN
POP AX
POP CX
CMP CX, AX
JL DEEP ;
TOP: PUSH AX
NEXT
DEEP: PUSH CX
NEXT
HEAD 83h,'MA',330Q,MAX ; MAX
POP AX
POP CX
CMP CX, AX
JGE DEEP
JMP TOP
HEAD 83h,'SP',300Q,SPAT ; SP@
; значение текущего указателя регистра SP в стек
MOV AX, SP
JMP ENDA
HEAD 83h,'SP',241Q,SPSTO ; SP!
MOV SP, [DI+6] ; 80h
NEXT
HEAD 83h,'RP',241Q,RPSTO ; RP!
MOV BP, $RS ; ccch
NEXT
HEAD 82h,';',323Q,SEMI ; ;S
; переход на слово по адресу в стеке возврата СЛОЖНО
; слово,которым заканчивается слова на форте
MOV SI, [BP] ; в RS хранится адрес следующего слова,
; до перехода на исполнение слова, которое завершается
ADD BP, 2 ; удаляем из RS
NEXT ; возврат на предыдущее слово
; ** Стек возвратов **
HEAD 85h, 'LEAV',305Q,LEAV ; LEAVE
; надо смотреть дальше с хранением адресов
; приравнивает значения индекса и предела
MOV AX, [BP]
MOV [BP+2], AX
NEXT
HEAD 82h, 62,322Q,TOR ; >R sds
; пишем в стек возвратов
; слово из стека данных
SUB BP, 2 ; заняли ячейку
POP [BP] ; записали значение
NEXT
HEAD 82h, 'R',276Q,FROMR ; R>
; в стек данных слово по адресу из стека возвратов
PUSH [BP] ; в стек записали
ADD BP, 2 ; убрали
NEXT
HEAD 81h,,311Q,I ; I R R@
; Копирует верхнее число из стека возвратов
; и записывая в стек параметров
RR$: PUSH [BP]
Z$: NEXT
HEAD 81h,,322Q,R ; R
JMP RR$
HEAD 82h,'I',247Q,SRP ; I'
; Копирует второе сверху число из стека возвратов
; и записывает его в стек параметров
PUSH [BP+2]
JMP Z$
HEAD 81h,,'J'+80h,J ; J
; Копирует третье сверху число из стека возвратов
; и записывает его в стек параметров
PUSH [BP+4]
JMP Z$
HEAD 82h,'J',247Q,JT ; J'
; Копирует четвертое сверху число из стека возвратов
; и записывает его в стек параметров
PUSH [BP+6]
JMP Z$
HEAD 81h,,'K'+80h,K ; K
; Копирует пятое сверху число из стека возвратов
; и записывает его в стек параметров
PUSH [BP+8]
JMP Z$
HEAD 82h,'K',247Q,KT ; K'
; Копирует шестое сверху число из стека возвратов
; и записывает его в стек параметров
PUSH [BP+10]
JMP Z$
HEAD 83h,'LE',326Q,LEV ; LEV
; эквивалент R> DROP :) только быстрее
; для выхода из interpret
ADD BP, 2
NEXT
;** Операции со стеком параметров **
HEAD 84h,'PIC',313Q,PICK ; PICK
POP BX
CMP BX, 0
JLE $GO
DEC BX
SAL BX, 1
ADD BX, SP
PUSH SS:[BX]
$GO: NEXT
HEAD 84h,'OVE',322Q,OVER ; OVER
MOV BX, SP
PUSH SS:[BX+2]
NEXT