Gameatic.asc

// new module script
#define APROXCHAR 60
int bonePileCount;
Timer * t_killMember;
Timer * t_enemy2[APROXCHAR];  //time throwing
Timer * t_enemy2_whenToStartThrow[APROXCHAR];  //this number is only big enough to not crash
bool enemy2_didthrow[APROXCHAR];  //time throwing
Timer * t_afterTookHit;
int enemy3_iniy[APROXCHAR];

int destination_left;
int destination_right;

function game_start() 
{
  destination_left = 24 ;
  destination_right = 224 - 24;
}

void checkWinCondition(){
  if(bonePileCount >= 3){
    // damn you cute player, you won!
    
    Wait(SecondsToLoops(1.6));
    
    CustomTransition_FadeOut(1.0, eBlockTween);
    if(player.Room == 1){
      player.ChangeRoom(2, 21, 284, eDirectionRight);
    } else if(player.Room == 2){
      player.ChangeRoom(3, 21, 284, eDirectionRight);
    } else if(player.Room == 3){
      player.ChangeRoom(4, 21, 284, eDirectionRight);
    } else if(player.Room == 4){
      player.ChangeRoom(5, 21, 284, eDirectionRight);
    } else if(player.Room == 5){
      player.ChangeRoom(9, 21, 284, eDirectionRight);
    }
  }
}

bool isDogWithBonne(){
  return (player.View == DOGIDDLE2 || player.View == DOGWALK2 || player.NormalView == DOGWALK2) ; 
}

bool isCharEnemy1(Character * enemy){
  return enemy.ID == cEnemy1_0.ID ||   
         enemy.ID == cEnemy1_1.ID ||  
         enemy.ID == cEnemy1_2.ID ||   
         enemy.ID == cEnemy1_3.ID ||  
         enemy.ID == cEnemy1_4.ID ||  
         enemy.ID == cEnemy1_5.ID ||  
         enemy.ID == cEnemy1_6.ID ;
}

bool isCharEnemy2(Character * enemy){
  return enemy.ID == cEnemy2_0.ID ||   
         enemy.ID == cEnemy2_1.ID ||  
         enemy.ID == cEnemy2_2.ID ||  
         enemy.ID == cEnemy2_3.ID ||  
         enemy.ID == cEnemy2_4.ID ;
}

bool isCharEnemy3(Character * enemy){
  return enemy.ID == cEnemy3_0.ID ||   
         enemy.ID == cEnemy3_1.ID ||  
         enemy.ID == cEnemy3_2.ID ||  
         enemy.ID == cEnemy3_3.ID ;
}

void dogGainsBone(){
  if(!isDogWithBonne()){
    player.ChangeView(DOGWALK2);
    player.SetIdleView(DOGIDDLE2, 1);
    KeyboardMovement.SetIdleView(DOGIDDLE2, 1);   
  }
}

void dogLooseBone(){
  if(isDogWithBonne()){
    player.ChangeView(DOGWALK1);
    player.SetIdleView(DOGIDDLE1, 1);
    KeyboardMovement.SetIdleView(DOGIDDLE1, 1);   
  }
}

void updateBonePileGraphic(){
  if(bonePileCount == 0){
    cBonePile.ChangeView(BONEPILE0);
  } else if(bonePileCount == 1){
    cBonePile.ChangeView(BONEPILE1);
  } else if(bonePileCount == 2){
    cBonePile.ChangeView(BONEPILE2);
  } else if(bonePileCount == 3){
    cBonePile.ChangeView(BONEPILE3);
  } 
}

void resetBonePile(){
  bonePileCount = 0;
  updateBonePileGraphic();
} 

int incrementBonePile(){
  bonePileCount++;
  updateBonePileGraphic();
  checkWinCondition();
}

void dogHitBonePile(){
  if(isDogWithBonne()){
    dogLooseBone();
    incrementBonePile();
		aDog_from_hell_dog_pick_bone.Play();
  }
}

void rightAfterTookHit(){
  player.UnlockView();
  player.ChangeView(DOGWALK1);
  player.SetIdleView(DOGIDDLE1, 1);
  KeyboardMovement.SetIdleView(DOGIDDLE1, 1);    
}

void dogTookEnemyHit(){
  if(player.View == DOGTOOKHIT){
    return;  
  }
	
	aDog_from_hell_dog_hurt.Play();
  
  bool waswithbone = isDogWithBonne();
  
  player.LockView(DOGTOOKHIT, eStopMoving);
  if(waswithbone){
    SpawnBone(player.x+20, player.y+20);
  }
  player.TweenY(0.6, 284, eEaseInElasticTween, eNoBlockTween);
  t_afterTookHit = Timer.StartRT(0.6, eOnce);
}

