-
Notifications
You must be signed in to change notification settings - Fork 88
/
js_driver.erl
218 lines (197 loc) · 7.74 KB
/
js_driver.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
%% @author Kevin Smith <ksmith@basho.com>
%% @copyright 2009-2010 Basho Technologies
%%
%% Licensed under the Apache License, Version 2.0 (the "License");
%% you may not use this file except in compliance with the License.
%% You may obtain a copy of the License at
%%
%% http://www.apache.org/licenses/LICENSE-2.0
%%
%% Unless required by applicable law or agreed to in writing, software
%% distributed under the License is distributed on an "AS IS" BASIS,
%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
%% See the License for the specific language governing permissions and
%% limitations under the License.
%% @doc This module manages all of the low-level details surrounding the
%% linked-in driver. It is reponsible for loading and unloading the driver
%% as needed. This module is also reponsible for creating and destroying
%% instances of Javascript VMs.
-module(js_driver).
-define(DEFAULT_HEAP_SIZE, 8). %% MB
-define(DEFAULT_THREAD_STACK, 16). %% MB
-export([load_driver/0, new/0, new/2, new/3, destroy/1, shutdown/1]).
-export([define_js/2, define_js/3, define_js/4, eval_js/2, eval_js/3]).
-define(SCRIPT_TIMEOUT, 5000).
-define(DRIVER_NAME, "erlang_js_drv").
%% @spec load_driver() -> true | false
%% @doc Attempt to load the Javascript driver
load_driver() ->
{ok, Drivers} = erl_ddll:loaded_drivers(),
case lists:member(?DRIVER_NAME, Drivers) of
false ->
case erl_ddll:load(priv_dir(), ?DRIVER_NAME) of
ok ->
true;
{error, Error} ->
error_logger:error_msg("Error loading ~p: ~p~n", [?DRIVER_NAME, erl_ddll:format_error(Error)]),
false
end;
true ->
true
end.
%% @spec new() -> {ok, port()} | {error, atom()} | {error, any()}
%% @doc Create a new Javascript VM instance and preload Douglas Crockford's
%% json2 converter (http://www.json.org/js.html). Uses a default heap
%% size of 8MB and a default thread stack size of 8KB.
new() ->
new(?DEFAULT_THREAD_STACK, ?DEFAULT_HEAP_SIZE).
%% @spec new(ThreadStackSize::int(), HeapSize::int()) -> {ok, port()} | {error, atom()} | {error, any()}
%% @doc Create a new Javascript VM instance and preload Douglas Crockford's
%% json2 converter (http://www.json.org/js.html)
new(ThreadStackSize, HeapSize) ->
{ok, Port} = new(ThreadStackSize, HeapSize, no_json),
%% Load json converter for use later
case define_js(Port, <<"json2.js">>, json_converter(), ?SCRIPT_TIMEOUT) of
ok ->
{ok, Port};
{error, Reason} ->
port_close(Port),
{error, Reason}
end.
%% @type init_fun() = function(port()).
%% @spec new(int(), int(), no_json | init_fun() | {ModName::atom(), FunName::atom()}) -> {ok, port()} | {error, atom()} | {error, any()}
%% @doc Create a new Javascript VM instance. The function arguments control how the VM instance is initialized.
%% User supplied initializers must return true or false.
new(ThreadStackSize, HeapSize, no_json) ->
Port = open_port({spawn, ?DRIVER_NAME}, [binary]),
_ = call_driver(Port, "ij", [ThreadStackSize, HeapSize], 5000),
{ok, Port};
new(ThreadStackSize, HeapSize, Initializer) when is_function(Initializer) ->
{ok, Port} = new(ThreadStackSize, HeapSize),
case Initializer(Port) of
ok ->
{ok, Port};
{error, Error} ->
js_driver:destroy(Port),
error_logger:error_report(Error),
throw({error, init_failed})
end;
new(ThreadStackSize, HeapSize, {InitMod, InitFun}) ->
{ok, Port} = new(ThreadStackSize, HeapSize),
case InitMod:InitFun(Port) of
ok ->
{ok, Port};
{error, Error} ->
js_driver:destroy(Port),
error_logger:error_report(Error),
throw({error, init_failed})
end.
%% @spec destroy(port()) -> ok
%% @doc Destroys a Javascript VM instance
destroy(Ctx) ->
port_close(Ctx).
%% @spec shutdown(port()) -> ok
%% @doc Destroys a Javascript VM instance and shuts down the underlying Javascript infrastructure.
%% NOTE: No new VMs can be created after this call is made!
shutdown(Ctx) ->
_ = call_driver(Ctx, "sd", [], 60000),
port_close(Ctx).
%% @spec define_js(port(), binary()) -> ok | {error, any()}
%% @doc Define a Javascript expression:
%% js_driver:define(Port, <<"var x = 100;">>).
define_js(Ctx, Js) ->
define_js(Ctx, Js, ?SCRIPT_TIMEOUT).
%% @private
define_js(Ctx, {file, FileName}, Timeout) ->
{ok, File} = file:read_file(FileName),
define_js(Ctx, list_to_binary(FileName), File, Timeout);
define_js(Ctx, Js, Timeout) when is_binary(Js) ->
define_js(Ctx, <<"unnamed">>, Js, Timeout).
%% @spec define_js(port(), binary(), binary(), integer()) -> {ok, binary()} | {error, any()}
%% @doc Define a Javascript expression:
%% js_driver:define(Port, <<var blah = new Wubba();">>).
%% Note: Filename is used only as a label for error reporting.
define_js(Ctx, FileName, Js, Timeout) when is_binary(FileName),
is_binary(Js) ->
case call_driver(Ctx, "dj", [FileName, Js], Timeout) of
{error, ErrorJson} when is_binary(ErrorJson) ->
{struct, [{<<"error">>, {struct, Error}}]} = js_mochijson2:decode(ErrorJson),
{error, Error};
{error, Error} ->
{error, Error};
ok ->
ok
end.
%% @spec eval_js(port(), binary()) -> {ok, any()} | {error, any()}
%% @doc Evaluate a Javascript expression and return the result
eval_js(Ctx, Js) ->
eval_js(Ctx, Js, ?SCRIPT_TIMEOUT).
%% @private
eval_js(Ctx, {file, FileName}, Timeout) ->
{ok, File} = file:read_file(FileName),
eval_js(Ctx, File, Timeout);
eval_js(Ctx, Js, Timeout) when is_binary(Js) ->
case call_driver(Ctx, "ej", [<<"<unnamed>">>, jsonify(Js)], Timeout) of
{ok, Result} ->
{ok, js_mochijson2:decode(Result)};
{error, ErrorJson} when is_binary(ErrorJson) ->
case js_mochijson2:decode(ErrorJson) of
{struct, [{<<"error">>, {struct, Error}}]} ->
{error, Error};
_ ->
{error, ErrorJson}
end;
{error, Error} ->
{error, Error}
end.
%% Internal functions
%% @private
jsonify(Code) when is_binary(Code) ->
{Body, <<LastChar:8>>} = split_binary(Code, size(Code) - 1),
C = case LastChar of
$; ->
Body;
_ ->
Code
end,
list_to_binary([<<"JSON.stringify(">>, C, <<");">>]).
%% @private
priv_dir() ->
%% Hacky workaround to handle running from a standard app directory
%% and .ez package
case code:priv_dir(erlang_js) of
{error, bad_name} ->
filename:join([filename:dirname(code:which(?MODULE)), "..", "priv"]);
Dir ->
Dir
end.
%% @private
call_driver(Ctx, Command, Args, Timeout) ->
CallToken = make_call_token(),
Marshalled = js_drv_comm:pack(Command, [CallToken] ++ Args),
port_command(Ctx, Marshalled),
Result = receive
{CallToken, ok} ->
ok;
{CallToken, ok, R} ->
{ok, R};
{CallToken, error, Error} ->
{error, Error}
after Timeout ->
{error, timeout}
end,
Result.
%% @private
make_call_token() ->
list_to_binary(integer_to_list(erlang:phash2(erlang:make_ref()))).
%% @private
json_converter() ->
FileName = filename:join([priv_dir(), "json2.js"]),
case js_cache:fetch(FileName) of
none ->
{ok, Contents} = file:read_file(FileName),
js_cache:store(FileName, Contents),
Contents;
Contents ->
Contents
end.