build.gradle

buildscript {
    repositories {
        mavenCentral()
        jcenter()
    }
}

plugins {
    id "com.jfrog.bintray" version "1.7"
}

group 'MicroUtils'
version 'MUVERSION'

// Apply the java plugin to add support for Java
apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'maven-publish'
sourceCompatibility = 1.8

repositories {
    mavenCentral()
    jcenter()
}

dependencies {
    compile "com.google.guava:guava:18.0"
    compile "com.google.code.findbugs:jsr305:3.0.1"
    compile "org.slf4j:slf4j-api:1.7.21"
    testCompile 'junit:junit:4.12'
    testCompile "org.slf4j:slf4j-log4j12:1.7.21"
    testCompile "log4j:log4j:1.2.17"
}

//https://github.com/bintray/gradle-bintray-plugin
bintray {
    user = 'oshai'
    key = 'my_key'
    publications = ['MyPublication']
    pkg {
        repo = 'mujava'
        name = 'MuJava'
        userOrg = 'microutils'
        licenses = ['Apache-2.0']
        vcsUrl = 'https://github.com/MicroUtils/MuJava'
        version {
            name = 'MUVERSION'
            desc = 'MuJava MUVERSION'
            released  = new Date()
        }
    }
}

// custom tasks for creating source/javadoc jars
task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

// add javadoc/source jar tasks as artifacts
artifacts {
    archives sourcesJar, javadocJar
}

publishing {
    publications {
        MyPublication(MavenPublication) {
            from components.java
            groupId 'io.github.microutils'
            artifactId 'mujava'
            version 'MUVERSION'
            artifact sourcesJar
            artifact javadocJar
        }
    }
}