-
Notifications
You must be signed in to change notification settings - Fork 6
/
Calc.ahk
207 lines (207 loc) · 8.07 KB
/
Calc.ahk
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
/*
@Example
MsgBox Calc("(1 + 2) * 3 / 4")
MsgBox Calc("1 == (3 - 2) && 0 != 0.0001")
MsgBox Calc("1 << 8 & 0xFF + 1")
MsgBox Calc("10 % 3")
MsgBox Calc("Log(1.2) + Sqrt(3)")
*/
Calc(expr) {
pos := 1
t := NextToken()
ast := Expression()
return VisitNode(ast)
/*
Expression -> ConditionalExpression EOF
ConditionalExpression -> LogicOrExpression
ConditionalExpression -> LogicOrExpression ? LogicOrExpression : ConditionalExpression
LogicOrExpression -> LogicAndExpression
LogicOrExpression -> LogicOrExpression || LogicAndExpression
LogicAndExpression -> BitwiseOrExpression
LogicAndExpression -> LogicAndExpression && BitwiseOrExpression
BitwiseOrExpression -> BitwiseXorExpression
BitwiseOrExpression -> BitwiseOrExpression | BitwiseXorExpression
BitwiseXorExpression -> BitwiseAndExpression
BitwiseXorExpression -> BitwiseXorExpression ^ BitwiseAndExpression
BitwiseAndExpression -> EqualityExpression
BitwiseAndExpression -> BitwiseAndExpression & EqualityExpression
EqualityExpression -> RelationalExpression
EqualityExpression -> EqualityExpression == RelationalExpression
EqualityExpression -> EqualityExpression != RelationalExpression
RelationalExpression -> ShiftExpression
RelationalExpression -> RelationalExpression > ShiftExpression
RelationalExpression -> RelationalExpression >= ShiftExpression
RelationalExpression -> RelationalExpression < ShiftExpression
RelationalExpression -> RelationalExpression <= ShiftExpression
ShiftExpression -> AdditiveExpression
ShiftExpression -> ShiftExpression << AdditiveExpression
ShiftExpression -> ShiftExpression >> AdditiveExpression
ShiftExpression -> ShiftExpression >>> AdditiveExpression
AdditiveExpression -> MultiplicativeExpression
AdditiveExpression -> AdditiveExpression + MultiplicativeExpression
AdditiveExpression -> AdditiveExpression - MultiplicativeExpression
MultiplicativeExpression -> UnaryExpression
MultiplicativeExpression -> MultiplicativeExpression * UnaryExpression
MultiplicativeExpression -> MultiplicativeExpression / UnaryExpression
MultiplicativeExpression -> MultiplicativeExpression // UnaryExpression
MultiplicativeExpression -> MultiplicativeExpression % UnaryExpression
UnaryExpression -> PowerExpression
UnaryExpression -> +UnaryExpression
UnaryExpression -> -UnaryExpression
UnaryExpression -> !UnaryExpression
UnaryExpression -> ~UnaryExpression
PowerExpression -> FuncCallExpression
PowerExpression -> PowerExpression ** FuncCallExpression
FuncCallExpression -> PrimaryExpression
FuncCallExpression -> name(ParameterList)
ParameterList -> e
ParameterList -> ConditionalExpression
ParameterList -> ParameterList, ConditionalExpression
PrimaryExpression -> NUMBER | (ConditionalExpression)
*/
Expression() {
node := ConditionalExpression()
Expect("EOF")
return node
}
ConditionalExpression() {
sub1 := LogicOrExpression()
if t.Kind == "?" {
t := NextToken()
sub2 := LogicOrExpression()
Expect(":")
sub3 := ConditionalExpression()
node := { Kind: "?:", Subs: [sub1, sub2, sub3] }
sub1 := node
}
return sub1
}
LogicOrExpression() => BinaryExpression(LogicAndExpression, "||")
LogicAndExpression() => BinaryExpression(BitwiseOrExpression, "&&")
BitwiseOrExpression() => BinaryExpression(BitwiseXorExpression, "|")
BitwiseXorExpression() => BinaryExpression(BitwiseAndExpression, "^")
BitwiseAndExpression() => BinaryExpression(EqualityExpression, "&")
EqualityExpression() => BinaryExpression(RelationalExpression, "== !=")
RelationalExpression() => BinaryExpression(ShiftExpression, "> >= < <=")
ShiftExpression() => BinaryExpression(AdditiveExpression, "<< >> >>>")
AdditiveExpression() => BinaryExpression(MultiplicativeExpression, "+ -")
MultiplicativeExpression() => BinaryExpression(UnaryExpression, "* / // %")
UnaryExpression() {
if t.Kind == "+" || t.Kind == "-" {
node := { Kind: "u" t.Kind, Subs: [] }
t := NextToken()
node.Subs.Push(UnaryExpression())
}
else if t.Kind == "!" || t.Kind == "~" {
node := { Kind: t.Kind, Subs: [] }
t := NextToken()
node.Subs.Push(UnaryExpression())
}
else
node := PowerExpression()
return node
}
PowerExpression() => BinaryExpression(FuncCallExpression, "**")
FuncCallExpression() {
if t.Kind == "NAME" {
node := { Kind: t.Kind, Value: t.Value }
t := NextToken()
Expect("(")
node.Subs := ParameterList()
Expect(")")
}
else
node := PrimaryExpression()
return node
}
ParameterList() {
list := []
if t.Kind !== ")" {
list.Push(ConditionalExpression())
while t.Kind == "," {
t := NextToken()
list.Push(ConditionalExpression())
}
}
return list
}
PrimaryExpression() {
if t.Kind == "NUMBER" {
node := { Kind: t.Kind, Value: t.Value }
t := NextToken()
}
else if t.Kind == "(" {
t := NextToken()
node := ConditionalExpression()
Expect(")")
}
else
throw Error("syntax error")
return node
}
BinaryExpression(subExprProc, operators) {
sub1 := subExprProc()
while operators ~= "(?:\s|^)\" t.Kind "(?:\s|$)" {
node := { Kind: t.Kind, Subs: [sub1] }
t := NextToken()
node.Subs.Push(subExprProc())
sub1 := node
}
return sub1
}
VisitNode(node) {
if node.Kind == "NUMBER"
return Number(node.Value)
nums := []
for sub in node.Subs
nums.Push(VisitNode(sub))
switch node.Kind {
case "?:": return nums[1] ? nums[2] : nums[3]
case "||": return nums[1] || nums[2]
case "&&": return nums[1] && nums[2]
case "|": return nums[1] | nums[2]
case "^": return nums[1] ^ nums[2]
case "&": return nums[1] & nums[2]
case "==": return nums[1] == nums[2]
case "!=": return nums[1] != nums[2]
case ">": return nums[1] > nums[2]
case ">=": return nums[1] >= nums[2]
case "<": return nums[1] < nums[2]
case "<=": return nums[1] <= nums[2]
case "<<": return nums[1] << nums[2]
case ">>": return nums[1] >> nums[2]
case ">>>": return nums[1] >>> nums[2]
case "+": return nums[1] + nums[2]
case "-": return nums[1] - nums[2]
case "*": return nums[1] * nums[2]
case "/": return nums[1] / nums[2]
case "//": return nums[1] // nums[2]
case "%": return Mod(nums[1], nums[2])
case "u+": return +nums[1]
case "u-": return -nums[1]
case "!": return !nums[1]
case "~": return ~nums[1]
case "**": return nums[1] ** nums[2]
case "NAME": return %node.Value%(nums*)
}
}
NextToken() {
if tokenPos := RegExMatch(expr, "S)\G\s*(?:(?<NUMBER>0[xX][0-9a-fA-F]+|\d+(?:\.\d+)?(?:e-?\d+)?)|(?<OPERATOR>>>>|<<|>>|<=|>=|==|!=|&&|\|\||\/\/|\*\*|[()+\-*\/!~%<>&^|?:,])|(?<NAME>[a-zA-Z\x{0080}-\x{ffff}][\w\x{0080}-\x{ffff}]*)|$)", &m, pos) {
pos := tokenPos + m.Len
if m["NUMBER"] != ""
return { Kind: "NUMBER", Value: m["NUMBER"] }
else if m["NAME"] != ""
return { Kind: "NAME", Value: m["NAME"] }
else if m["OPERATOR"] != ""
return { Kind: m["OPERATOR"] }
else
return { Kind: "EOF" }
}
throw Error('illegal character: "' SubStr(expr, pos, 1) '"')
}
Expect(kind) {
if t.Kind != kind
throw Error('expected "' kind '"')
t := NextToken()
}
}