-
Notifications
You must be signed in to change notification settings - Fork 5
/
flake.nix
97 lines (92 loc) · 3.14 KB
/
flake.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
{
description = "Neotron BMC";
inputs = {
flake-utils.url = "github:numtide/flake-utils";
rust-overlay = {
url = "github:oxalica/rust-overlay";
inputs = {
nixpkgs.follows = "nixpkgs";
flake-utils.follows = "flake-utils";
};
};
crane = {
url = "github:ipetkov/crane";
inputs = {
nixpkgs.follows = "nixpkgs";
flake-utils.follows = "flake-utils";
rust-overlay.follows = "rust-overlay";
};
};
};
outputs = { self, nixpkgs, flake-utils, rust-overlay, crane }:
let
# List of systems this flake.nix has been tested to work with
systems = [ "x86_64-linux" ];
pkgsForSystem = system: nixpkgs.legacyPackages.${system}.appendOverlays [
rust-overlay.overlays.default
];
in
flake-utils.lib.eachSystem systems
(system:
let
pkgs = pkgsForSystem system;
toolchain = pkgs.rust-bin.stable.latest.default.override {
targets = [ "thumbv6m-none-eabi" ];
};
craneLib = (crane.mkLib pkgs).overrideToolchain toolchain;
bmc-pico = craneLib.mkCargoDerivation {
pname = "neotron-bmc-pico";
version = (craneLib.crateNameFromCargoToml {
cargoToml = ./neotron-bmc-pico/Cargo.toml;
}).version;
cargoArtifacts = null;
cargoVendorDir = craneLib.vendorCargoDeps { src = ./neotron-bmc-pico; };
src = with pkgs.lib;
let keep = suffixes: path: type: any (s: hasSuffix s path) suffixes;
in
cleanSourceWith {
src = craneLib.path ./.;
filter = path: type: any id (map (f: f path type) [
craneLib.filterCargoSources
(keep [
".md" # neotron-bmc-protocol needs README.md
".x"
])
]);
};
buildPhaseCargoCommand = ''
cd neotron-bmc-pico # because .cargo/config.toml exists here
cargo build --release --target=thumbv6m-none-eabi
'';
nativeBuildInputs = [
pkgs.makeWrapper
pkgs.probe-run
pkgs.flip-link
];
installPhase = ''
mkdir -p $out/bin
cp target/thumbv6m-none-eabi/release/neotron-bmc-pico $out/bin/
makeWrapper ${pkgs.probe-run}/bin/probe-run $out/bin/flash-neotron-bmc-pico \
--set DEFMT_LOG info \
--add-flags "--chip STM32F030K6Tx $out/bin/neotron-bmc-pico"
'';
};
in rec
{
packages.neotron-bmc-pico = bmc-pico;
defaultPackage = packages.neotron-bmc-pico;
defaultApp = apps.neotron-bmc-pico;
apps.neotron-bmc-pico = flake-utils.lib.mkApp {
drv = bmc-pico;
exePath = "/bin/flash-neotron-bmc-pico";
};
devShell = pkgs.mkShell {
nativeBuildInputs = [
toolchain
pkgs.probe-run
pkgs.flip-link
];
};
}
);
}