void testDogBoneCollision(){
  Character * abone = whichBoneCollidesDog();
  if(abone==null){
    return;  
  }
  
  if(player.View == DOGTOOKHIT || player.View == DOGWALK2 || player.View == DOGIDDLE2){
    //a hitted dog, or a dog that already has a bone, can't collect a new bone
    return;
  }
  
  dogGainsBone();
  TrashBone(abone);
}

void splashArmsLegs(Character * enemy){
  int ox = enemy.x-30;
  int oy = enemy.y-70;
  float timeTw = 0.6;
  
  gLegs1.X = ox;
  gLegs2.X = ox;
  gArms1.X = ox;
  gArms2.X = ox;
  gLegs1.Y = oy;
  gLegs2.Y = oy;
  gArms1.Y = oy;
  gArms2.Y = oy;
  
  if(isCharEnemy1(enemy)){
    gLegs1.BackgroundGraphic = 49;
    gLegs2.BackgroundGraphic = 49;
    gArms1.BackgroundGraphic = 57;
    gArms2.BackgroundGraphic = 57;
    gLegs1.LockView(ENEMY1LEGS);
    gLegs2.LockView(ENEMY1LEGS);
    gArms1.LockView(ENEMY1ARMS);
    gArms2.LockView(ENEMY1ARMS);
    gLegs1.Animate(ENEMY1LEGS, 1, eRepeat, eNoBlock, eForwards);
    gLegs2.Animate(ENEMY1LEGS, 1, eRepeat, eNoBlock, eForwards);
    gArms1.Animate(ENEMY1ARMS, 1, eRepeat, eNoBlock, eForwards);
    gArms2.Animate(ENEMY1ARMS, 1, eRepeat, eNoBlock, eForwards);
  } else if(isCharEnemy2(enemy)){
    gLegs1.BackgroundGraphic = 87;
    gLegs2.BackgroundGraphic = 87;
    gArms1.BackgroundGraphic = 95;
    gArms2.BackgroundGraphic = 95;
    gLegs1.LockView(ENEMY2LEGS);
    gLegs2.LockView(ENEMY2LEGS);
    gArms1.LockView(ENEMY2ARMS);
    gArms2.LockView(ENEMY2ARMS);
    gLegs1.Animate(ENEMY2LEGS, 1, eRepeat, eNoBlock, eForwards);
    gLegs2.Animate(ENEMY2LEGS, 1, eRepeat, eNoBlock, eForwards);
    gArms1.Animate(ENEMY2ARMS, 1, eRepeat, eNoBlock, eForwards);
    gArms2.Animate(ENEMY2ARMS, 1, eRepeat, eNoBlock, eForwards);
  } else if(isCharEnemy3(enemy)){
    gLegs1.BackgroundGraphic = 122;
    gLegs2.BackgroundGraphic = 122;
    gArms1.BackgroundGraphic = 130;
    gArms2.BackgroundGraphic = 130;
    gLegs1.LockView(ENEMY3LEGS);
    gLegs2.LockView(ENEMY3LEGS);
    gArms1.LockView(ENEMY3ARMS);
    gArms2.LockView(ENEMY3ARMS);
    gLegs1.Animate(ENEMY3LEGS, 1, eRepeat, eNoBlock, eForwards);
    gLegs2.Animate(ENEMY3LEGS, 1, eRepeat, eNoBlock, eForwards);
    gArms1.Animate(ENEMY3ARMS, 1, eRepeat, eNoBlock, eForwards);
    gArms2.Animate(ENEMY3ARMS, 1, eRepeat, eNoBlock, eForwards);
  }
  
  gLegs1.Visible = true;
  gLegs2.Visible = true;
  gArms1.Visible = true;
  gArms2.Visible = true;
  
  gLegs1.TweenPosition(timeTw, Room.Width + Random(100), Room.Height + Random(100), eEaseInSineTween, eNoBlockTween);
  gLegs2.TweenPosition(timeTw, 0 -20 - Random(100), Room.Height + Random(100), eEaseInSineTween, eNoBlockTween);
  gArms1.TweenPosition(timeTw, Room.Width + Random(100), Room.Height + Random(100), eEaseInSineTween, eNoBlockTween);
  gArms2.TweenPosition(timeTw, -20- Random(100), Room.Height + Random(100), eEaseInSineTween, eNoBlockTween);
  t_killMember = Timer.StartRT(timeTw, eOnce);
}


