Delay() inside of "for" loops fail after socket connection is made

[uncletammy]

Using the async branch, delay()s inside of "for" loops aren't honored after a websockets connection is established. The same loop performs as expected before the ws connection is made. Is this expected behavior? Is there a workaround?

Hardware

Generic ESP-12E board

Sketch

#include <ESP8266WiFi.h>
#include <ESP8266WiFiMulti.h>
#include <WebSocketsClient.h>
#include <Hash.h>

ESP8266WiFiMulti WiFiMulti;
WebSocketsClient webSocket;

void webSocketEvent(WStype_t type, uint8_t * payload, size_t length) {

    // Immediately exits the for loop and prints 1-255 in the console
    for(uint8_t c = 255; c > 0; c--) {
          Serial.println(c);
        delay(1000);
    }

}

void setup() {
    Serial.begin(115200);

    WiFiMulti.addAP("myNetworkName", "myPassword");

    while(WiFiMulti.run() != WL_CONNECTED) {
        delay(100);
    }

    webSocket.begin("192.168.1.119", 1440);
    webSocket.onEvent(webSocketEvent);


    // Works as expected
    for(uint8_t c = 255; c > 0; c--) {
        Serial.println(c);
        delay(1000);
    }


}

void loop() {

}

[Links2004]

yes that is normal, when using async
the webSocketEvent has the similar constraints then an interrupt on ESP.
the code is not running in the "arduino loop" context.
your code can take more time then in a interrupt,
but all thinks that end up calling yield will make problems.

if you want delayed actions on way is to set a flag or save the executing time.
and handle that in the loop.

may reading millis and comparing is working inside the webSocketEvent.

until we port the ESP8266 RTOS SDK this is the only way.
(the port will need some time, and a Stable RTOS SDK)

[uncletammy]

@Links2004, thanks for the quick reply. I used a flag as a workaround. My solution was similar to the code below.

#include <ESP8266WiFi.h>
#include <ESP8266WiFiMulti.h>
#include <WebSocketsClient.h>
#include <Hash.h>

ESP8266WiFiMulti WiFiMulti;
WebSocketsClient webSocket;

boolean mustDoSomething = false;

void doSomething(){

    // Now also works as expected
    for(uint8_t c = 255; c > 0; c--) {
        Serial.println(c);
        delay(1000);
    }

}

void webSocketEvent(WStype_t type, uint8_t * payload, size_t length) {

  mustDoSomething = true;

}

void setup() {
    Serial.begin(115200);

    WiFiMulti.addAP("myNetworkName", "myPassword");

    while(WiFiMulti.run() != WL_CONNECTED) {
        delay(100);
    }
    webSocket.begin("192.168.1.119", 1440);
    webSocket.onEvent(webSocketEvent);

    // Works as expected
    for(uint8_t c = 255; c > 0; c--) {
        Serial.println(c);
        delay(1000);
    }


}

void loop() {

  if (mustDoSomething){
    doSomething();
  }
  mustDoSomething = false;
}

[sumaInovation]

can we use HTTPS website with communicate