Android.bp

cc_library_shared {
    name: "nfc_nci_nxp",
    defaults: ["hidl_defaults"],
    proprietary: true,

    srcs: [
        "halimpl/common/*.cc",
        "halimpl/dnld/*.cc",
        "halimpl/hal/*.cc",
        "halimpl/log/*.cc",
        "halimpl/self-test/*.cc",
        "halimpl/src/adaptation/EseAdaptation.cpp",
        "halimpl/tml/*.cc",
        "halimpl/utils/*.cc",
        "halimpl/utils/*.cpp",
        "halimpl/configs/*.cpp",
    ],
    shared_libs: [
        "libbase",
        "libcutils",
        "liblog",
        "libhwbinder",
        "libhardware",
        "libhardware_legacy",
        "libhidlbase",
        "libhidltransport",
        "liblog",
        "libutils",
        "android.hardware.nfc@1.0",
        "android.hardware.nfc@1.1",
        "android.hardware.secure_element@1.0",
        "ese_spi_nxp",
        "vendor.nxp.nxpese@1.0",
    ],
    local_include_dirs: [
        "halimpl/dnld",
        "halimpl/hal",
        "halimpl/log",
        "halimpl/self-test",
        "halimpl/tml",
        "halimpl/src/include",
        "halimpl/configs",
    ],
    export_include_dirs: [
        "extns/impl",
        "halimpl/inc",
        "halimpl/common",
        "halimpl/utils",
    ],
    cflags: [
        "-DBUILDCFG=1",
        "-Wno-deprecated-register",
        "-Wno-unused-parameter",
        "-Wno-missing-field-initializers",
        "-DNFC_HAL_TARGET=TRUE",
        "-DNFC_RW_ONLY=TRUE",
        "-DNXP_EXTNS=TRUE",
        "-DNFC_NXP_AID_MAX_SIZE_DYN=TRUE",
        "-DNXP_NFCC_HCE_F=TRUE",
        "-DNFC_NXP_LISTEN_ROUTE_TBL_OPTIMIZATION=TRUE",
        "-DNFC_NXP_HFO_SETTINGS=FALSE",
        "-DANDROID",
        "-DNXP_HW_SELF_TEST"
    ],
}

cc_binary {
    name: "android.hardware.nfc@1.1-service",
    defaults: ["hidl_defaults"],
    proprietary: true,
    init_rc: ["1.1/android.hardware.nfc@1.1-service.rc"],
    relative_install_path: "hw",
    srcs: [
        "1.1/NxpNfcService.cpp",
        "1.1/Nfc.cpp",
        "extns/impl/NxpNfc.cpp",
    ],

    shared_libs: [
        "nfc_nci_nxp",
        "libbase",
        "libcutils",
        "libhardware",
        "liblog",
        "libutils",
        "android.hardware.nfc@1.0",
        "android.hardware.nfc@1.1",
        "ese_spi_nxp",
        "libhidlbase",
        "libhidltransport",
        "libhwbinder",
        "vendor.nxp.nxpnfc@1.0",
    ],
}