void ChompEnemy(Character * enemy){
  if(player.NormalView == DOGWALK2){
    return;  
  }
  
	aDog_from_hell_dog_bite.Play();
	
  int chomp_delay = 2;
  int x_off = 18 ;
  int y_off =47 ;
  
  if(isCharEnemy1(enemy)){
    enemy.LockView(ENEMY1HIT, eStopMoving);  
  } else if(isCharEnemy2(enemy)){
    enemy.LockView(ENEMY2HIT, eStopMoving);
  } else if(isCharEnemy3(enemy)){
    enemy.LockView(ENEMY3HIT, eStopMoving);
  }
  
  gBlood.SetPosition(player.x - x_off, player.y - y_off);
  
  gBlood.Visible = true;
  gBlood.BackgroundGraphic = 66;
  gBlood.LockView(VIEWBLOOD);
  gBlood.Animate(0, 1, eOnce, eNoBlock, eForwards);
  
  gFakeOverlay.BackgroundGraphic = 1;
  gFakeOverlay.SetPosition(player.x - x_off, player.y - y_off);
  gFakeOverlay.Visible = true;
  Wait(chomp_delay);
  
  gFakeOverlay.BackgroundGraphic = 2;
  Wait(chomp_delay);  

  gFakeOverlay.BackgroundGraphic = 3;
  Wait(chomp_delay);
  
  gFakeOverlay.BackgroundGraphic = 4;
  Wait(chomp_delay);
  
  gBlood.Visible = false;
  gFakeOverlay.Visible = false;
  
  splashArmsLegs(enemy);
  //enemy.UnlockView();
  
  dogGainsBone();
  aDog_from_hell_dog_pick_bone.Play();
  enemy.ChangeRoom(TRASH);  
}

void DoChompOrHit(Character * enemy){
  if(isDogWithBonne()){
    dogTookEnemyHit(); 
    return;   
  }
  
  if((player.Loop == 1 && (player.Moving == false && !KeyboardMovement.Moving() )) &&
     (enemy.DestinationX == destination_left && enemy.Moving)){
  // dog is stopped looking left &
  // enemy is going left 
  
    dogTookEnemyHit(); 
    return;
    
  } else if((player.Loop != 1 && (player.Moving == false && !KeyboardMovement.Moving() )) &&
     (enemy.DestinationX == destination_right && enemy.Moving)){
  // dog is stopped looking right &
  // enemy is going right 
  
    dogTookEnemyHit(); 
    return;
  } else if((player.Loop == 1 && (player.Moving == true || KeyboardMovement.Moving() ))){
    //dog eating enemy at left while moving
    ChompEnemy(enemy); 
    return;
  } else if((player.Loop != 1 && (player.Moving == true || KeyboardMovement.Moving() ))){
    //dog eating enemy at left while moving
    ChompEnemy(enemy); 
    return;
  } 
}

void dealWithEnemy1(Character * enemy1){
  if(enemy1.Room != player.Room){
    return;  
  }  
  
   if(enemy1.DestinationX == destination_left && enemy1.Moving){
    
  } else if(enemy1.DestinationX == destination_right && enemy1.Moving){
    
  } else if(enemy1.x == destination_left && enemy1.View != ENEMY1HIT){
    enemy1.AddWaypoint(destination_right, enemy1.y);
  } else if(enemy1.x == destination_right && enemy1.View != ENEMY1HIT) {
    enemy1.AddWaypoint(destination_left , enemy1.y);    
  }
  
  if(enemy1.IsCollidingWithChar(player)== 1){
    DoChompOrHit(enemy1);
  }
}

