-
Notifications
You must be signed in to change notification settings - Fork 2
/
tutorial_8_advPixies.asm
1527 lines (1237 loc) · 28 KB
/
tutorial_8_advPixies.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
// ------------------------------------------------------------
//
// Tutorial 8 - 8 way parallax scrolling with Pixies.
//
// Shows how to add Pixies on top of multiple RRB layers.
//
// Tile and Attrib data are DMA'd into the screen RRB layout and the GOTOX position for
// each row is set accordingly.
//
//
.file [name="tutorial_8_advPixies.prg", segments="Code,Data"]
// Color RAM is at a fixed base address
//
.const COLOR_RAM = $ff80000
// ------------------------------------------------------------
//
.segmentdef Zeropage [start=$02, min=$02, max=$fb, virtual]
.segmentdef Code [start=$2001, max=$cfff]
.segmentdef Data [start=$4000, max=$cfff]
.segmentdef BSS [start=$e000, max=$f400, virtual]
.segmentdef MappedPixieWorkRam [start=$4000, max=$7fff, virtual]
.segmentdef ScreenRam [start=$50000, virtual]
.segmentdef PixieWorkRam [start=$58000, virtual]
.cpu _45gs02
// ------------------------------------------------------------
// Defines to describe the screen size
//
// If you use H320 then SCREEN_WIDTH much be <= 360, otherwise <= 720
#define H320
.const SCREEN_WIDTH = 320
// If you use V200 then SCREEN_HEIGHT much be <= 240
#define V200
.const SCREEN_HEIGHT = 200
// ------------------------------------------------------------
#import "mega65macros.asm"
// Figure out how many characters wide and high the visible area is
//
.const CHARS_WIDE = (SCREEN_WIDTH / 16) + 1 // NCM chars are 16 pixels wide
// Add one extra characters to show as we shift off left side
.const NUM_ROWS = (SCREEN_HEIGHT / 8)
// LOGICAL_LAYER_SIZE is the number of bytes the VIC-IV uses for one layer
//
.const LOGICAL_LAYER_SIZE = (2 + (CHARS_WIDE * 2))
.const NUM_LAYERS = 4
// LOGICAL_PIXIE_SIZE is the number of bytes reserved for pixies on each row, at a minimum,
// one pixie is a GOTOX + CHAR (2 words)
//
.const NUM_PIXIEWORDS = 160
.const LOGICAL_PIXIE_SIZE = 2 * (NUM_PIXIEWORDS)
// LOGICAL_EOL_SIZE is the end of line marker, this consists of a GOTOX(SCREEN_WIDTH) + CHAR
// this end of line set are needed to ensure that all of the line is visible as the RRB
// system will only draw up to the position of the last character.
.const LOGICAL_EOL_SIZE = 2 * (2)
// LOGICAL_ROW_SIZE is the number of bytes the VIC-IV advances each row
//
.const LOGICAL_ROW_SIZE = (LOGICAL_LAYER_SIZE * NUM_LAYERS) + LOGICAL_PIXIE_SIZE + LOGICAL_EOL_SIZE
.const LOGICAL_NUM_ROWS = NUM_ROWS
.print ("LOGICAL_ROW_SIZE = " + LOGICAL_ROW_SIZE)
// ------------------------------------------------------------
//
.const MAP_WIDTH = (512 / 16)
.const MAP_HEIGHT = (SCREEN_HEIGHT / 8) * 2
// MAP_LOGICAL_SIZE is the number of bytes each row takes in the map / attrib data
//
.const MAP_LOGICAL_SIZE = MAP_WIDTH * 2
// ------------------------------------------------------------
//
.const NUM_OBJS1 = 256
.const NUM_OBJS2 = 256
.const NUM_OBJS3 = 256
// ------------------------------------------------------------
//
.segment Zeropage "Main zeropage"
Tmp: .word $0000,$0000
Tmp1: .word $0000,$0000
Tmp2: .word $0000,$0000
Tmp3: .word $0000,$0000
Tmp4: .word $0000,$0000
FrameCount: .byte $00
AnimCount: .byte $00
ScrollX1: .byte $00,$00
ScrollX2: .byte $00,$00
ScrollY1: .byte $00,$00
ScrollY2: .byte $00,$00
ShiftOffsetsL: .byte $00, $00, $00, $00
ShiftOffsetsH: .byte $00, $00, $00, $00
LayerMasks: .byte $00,$00,$00,$00
YShift: .byte $00,$00,$00,$00
ObjPosX: .byte $00,$00
ObjPosY: .byte $00,$00
ObjChar: .byte $00,$00
// ------------------------------------------------------------
//
.segment Code
BasicUpstart65(Entry)
* = $2016
.segment Code "Entry"
Entry: {
jsr System.InitM65
// Update screen positioning based on PAL/NTSC
jsr System.CenterFrameHorizontally
jsr System.CenterFrameVertically
jsr System.InitVideoMode
VIC4_SetRowWidth(LOGICAL_ROW_SIZE)
VIC4_SetNumCharacters(LOGICAL_ROW_SIZE/2)
VIC4_SetNumRows(NUM_ROWS)
VIC4_SetScreenPtr(ScreenRam)
jsr InitPalette
// We only need to update EOL data once as it never changes
//
jsr UpdateLayerData.UpdateLayerEOL
lda #$00
sta $d020
lda #$00
sta $d021
_set16im(0, ScrollX1)
_set16im(0, ScrollX2)
_set16im(0, ScrollY1)
_set16im(0, ScrollY2)
jsr CopyMap3to4
jsr InitObjData
// Main loop
mainloop:
// Wait for (H400) rasterline $07
!: lda $d053
and #$07
cmp.zp System.BotBorder+1
bne !-
lda.zp System.BotBorder+0
cmp $d052
bne !-
!: cmp $d052
beq !-
lda #$04
sta $d020
// Layer1 : Calculate how much to shift the layer row off the left size
ldx #$00
lda ScrollX1
jsr UpdateShiftAmount
ldx #$01
lda ScrollX1
jsr UpdateShiftAmount
// Layer2 : Calculate how much to shift the layer row off the left size
ldx #$02
lda ScrollX2
jsr UpdateShiftAmount
ldx #$03
lda ScrollX2
jsr UpdateShiftAmount
// Update the GOTOX position for all layers using the offsets calculated above
jsr UpdateLayerPositions
// Update the tile / attrib data using DMA
jsr UpdateLayerData.UpdateLayer1
jsr UpdateLayerData.UpdateLayer2
jsr UpdateLayerData.UpdateLayer3
jsr UpdateLayerData.UpdateLayer4
// Update Pixie data using DMA
jsr UpdateLayerData.UpdateLayerPixies
lda #$08
sta $d020
inc FrameCount
// Do some sin/cos based scrolling for the 2 layers
ldx FrameCount
lda sintable,x
sta ScrollX1
sta ScrollY2
lda costable,x
sta ScrollX2
sta ScrollY1
// Clear the work Pixie ram using DMA
jsr ClearWorkPixies
inc AnimCount
lda #$00
sta ObjPosY+1
// Map PixieWorkRam (at $54000) into MappedPixieWorkRam (at $4000)
mapLo(PixieWorkTiles, MappedPixieWorkTiles, $0c)
mapHi(PixieWorkTiles+$4000, MappedPixieWorkTiles+$4000, $03)
map
eom
_set16im((Sprites/64), ObjChar) // Start charIndx with first pixie char
// Add Objs into the work ram here
//
ldx #$00
!:
clc
lda Objs1PosXLo,x
adc Objs1VelX,x
sta Objs1PosXLo,x
clc
lda Objs1PosYLo,x
adc Objs1VelY,x
sta Objs1PosYLo,x
clc
lda Objs1PosXLo,x
adc #32
sta ObjPosX+0
lda #$00
adc #$00
sta ObjPosX+1
lda Objs1PosYLo,x
sta ObjPosY+0
phx
jsr AddObj
plx
inx
cpx #NUM_OBJS1
bne !-
_set16im((Sprites/64)+2, ObjChar) // Start charIndx with first pixie char
// Add Objs into the work ram here
//
ldx #$00
!:
clc
lda Objs2PosXLo,x
adc Objs2VelX,x
sta Objs2PosXLo,x
clc
lda Objs2PosYLo,x
adc Objs2VelY,x
sta Objs2PosYLo,x
clc
lda Objs2PosXLo,x
adc #32
sta ObjPosX+0
lda #$00
adc #$00
sta ObjPosX+1
lda Objs2PosYLo,x
sta ObjPosY+0
phx
jsr AddObj
plx
inx
cpx #NUM_OBJS2
bne !-
_set16im((Sprites/64), ObjChar) // Start charIndx with first pixie char
// Add Objs into the work ram here
//
ldx #$00
!:
clc
lda Objs3PosXLo,x
adc Objs3VelX,x
sta Objs3PosXLo,x
clc
lda Objs3PosYLo,x
adc Objs3VelY,x
sta Objs3PosYLo,x
clc
lda Objs3PosXLo,x
adc #32
sta ObjPosX+0
lda #$00
adc #$00
sta ObjPosX+1
lda Objs3PosYLo,x
sta ObjPosY+0
phx
jsr AddObj
plx
inx
cpx #NUM_OBJS3
bne !-
unmapMemory()
lda #$00
sta $d020
jmp mainloop
}
// ------------------------------------------------------------
//
InitObjData:
{
.var xpos = Tmp // 8bit
.var ypos = Tmp+2 // 8bit
// Init Obj group 1
//
//
_set8im(0, xpos)
_set8im(0, ypos)
ldx #$00
iloop1:
lda xpos
sta Objs1PosXLo,x
lda ypos
sta Objs1PosYLo,x
lda #1
sta Objs1VelY,x
txa
and #$01
bne ip1
lda #$ff
bra id1
ip1:
lda #$01
id1:
sta Objs1VelX,x
_add8im(xpos, -28, xpos)
_add8im(ypos, 10, ypos)
inx
cpx #NUM_OBJS1
bne iloop1
// Init Obj group 2
//
//
_set8im(0, xpos)
_set8im(0, ypos)
ldx #$00
iloop2:
lda xpos
sta Objs2PosXLo,x
lda ypos
sta Objs2PosYLo,x
lda #$ff
sta Objs2VelY,x
txa
and #$01
bne ip2
lda #$ff
bra id2
ip2:
lda #$01
id2:
sta Objs2VelX,x
_add8im(xpos, 28, xpos)
_add8im(ypos, 10, ypos)
inx
cpx #NUM_OBJS2
bne iloop2
// Init Obj group 2
//
//
_set8im(0, xpos)
_set8im(0, ypos)
ldx #$00
iloop3:
lda xpos
sta Objs3PosXLo,x
lda ypos
sta Objs3PosYLo,x
lda #1
sta Objs3VelY,x
txa
and #$01
bne ip3
lda #$fe
bra id3
ip3:
lda #$02
id3:
sta Objs3VelX,x
_add8im(xpos, 17, xpos)
_add8im(ypos, 10, ypos)
inx
cpx #NUM_OBJS3
bne iloop3
rts
}
// ------------------------------------------------------------
//
yShiftTable: .byte 0<<5,7<<5,6<<5,5<<5,4<<5,3<<5,2<<5,1<<5
yMaskTable: .byte %11111111,%11111110,%11111100,%11111000,%11110000,%11100000,%11000000,%10000000
AddObj:
{
.var tilePtr = Tmp // 16bit
.var attribPtr = Tmp+2 // 16bit
.var charIndx = Tmp1+0 // 16bit
.var yShift = Tmp1+2 // 8bit
.var gotoXmask = Tmp2 // 8bit
_set16(ObjChar, charIndx) // Start charIndx with first pixie char
lda ObjPosY+0 // Find sub row y offset (0 - 7)
and #$07
tay
lda yMaskTable,y // grab the rowMask value
sta gotoXmask
lda yShiftTable,y // grab the yShift value
sta yShift
beq !+ // if (yShift != 0) charIndx--
dew charIndx
!:
// Calculate which row to add pixie data to, put this in X,
// we use this to index the row tile / attrib ptrs
//
lda ObjPosY+0
lsr
lsr
lsr
dec
dec
tax // move yRow into X reg
bmi middleRow
cpx #NUM_ROWS
lbcs done
// Top character, this uses the first mask from the tables above,
// grab tile and attrib ptr for this row and advance by the 4 bytes
// that we will write per row.
//
clc // grab and advance tilePtr
lda PixieRowScreenPtrLo,x
sta tilePtr+0
adc #$04
sta PixieRowScreenPtrLo,x
lda PixieRowScreenPtrHi,x
sta tilePtr+1
adc #$00
sta PixieRowScreenPtrHi,x
clc // grab and advance attribPtr
lda PixieRowAttribPtrLo,x
sta attribPtr+0
adc #$04
sta PixieRowAttribPtrLo,x
lda PixieRowAttribPtrHi,x
sta attribPtr+1
adc #$00
sta PixieRowAttribPtrHi,x
// GOTOX
ldz #$00
lda ObjPosX+0 // tile = <xpos,>xpos | yShift
sta (tilePtr),z
lda #$98 // attrib = $98 (transparent+gotox+rowmask), gotoXmask
sta (attribPtr),z
inz
lda ObjPosX+1
and #$03
ora yShift
sta (tilePtr),z
lda gotoXmask
sta (attribPtr),z
inz
// Char
lda charIndx+0
sta (tilePtr),z
lda #$08
sta (attribPtr),z
inz
lda charIndx+1
sta (tilePtr),z
lda #$1f
sta (attribPtr),z
middleRow:
// Advance to next row and charIndx
inw charIndx
inx
bmi bottomRow
cpx #NUM_ROWS
lbcs done
// Middle character, yShift is the same as first char but full character is drawn so disable rowmask,
// grab tile and attrib ptr for this row and advance by the 4 bytes
// that we will write per row.
//
clc // grab and advance tilePtr
lda PixieRowScreenPtrLo,x
sta tilePtr+0
adc #$04
sta PixieRowScreenPtrLo,x
lda PixieRowScreenPtrHi,x
sta tilePtr+1
adc #$00
sta PixieRowScreenPtrHi,x
clc // grab and advance attribPtr
lda PixieRowAttribPtrLo,x
sta attribPtr+0
adc #$04
sta PixieRowAttribPtrLo,x
lda PixieRowAttribPtrHi,x
sta attribPtr+1
adc #$00
sta PixieRowAttribPtrHi,x
// GOTOX
ldz #$00
lda ObjPosX+0 // tile = <xpos,>xpos | yShift
sta (tilePtr),z
lda #$90 // attrib = $98 (transparent+gotox), $00
sta (attribPtr),z
inz
lda ObjPosX+1
and #$03
ora yShift
sta (tilePtr),z
lda #$ff
sta (attribPtr),z
inz
// Char
lda charIndx+0
sta (tilePtr),z
lda #$08
sta (attribPtr),z
inz
lda charIndx+1
sta (tilePtr),z
lda #$1f
sta (attribPtr),z
bottomRow:
// If we have a yShift of 0 we only need to add to 2 rows, skip the last row!
//
lda yShift
beq done
// Advance to next row and charIndx
inw charIndx
inx
bmi done
cpx #NUM_ROWS
lbcs done
// Bottom character, yShift is the same as first char but flip the bits of the gotoXmask,
// grab tile and attrib ptr for this row and advance by the 4 bytes
// that we will write per row.
//
clc // grab and advance tilePtr
lda PixieRowScreenPtrLo,x
sta tilePtr+0
adc #$04
sta PixieRowScreenPtrLo,x
lda PixieRowScreenPtrHi,x
sta tilePtr+1
adc #$00
sta PixieRowScreenPtrHi,x
clc // grab and advance tilePtr
lda PixieRowAttribPtrLo,x
sta attribPtr+0
adc #$04
sta PixieRowAttribPtrLo,x
lda PixieRowAttribPtrHi,x
sta attribPtr+1
adc #$00
sta PixieRowAttribPtrHi,x
lda gotoXmask
eor #$ff
sta gotoXmask
// GOTOX
ldz #$00
lda ObjPosX+0 // tile = <xpos,>xpos | yShift
sta (tilePtr),z
lda #$98 // attrib = $98 (transparent+gotox+rowmask), gotoXmask
sta (attribPtr),z
inz
lda ObjPosX+1
and #$03
ora yShift
sta (tilePtr),z
lda gotoXmask
sta (attribPtr),z
inz
// Char
lda charIndx+0
sta (tilePtr),z
lda #$08
sta (attribPtr),z
inz
lda charIndx+1
sta (tilePtr),z
lda #$1f
sta (attribPtr),z
done:
rts
}
// ------------------------------------------------------------
// Calculate the GOTOX position, this is 0 - (scrollPos & $0f)
//
UpdateShiftAmount:
{
and #$0f
sta ul2xscroll
sec
lda #0
sbc ul2xscroll:#$00
sta ShiftOffsetsL,x
lda #0
sbc #0
and #$03
sta ShiftOffsetsH,x
rts
}
// ------------------------------------------------------------
// Update the RRB GOTOX value for each of the layers
//
// loop X through each layer
// loop Y through each row
//
//shiftMasks: .byte $ff,$fe,$fc,$f8,$f0,$e0,$c0,$80
shiftMasks: .byte %11111111,%01111111,%00111111,%00011111,%00001111,%00000111,%00000011,%00000001,%00000000
UpdateLayerPositions:
{
.var tileLayerPtr = Tmp // 32bit
.var tileRowPtr = Tmp1 // 32bit
.var attribLayerPtr = Tmp2 // 32bit
.var attribRowPtr = Tmp3 // 32bit
.var gotoXmarker = Tmp4 // 8bit
// Start layerPtr at top left GOTOX token
_set32im(ScreenRam, tileLayerPtr)
_set32im(COLOR_RAM, attribLayerPtr)
// set GotoX info
lda #$18
sta gotoXmarker
// Parallax layer 1 (layers 0 & 1)
lda ScrollY1
and #$07
sta YShift+0
tax
lda shiftMasks,x
sta LayerMasks+0
eor #$ff
sta LayerMasks+1
// Parallax layer 2 (layers 2 & 3)
lda ScrollY2
and #$07
sta YShift+2
tax
lda shiftMasks,x
sta LayerMasks+2
eor #$ff
sta LayerMasks+3
// shift yshift left 5 times
lda YShift+0
asl
asl
asl
asl
asl
sta YShift+0
sta YShift+1
// shift yshift left 5 times
lda YShift+2
asl
asl
asl
asl
asl
sta YShift+2
sta YShift+3
// Update all layers
ldx #$00
layerLoop:
// Copy layerPtr to rowPtr
_set32(tileLayerPtr, tileRowPtr)
_set32(attribLayerPtr, attribRowPtr)
// Update GOTOX position for each row in this layer
ldy #$00
rowLoop:
ldz #$00
lda ShiftOffsetsL,x // Update Byte0 of layer row
sta ((tileRowPtr)),z
lda gotoXmarker
sta ((attribRowPtr)),z
inz
lda YShift,x // Get (FCM char data Y offset)
ora ShiftOffsetsH,x // Update Byte1 of layer row
sta ((tileRowPtr)),z
lda LayerMasks,x
sta ((attribRowPtr)),z
// Advance row pointers to the next logical row
_add32im(tileRowPtr, LOGICAL_ROW_SIZE, tileRowPtr)
_add32im(attribRowPtr, LOGICAL_ROW_SIZE, attribRowPtr)
iny
cpy #LOGICAL_NUM_ROWS
bne rowLoop
// Advance layer pointer to the next logical layer
_add32im(tileLayerPtr, LOGICAL_LAYER_SIZE, tileLayerPtr)
_add32im(attribLayerPtr, LOGICAL_LAYER_SIZE, attribLayerPtr)
lda gotoXmarker
ora #$80
sta gotoXmarker
inx
cpx #NUM_LAYERS
lbne layerLoop
rts
}
// ------------------------------------------------------------
//
ClearWorkPixies: {
.var rowScreenPtr = Tmp // 16bit
.var rowAttribPtr = Tmp+2 // 16bit
_set16im(MappedPixieWorkTiles, rowScreenPtr)
_set16im(MappedPixieWorkAttrib, rowAttribPtr)
// Clear the RRBIndex list
ldx #0
!:
lda rowScreenPtr+0
sta PixieRowScreenPtrLo,x
lda rowScreenPtr+1
sta PixieRowScreenPtrHi,x
lda rowAttribPtr+0
sta PixieRowAttribPtrLo,x
lda rowAttribPtr+1
sta PixieRowAttribPtrHi,x
_add16im(rowScreenPtr, LOGICAL_PIXIE_SIZE, rowScreenPtr)
_add16im(rowAttribPtr, LOGICAL_PIXIE_SIZE, rowAttribPtr)
inx
cpx #NUM_ROWS
bne !-
// Clear the working pixie data using DMA
RunDMAJob(Job)
rts
Job:
DMAHeader(ClearPixieTile>>20, PixieWorkTiles>>20)
.for(var r=0; r<NUM_ROWS; r++) {
// Tile
DMACopyJob(
ClearPixieTile,
PixieWorkTiles + (r * LOGICAL_PIXIE_SIZE),
LOGICAL_PIXIE_SIZE,
true, false)
// Atrib
DMACopyJob(
ClearPixieAttrib,
PixieWorkAttrib + (r * LOGICAL_PIXIE_SIZE),
LOGICAL_PIXIE_SIZE,
(r!=(NUM_ROWS-1)), false)
}
.print ("RRBClear DMAjob = " + (* - Job))
}
// ------------------------------------------------------------
// To update the tile / attrib data for the scrolling layers we need to DMA
// data from the Map into the screen, this is done as a DMA for each row,
// one for tiles and one for attribs.
//
colTabL:
.fill 32, <(MAP_LOGICAL_SIZE * i)
colTabH:
.fill 32, >(MAP_LOGICAL_SIZE * i)
UpdateLayerData: {
.var src_tile_ptr = Tmp // 32bit
.var src_attrib_ptr = Tmp1 // 32bit
.var dst_offset = Tmp2 // 16bit
.var copy_length = Tmp2+2 // 16bit
.var src_offset = Tmp3 // 16bit
.var src_stride = Tmp3+2 // 16bit
.var scrollY = Tmp4 // 16bit
UpdateLayer1: {
_set32im(MapRam, src_tile_ptr)
_set32im(AttribRam, src_attrib_ptr)
_set16im(MAP_LOGICAL_SIZE, src_stride)
_set16(ScrollY1, scrollY)
lsr scrollY+1
ror scrollY+0
lsr scrollY+1
ror scrollY+0
lsr scrollY+1
ror scrollY+0
ldx scrollY+0
clc
lda src_tile_ptr+0
adc colTabL,x
sta src_tile_ptr+0
lda src_tile_ptr+1
adc colTabH,x
sta src_tile_ptr+1
// Source offset is (ScrollX1 >> 4) << 1
_set16(ScrollX1, src_offset)
lsr src_offset+1
ror src_offset+0
lsr src_offset+1
ror src_offset+0
lsr src_offset+1
ror src_offset+0
lda src_offset+0
and #$fe
sta src_offset+0
// Copy into tile after GOTOX
_set16im(2, dst_offset)
_set16im(CHARS_WIDE * 2, copy_length)
jsr CopyLayerChunks
rts
}
UpdateLayer2: {
_set32im(MapRam2 + MAP_LOGICAL_SIZE, src_tile_ptr)
_set32im(AttribRam, src_attrib_ptr)
_set16im(MAP_LOGICAL_SIZE, src_stride)
_set16(ScrollY1, scrollY)
lsr scrollY+1
ror scrollY+0
lsr scrollY+1
ror scrollY+0
lsr scrollY+1
ror scrollY+0
ldx scrollY+0
clc
lda src_tile_ptr+0
adc colTabL,x
sta src_tile_ptr+0
lda src_tile_ptr+1
adc colTabH,x
sta src_tile_ptr+1
// Source offset is (ScrollX1 >> 4) << 1
_set16(ScrollX1, src_offset)
lsr src_offset+1
ror src_offset+0
lsr src_offset+1
ror src_offset+0
lsr src_offset+1
ror src_offset+0
lda src_offset+0
and #$fe
sta src_offset+0
// Copy into tile after GOTOX on the second layer
_set16im(2 + LOGICAL_LAYER_SIZE, dst_offset)
_set16im(CHARS_WIDE * 2, copy_length)
jsr CopyLayerChunks
rts
}
UpdateLayer3: {
_set32im(MapRam3, src_tile_ptr)
_set32im(AttribRam, src_attrib_ptr)
_set16im(MAP_LOGICAL_SIZE, src_stride)
_set16(ScrollY2, scrollY)
lsr scrollY+1
ror scrollY+0
lsr scrollY+1
ror scrollY+0
lsr scrollY+1
ror scrollY+0