build.gradle

plugins {
    id "java-library"
    id "maven-publish"
    id "signing"
    id "checkstyle"
}

base {
    java.toolchain.languageVersion = JavaLanguageVersion.of(17)
    compileJava.options.encoding = compileTestJava.options.encoding = javadoc.options.encoding = "UTF-8"

    archivesName = project.maven_name
    group = project.maven_group
    version = project.maven_version
}

repositories {
    mavenCentral()
    maven {
        name = "Lenni0451"
        url = "https://maven.lenni0451.net/everything"
    }
}

dependencies {
    api "net.raphimc:software-renderer:1.0.0-SNAPSHOT"
    api "io.github.spair:imgui-java-binding:1.86.11"

    ["windows", "linux", "macos"].each {
        testImplementation "io.github.spair:imgui-java-natives-$it:1.86.4"
    }
}

java {
    withSourcesJar()
    withJavadocJar()
}

artifacts {
    archives javadocJar, sourcesJar
}

publishing {
    repositories {
        maven {
            name = "reposilite"
            def releasesUrl = "https://maven.lenni0451.net/releases"
            def snapshotsUrl = "https://maven.lenni0451.net/snapshots"
            url = project.maven_version.endsWith("SNAPSHOT") ? snapshotsUrl : releasesUrl

            credentials(PasswordCredentials)
            authentication {
                basic(BasicAuthentication)
            }
        }
    }
    publications {
        maven(MavenPublication) {
            artifactId = project.maven_name
            groupId = project.maven_group
            version = project.maven_version

            from components.java

            pom {
                name = rootProject.name
                description = "Draw ImGui in a Java Swing Panel"
                url = "https://github.com/Lenni0451/imgui-swing"
                licenses {
                    license {
                        name = "MIT License"
                        url = "https://github.com/Lenni0451/imgui-swing/blob/main/LICENSE"
                    }
                }
                developers {
                    developer {
                        id = "Lenni0451"
                    }
                }
                scm {
                    connection = "scm:git:git://github.com/Lenni0451/imgui-swing.git"
                    developerConnection = "scm:git:ssh://github.com/Lenni0451/imgui-swing.git"
                    url = "github.com/Lenni0451/imgui-swing"
                }
            }
        }
    }
}

checkstyle {
    toolVersion = "9.3" //Latest version for Java 8
    configFile = rootProject.file("config/checkstyle/checkstyle.xml")
}

signing {
    setRequired false
    sign configurations.archives
    sign publishing.publications.maven
}

project.tasks.withType(PublishToMavenRepository).forEach {
    it.dependsOn(project.tasks.withType(Sign))
}
build.dependsOn(check)