// enemy walks around and occasionally pauses to throw letters 
void dealWithEnemy2(Character * enemy2){
  if(enemy2.Room != player.Room){
    return;  
  }
  
  
  if(enemy2.View == ENEMY2THROW){
    if(enemy2.Frame == 2){
      if(!enemy2_didthrow[enemy2.ID]){
        if( enemy2.Loop == 2){
         ThrowLetter(enemy2.x, enemy2.y, eDirectionRight);
        } else {
         ThrowLetter(enemy2.x, enemy2.y, eDirectionLeft);          
        }
      }
      
      enemy2_didthrow[enemy2.ID] = true;
    } else {
      enemy2_didthrow[enemy2.ID] = false;
    }
  }
  
  
  if(t_enemy2_whenToStartThrow[enemy2.ID] != null && t_enemy2_whenToStartThrow[enemy2.ID].EvtExpired){
    t_enemy2_whenToStartThrow[enemy2.ID] = null;
    
    t_enemy2[enemy2.ID] = Timer.StartRT(1.9, eOnce);
  }
  
  
  if(t_enemy2[enemy2.ID] != null && t_enemy2[enemy2.ID].EvtExpired){
    t_enemy2[enemy2.ID] = null;
    if(enemy2.View == ENEMY2THROW){
      enemy2.UnlockView();
    }
    
    enemy2.PlaceOnWalkableArea();
    if(enemy2.Loop == 2){
      //looking right
      enemy2.AddWaypoint(destination_right, enemy2.y);      
    } else {
      //looking left maybe
      enemy2.AddWaypoint(destination_left , enemy2.y);    
    }
    
  }  
  
  if(t_enemy2[enemy2.ID] != null && enemy2.View != ENEMY2THROW){
    enemy2.LockView(ENEMY2THROW, eStopMoving);
    enemy2.Animate(enemy2.Loop, 4, eRepeat, eNoBlock);
  } else if(t_enemy2[enemy2.ID] != null && enemy2.View == ENEMY2THROW) {
    
  } else {
    if(t_enemy2_whenToStartThrow[enemy2.ID] == null ){
      t_enemy2_whenToStartThrow[enemy2.ID] = Timer.StartRT(0.5+IntToFloat(Random(8))*0.1, eOnce);
    }  
    
    
    if(enemy2.DestinationX == destination_left && enemy2.Moving){
      
    } else if(enemy2.DestinationX == destination_right && enemy2.Moving){
      
    } else if(enemy2.x == destination_left && enemy2.View != ENEMY2HIT){
      enemy2.AddWaypoint(destination_right, enemy2.y);
    } else if(enemy2.x == destination_right && enemy2.View != ENEMY2HIT) {
      enemy2.AddWaypoint(destination_left , enemy2.y);    
    }
    
  }
  
  
  if(enemy2.IsCollidingWithChar(player)== 1){
    DoChompOrHit(enemy2);
  }
}

void checkBonePileRepExe(){
  if(cBonePile.IsCollidingWithChar(player)){
    dogHitBonePile();
  } 
}

void dealWithEnemy3(Character * enemy3){
  if(enemy3.Room != player.Room){
    return;  
  }  
  
  enemy3.y = enemy3_iniy[enemy3.ID]+FloatToInt(52.0*Maths.Sin(IntToFloat(getFrameNumber()%120)*Maths.Pi/120.0));
  
   if(enemy3.DestinationX == destination_left && enemy3.Moving){
    
  } else if(enemy3.DestinationX == destination_right && enemy3.Moving){
    
  } else if(enemy3.x == destination_left && enemy3.View != ENEMY3HIT){
    enemy3.AddWaypoint(destination_right, enemy3.y);
  } else if(enemy3.x == destination_right && enemy3.View != ENEMY3HIT) {
    enemy3.AddWaypoint(destination_left , enemy3.y);    
  }
  
  if(AreThingsOverlapping(enemy3.ID, player.ID)>= 5){
    DoChompOrHit(enemy3);
  }
}


void init_enemy1(Character * enemy1){
  enemy1.AddWaypoint(destination_left, enemy1.y);  
}

void init_enemy2(Character * enemy2){
  enemy2.AddWaypoint(destination_left, enemy2.y);  
}

void init_enemy3(Character * enemy3){
  enemy3.AddWaypoint(destination_left, enemy3.y);  
  enemy3_iniy[enemy3.ID] =  enemy3.y;
}

void repeatedly_execute_always(){
  Character * aLetter = whichLetterCollided();
  if(aLetter!=null){
    dogTookEnemyHit();  
  }
  
  testDogBoneCollision();

  if(t_afterTookHit != null && t_afterTookHit.EvtExpired){
    rightAfterTookHit();  
  }

  if(t_killMember!=null && t_killMember.EvtExpired){
    gLegs1.UnlockView();
    gLegs2.UnlockView();
    gArms1.UnlockView();
    gArms2.UnlockView();
    
  }  
}

void resetTimers(){
  int i=0;
  
  while(i<APROXCHAR){
    t_enemy2[i]=null;  //time throwing
    t_enemy2_whenToStartThrow[i]=null;  //this number is only big enough to not crash
    enemy2_didthrow[i]=false;
    i++;  
  }


}

void on_event (EventType event, int data){
  if(event == eEventLeaveRoom){
    resetBonePile();  
    resetTimers();
  }
}