Jenkinsfile-release

pipeline {
    agent any

    options {
        buildDiscarder(logRotator(numToKeepStr: "1"))
        disableConcurrentBuilds()
        disableResume()
        timestamps()
        timeout(time: 30, unit: 'MINUTES')
    }

    environment {
        GIT_PUSH_BRANCH = "develop"
        GIT_CONFIG_USER_NAME = "Jenkins"
        GIT_CONFIG_USER_MAIL = "contact+jenkins@c-henry.fr"
        GIT_AUTH = credentials "gitlab-jenkins-release"
    }

    parameters {
        string defaultValue: "", description: "", name: "VERSION", trim: true
        text defaultValue: "", description: "", name: "CHANGELOG"
    }

    stages {
        stage("Updating versionCode and versionName") {
            steps {
                script {
                    if(params.VERSION.isEmpty()) error("Parameter VERSION must not be empty")
                    if(params.CHANGELOG.isEmpty()) error("Parameter CHANGELOG must not be empty")

                    def filePath = "$WORKSPACE/.versions.properties"
                    def props = readProperties  file: filePath

                    env.VERSION_CODE = Integer.parseInt("${props.versionCode}".trim()) + 1
                    props.versionCode = env.VERSION_CODE
                    props.versionName = params.VERSION

                    def propsString = props.collect { k, v -> "$k = $v"}.join("\n")

                    writeFile file: filePath, text: normalizeString(propsString)

                    sh "git add $filePath"
                }
            }
        }

        stage("Creating new changelog for version") {
            steps {
                script {
                    def changelogPath = "$WORKSPACE/fastlane/metadata/android/en-US/changelogs/${env.VERSION_CODE}.txt"
                    def file = new File(changelogPath)
                    file.write(normalizeString(params.CHANGELOG), "utf-8")

                    sh "git add $changelogPath"
                }
            }
        }

        stage("Commit and push") {
            steps {
                script {
                    def shellFctn = "echo username=${'$'}GIT_AUTH_USR; echo password=${'$'}GIT_AUTH_PSW;"
                    def versionSummary = "Release v${params.VERSION}"

                    sh("""
                        git config --local credential.helper "!f() { $shellFctn }; f"
                        git config --global user.name ${env.GIT_CONFIG_USER_NAME}
                        git config --global user.email ${env.GIT_CONFIG_USER_MAIL}
                        git commit -am '[Jenkins CI] $versionSummary'

                        git tag -f -m "$versionSummary\n\n${normalizeString(params.CHANGELOG)}" v${params.VERSION}
                        git push --tags origin HEAD:${env.GIT_PUSH_BRANCH}
                    """)
                }
            }
        }
    }
}

String normalizeString(String changelog) {
    return changelog.endsWith("\n") ? changelog : "${changelog}\n"
}