library.gradle

android {
    compileSdkVersion compileVersion

    defaultConfig {
        minSdkVersion obtainMinSdkVersion()
        targetSdkVersion compileVersion
        versionCode 1
        versionName "8.12.0-SNAPSHOT"
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        consumerProguardFiles "consumer-rules.pro"
    }

    testOptions {
        unitTests.includeAndroidResources = true
        unitTests.all {
            maxHeapSize = "1024m"
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
    kotlinOptions {
        jvmTarget = '1.8'
    }
}

project.afterEvaluate {
    // Remove afterEvaluate
    // after https://github.com/Kotlin/kotlinx-kover/issues/362 is fixed
    project.pluginManager.apply("org.jetbrains.kotlinx.kover")
}

def obtainMinSdkVersion() {
    def result = minVersion

    if (project.hasProperty("minSdkVersion")) {
        result = project.getProperties().get("minSdkVersion").toInteger()
    }

    result
}